From 6a72492a10304be1714d198c74bec407cc8e6429 Mon Sep 17 00:00:00 2001
From: =?UTF-8?q?Micha=C5=82=20G=C3=B3rny?= <mgorny@gentoo.org>
Date: Wed, 31 Mar 2021 00:24:52 +0200
Subject: dev-python/ipython: Remove old
MIME-Version: 1.0
Content-Type: text/plain; charset=UTF-8
Content-Transfer-Encoding: 8bit

Signed-off-by: Michał Górny <mgorny@gentoo.org>
---
 dev-python/ipython/Manifest              |   1 -
 dev-python/ipython/ipython-7.20.0.ebuild | 137 -------------------------------
 2 files changed, 138 deletions(-)
 delete mode 100644 dev-python/ipython/ipython-7.20.0.ebuild

(limited to 'dev-python/ipython')

diff --git a/dev-python/ipython/Manifest b/dev-python/ipython/Manifest
index 0cbf326fbe7b..c28ab91001fe 100644
--- a/dev-python/ipython/Manifest
+++ b/dev-python/ipython/Manifest
@@ -1,3 +1,2 @@
-DIST ipython-7.20.0.tar.gz 5140776 BLAKE2B ec01caf874ab9c331eb1f074f9e70acb521fe6d4abe3e8f086d9e9e77cd710c3b0d88c6d7b071abc6962eee8141b65a012ec772cbec3450db25f086fc66cf1c6 SHA512 2fff1a64c3d83e794e76bcbdf54e105f499321d9a7e5d3221cdc3e15a96e90543fd465b8dbee4836965286e7c1f1ea6d13e4d3d88c095164858bf71c161111fe
 DIST ipython-7.21.0.tar.gz 5141725 BLAKE2B dae44d481e959ef7d002bdb51d0ab1e2f3eca3449071a2e4161aa735c06fef8a948d80bafd3f2bdd066208437b5ed36615cad5885af453771a32a313fba907eb SHA512 200e41d4e06343b6320f3d106925f6c995f39cf88d01250f53885d4e94d0fd9454a6be4cd7c69410f7dced94b05634f6d2269f9737cc563accf85206d4d7fff8
 DIST ipython-7.22.0.tar.gz 5143229 BLAKE2B be78fc7089d620cb9ad437ed8154b37ac8c7cd68ca18a2569cfcf7ea9af968c58eeee18c8d18a1f26459ccef73e59083ac27055c19e4df254836e484ce0a9908 SHA512 2647dcd5e0d9b6afc8d990d2c099ad7ed581b5eff6d657630929e0d0d9f8965e7c7924c51a10a797e7d7406212d7a06c941c163e6f6046aa62130049a9bbc0d0
diff --git a/dev-python/ipython/ipython-7.20.0.ebuild b/dev-python/ipython/ipython-7.20.0.ebuild
deleted file mode 100644
index a6700d2b28b3..000000000000
--- a/dev-python/ipython/ipython-7.20.0.ebuild
+++ /dev/null
@@ -1,137 +0,0 @@
-# Copyright 1999-2021 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=7
-
-DISTUTILS_USE_SETUPTOOLS=no
-PYTHON_COMPAT=( python3_{7..9} )
-PYTHON_REQ_USE='readline,sqlite,threads(+)'
-
-inherit distutils-r1 optfeature virtualx
-
-DESCRIPTION="Advanced interactive shell for Python"
-HOMEPAGE="https://ipython.org/ https://github.com/ipython/ipython/"
-SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
-
-LICENSE="BSD"
-SLOT="0"
-KEYWORDS="amd64 ~arm arm64 ~ppc ppc64 x86 ~amd64-linux ~x86-linux"
-IUSE="doc examples matplotlib notebook nbconvert qt5 +smp test"
-RESTRICT="!test? ( test )"
-
-CDEPEND="
-	dev-python/backcall[${PYTHON_USEDEP}]
-	dev-python/decorator[${PYTHON_USEDEP}]
-	>=dev-python/jedi-0.16[${PYTHON_USEDEP}]
-	>=dev-python/pexpect-4.3[${PYTHON_USEDEP}]
-	dev-python/pickleshare[${PYTHON_USEDEP}]
-	>=dev-python/prompt_toolkit-2[${PYTHON_USEDEP}]
-	<dev-python/prompt_toolkit-3.1[${PYTHON_USEDEP}]
-	dev-python/pygments[${PYTHON_USEDEP}]
-	dev-python/traitlets[${PYTHON_USEDEP}]
-	matplotlib? ( dev-python/matplotlib[${PYTHON_USEDEP}] )
-"
-
-RDEPEND="${CDEPEND}
-	nbconvert? ( dev-python/nbconvert[${PYTHON_USEDEP}] )"
-
-BDEPEND="
-	test? (
-		${CDEPEND}
-		app-text/dvipng[truetype]
-		>=dev-python/ipykernel-5.1.0[${PYTHON_USEDEP}]
-		dev-python/nbformat[${PYTHON_USEDEP}]
-		dev-python/nose[${PYTHON_USEDEP}]
-		>=dev-python/numpy-1.14[${PYTHON_USEDEP}]
-		dev-python/requests[${PYTHON_USEDEP}]
-		dev-python/testpath[${PYTHON_USEDEP}]
-	)
-	doc? (
-		>=dev-python/ipykernel-5.1.0[${PYTHON_USEDEP}]
-		dev-python/matplotlib[${PYTHON_USEDEP}]
-		>=dev-python/sphinx-2[${PYTHON_USEDEP}]
-		dev-python/sphinx_rtd_theme[${PYTHON_USEDEP}]
-	)"
-
-PDEPEND="
-	notebook? (
-		dev-python/notebook[${PYTHON_USEDEP}]
-		dev-python/ipywidgets[${PYTHON_USEDEP}]
-		dev-python/widgetsnbextension[${PYTHON_USEDEP}]
-	)
-	qt5? ( dev-python/qtconsole[${PYTHON_USEDEP}] )
-	smp? (
-		>=dev-python/ipykernel-5.1.0[${PYTHON_USEDEP}]
-		>=dev-python/ipyparallel-6.2.3[${PYTHON_USEDEP}]
-	)"
-
-PATCHES=( "${FILESDIR}"/2.1.0-substitute-files.patch )
-
-DISTUTILS_IN_SOURCE_BUILD=1
-
-python_prepare_all() {
-	# Remove out of date insource files
-	rm IPython/extensions/cythonmagic.py || die
-	rm IPython/extensions/rmagic.py || die
-
-	# Prevent un-needed download during build
-	if use doc; then
-		sed -e "/^    'sphinx.ext.intersphinx',/d" -i docs/source/conf.py || die
-	fi
-
-	distutils-r1_python_prepare_all
-}
-
-python_compile_all() {
-	if use doc; then
-		emake -C docs html_noapi
-		HTML_DOCS=( docs/build/html/. )
-	fi
-}
-
-src_test() {
-	virtx distutils-r1_src_test
-}
-
-python_test() {
-	distutils_install_for_testing
-	pushd "${TEST_DIR}" >/dev/null || die
-	"${TEST_DIR}"/scripts/iptest || die
-	popd >/dev/null || die
-}
-
-python_install() {
-	distutils-r1_python_install
-
-	# Create ipythonX.Y symlinks.
-	# TODO:
-	# 1. do we want them for pypy? No.  pypy has no numpy
-	# 2. handle it in the eclass instead (use _python_ln_rel).
-	# With pypy not an option the dosym becomes unconditional
-	dosym ../lib/python-exec/${EPYTHON}/ipython \
-		/usr/bin/ipython${EPYTHON#python}
-}
-
-python_install_all() {
-	distutils-r1_python_install_all
-
-	if use examples; then
-		dodoc -r examples
-		docompress -x /usr/share/doc/${PF}/examples
-	fi
-}
-
-pkg_postinst() {
-	optfeature "sympyprinting" dev-python/sympy
-	optfeature "cythonmagic" dev-python/cython
-	optfeature "%lprun magic command" dev-python/line_profiler
-	optfeature "%mprun magic command" dev-python/memory_profiler
-
-	if use nbconvert; then
-		if ! has_version app-text/pandoc ; then
-			einfo "Node.js will be used to convert notebooks to other formats"
-			einfo "like HTML. Support for that is still experimental. If you"
-			einfo "encounter any problems, please use app-text/pandoc instead."
-		fi
-	fi
-}
-- 
cgit v1.2.3