From 720627c5a2848c60fbbf9518cc4a3babf4554b73 Mon Sep 17 00:00:00 2001
From: =?UTF-8?q?Micha=C5=82=20G=C3=B3rny?= <mgorny@gentoo.org>
Date: Fri, 15 Dec 2023 17:34:22 +0100
Subject: dev-python/lazy-object-proxy: Bump to 1.10.0
MIME-Version: 1.0
Content-Type: text/plain; charset=UTF-8
Content-Transfer-Encoding: 8bit

Signed-off-by: Michał Górny <mgorny@gentoo.org>
---
 .../lazy-object-proxy-1.10.0.ebuild                | 50 ++++++++++++++++++++++
 1 file changed, 50 insertions(+)
 create mode 100644 dev-python/lazy-object-proxy/lazy-object-proxy-1.10.0.ebuild

(limited to 'dev-python/lazy-object-proxy/lazy-object-proxy-1.10.0.ebuild')

diff --git a/dev-python/lazy-object-proxy/lazy-object-proxy-1.10.0.ebuild b/dev-python/lazy-object-proxy/lazy-object-proxy-1.10.0.ebuild
new file mode 100644
index 000000000000..049fdedf879d
--- /dev/null
+++ b/dev-python/lazy-object-proxy/lazy-object-proxy-1.10.0.ebuild
@@ -0,0 +1,50 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_EXT=1
+DISTUTILS_USE_PEP517=setuptools
+PYPI_NO_NORMALIZE=1
+PYTHON_COMPAT=( python3_{10..12} pypy3 )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="A fast and thorough lazy object proxy"
+HOMEPAGE="
+	https://github.com/ionelmc/python-lazy-object-proxy/
+	https://pypi.org/project/lazy-object-proxy/
+	https://python-lazy-object-proxy.readthedocs.io/
+"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux ~x64-macos"
+IUSE="+native-extensions"
+
+BDEPEND="
+	>=dev-python/setuptools-scm-8[${PYTHON_USEDEP}]
+"
+
+distutils_enable_tests pytest
+
+PATCHES=(
+	# https://github.com/ionelmc/python-lazy-object-proxy/pull/79
+	"${FILESDIR}/${P}-pure-tests.patch"
+)
+
+python_prepare_all() {
+	# No need to benchmark
+	sed \
+		-e '/benchmark/s:test_:_&:g' \
+		-e '/pytest.mark.benchmark/d' \
+		-i tests/test_lazy_object_proxy.py || die
+
+	distutils-r1_python_prepare_all
+
+	if use native-extensions; then
+		unset SETUPPY_FORCE_PURE
+	else
+		export SETUPPY_FORCE_PURE=1
+	fi
+}
-- 
cgit v1.2.3