From 714b0f4460f2d9d0b41e81f80ddfa67a19929a48 Mon Sep 17 00:00:00 2001
From: =?UTF-8?q?Micha=C5=82=20G=C3=B3rny?= <mgorny@gentoo.org>
Date: Wed, 17 Apr 2024 15:44:26 +0200
Subject: dev-python/meson-python: Bump to 0.16.0
MIME-Version: 1.0
Content-Type: text/plain; charset=UTF-8
Content-Transfer-Encoding: 8bit

Signed-off-by: Michał Górny <mgorny@gentoo.org>
---
 dev-python/meson-python/meson-python-0.16.0.ebuild | 53 ++++++++++++++++++++++
 1 file changed, 53 insertions(+)
 create mode 100644 dev-python/meson-python/meson-python-0.16.0.ebuild

(limited to 'dev-python/meson-python/meson-python-0.16.0.ebuild')

diff --git a/dev-python/meson-python/meson-python-0.16.0.ebuild b/dev-python/meson-python/meson-python-0.16.0.ebuild
new file mode 100644
index 000000000000..f75822a30233
--- /dev/null
+++ b/dev-python/meson-python/meson-python-0.16.0.ebuild
@@ -0,0 +1,53 @@
+# Copyright 2022-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=standalone
+PYTHON_COMPAT=( python3_{10..12} pypy3 )
+
+inherit distutils-r1
+
+DESCRIPTION="Meson PEP 517 Python build backend"
+HOMEPAGE="
+	https://pypi.org/project/meson-python/
+	https://github.com/mesonbuild/meson-python/
+"
+SRC_URI="
+	https://github.com/mesonbuild/meson-python/archive/${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~arm64-macos ~x64-macos"
+
+RDEPEND="
+	>=dev-python/pyproject-metadata-0.7.1[${PYTHON_USEDEP}]
+	>=dev-build/meson-0.63.0[${PYTHON_USEDEP}]
+	!kernel_Darwin? ( dev-util/patchelf )
+	$(python_gen_cond_dep '
+		>=dev-python/tomli-1.0.0[${PYTHON_USEDEP}]
+	' 3.10)
+"
+BDEPEND="
+	>=dev-python/cython-0.29.34[${PYTHON_USEDEP}]
+	test? (
+		dev-python/pytest-mock[${PYTHON_USEDEP}]
+		dev-vcs/git
+	)
+"
+
+distutils_enable_tests pytest
+
+PATCHES=(
+	# https://github.com/mesonbuild/meson-python/pull/612
+	"${FILESDIR}/${P}-pyproject-metadata-0.8.patch"
+)
+
+python_test() {
+	unset NINJA
+
+	local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+	epytest -p pytest_mock
+}
-- 
cgit v1.2.3