From c9ac4903154762ad288240359ec77267d8e5dc95 Mon Sep 17 00:00:00 2001
From: Georgy Yakovlev <ya@sysdump.net>
Date: Sun, 27 May 2018 16:29:26 -0700
Subject: dev-python/libvirt-python: add python-3.6 support

Closes: https://github.com/gentoo/gentoo/pull/8463

Package-Manager: Portage-2.3.40, Repoman-2.3.9
Signed-off-by: Matthias Maier <tamiko@gentoo.org>
---
 .../libvirt-python/libvirt-python-4.2.0-r1.ebuild  | 46 ++++++++++++++++++++++
 1 file changed, 46 insertions(+)
 create mode 100644 dev-python/libvirt-python/libvirt-python-4.2.0-r1.ebuild

(limited to 'dev-python/libvirt-python/libvirt-python-4.2.0-r1.ebuild')

diff --git a/dev-python/libvirt-python/libvirt-python-4.2.0-r1.ebuild b/dev-python/libvirt-python/libvirt-python-4.2.0-r1.ebuild
new file mode 100644
index 000000000000..d097045772d1
--- /dev/null
+++ b/dev-python/libvirt-python/libvirt-python-4.2.0-r1.ebuild
@@ -0,0 +1,46 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+PYTHON_COMPAT=( python{2_7,3_4,3_5,3_6} )
+
+MY_P="${P/_rc/-rc}"
+
+inherit distutils-r1
+
+if [[ ${PV} = *9999* ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="git://libvirt.org/libvirt-python.git"
+	SRC_URI=""
+	KEYWORDS=""
+	RDEPEND="app-emulation/libvirt:=[-python(-)]"
+else
+	SRC_URI="http://libvirt.org/sources/python/${MY_P}.tar.gz"
+	KEYWORDS="~amd64 ~arm64 ~x86"
+	RDEPEND="app-emulation/libvirt:0/${PV}"
+fi
+S="${WORKDIR}/${P%_rc*}"
+
+DESCRIPTION="libvirt Python bindings"
+HOMEPAGE="https://www.libvirt.org"
+LICENSE="LGPL-2"
+SLOT="0"
+IUSE="examples test"
+
+DEPEND="${RDEPEND}
+	virtual/pkgconfig
+	test? ( dev-python/lxml[${PYTHON_USEDEP}]
+		dev-python/nose[${PYTHON_USEDEP}] )"
+
+python_test() {
+	esetup.py test
+}
+
+python_install_all() {
+	if use examples; then
+		dodoc -r examples
+		docompress -x /usr/share/doc/${PF}/examples
+	fi
+	distutils-r1_python_install_all
+}
-- 
cgit v1.2.3