From 75f47d8cc85d4026bc86ebffba9809a2a5eb8edb Mon Sep 17 00:00:00 2001
From: =?UTF-8?q?Micha=C5=82=20G=C3=B3rny?= <mgorny@gentoo.org>
Date: Thu, 4 Dec 2025 05:23:30 +0100
Subject: dev-python/opentelemetry-api: Bump to 1.39.0
MIME-Version: 1.0
Content-Type: text/plain; charset=UTF-8
Content-Transfer-Encoding: 8bit

Signed-off-by: Michał Górny <mgorny@gentoo.org>
---
 .../opentelemetry-api-1.39.0.ebuild                | 61 ++++++++++++++++++++++
 1 file changed, 61 insertions(+)
 create mode 100644 dev-python/opentelemetry-api/opentelemetry-api-1.39.0.ebuild

(limited to 'dev-python/opentelemetry-api/opentelemetry-api-1.39.0.ebuild')

diff --git a/dev-python/opentelemetry-api/opentelemetry-api-1.39.0.ebuild b/dev-python/opentelemetry-api/opentelemetry-api-1.39.0.ebuild
new file mode 100644
index 000000000000..70d7b5f4f0ca
--- /dev/null
+++ b/dev-python/opentelemetry-api/opentelemetry-api-1.39.0.ebuild
@@ -0,0 +1,61 @@
+# Copyright 2024-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=hatchling
+PYTHON_COMPAT=( python3_{11..13} )
+
+inherit distutils-r1
+
+MY_P="opentelemetry-python-${PV}"
+DESCRIPTION="OpenTelemetry Python API"
+HOMEPAGE="
+	https://opentelemetry.io/
+	https://pypi.org/project/opentelemetry-api/
+	https://github.com/open-telemetry/opentelemetry-python/
+"
+SRC_URI="
+	https://github.com/open-telemetry/opentelemetry-python/archive/refs/tags/v${PV}.tar.gz
+		-> ${MY_P}.gh.tar.gz
+"
+S="${WORKDIR}/${MY_P}/${PN}"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~x86"
+
+RDEPEND="
+	>=dev-python/importlib-metadata-6.0[${PYTHON_USEDEP}]
+	>=dev-python/typing-extensions-4.5.0[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		dev-python/typing-extensions[${PYTHON_USEDEP}]
+	)
+"
+
+EPYTEST_PLUGINS=()
+distutils_enable_tests pytest
+
+src_prepare() {
+	default
+
+	# Unnecessary restriction
+	sed -i -e '/importlib-metadata/s:, < [0-9.]*::' pyproject.toml || die
+}
+
+python_test() {
+	cp -a "${BUILD_DIR}"/{install,test} || die
+	local -x PATH=${BUILD_DIR}/test/usr/bin:${PATH}
+
+	for dep in opentelemetry-semantic-conventions opentelemetry-sdk \
+		tests/opentelemetry-test-utils
+	do
+		pushd "${WORKDIR}/${MY_P}/${dep}" >/dev/null || die
+		distutils_pep517_install "${BUILD_DIR}"/test
+		popd >/dev/null || die
+	done
+
+	epytest
+}
-- 
cgit v1.2.3