From b24f9cfd6f13efa097e1529084f8c6a1caf29f78 Mon Sep 17 00:00:00 2001
From: Arfrever Frehtes Taifersar Arahesis <Arfrever@Apache.Org>
Date: Thu, 21 Sep 2017 20:44:25 +0200
Subject: dev-python/protobuf-python: Version bump (3.4.1) (bug #619828).

---
 .../protobuf-python/protobuf-python-3.4.1.ebuild   | 46 ++++++++++++++++++++++
 1 file changed, 46 insertions(+)
 create mode 100644 dev-python/protobuf-python/protobuf-python-3.4.1.ebuild

(limited to 'dev-python/protobuf-python/protobuf-python-3.4.1.ebuild')

diff --git a/dev-python/protobuf-python/protobuf-python-3.4.1.ebuild b/dev-python/protobuf-python/protobuf-python-3.4.1.ebuild
new file mode 100644
index 000000000000..156bcde3e958
--- /dev/null
+++ b/dev-python/protobuf-python/protobuf-python-3.4.1.ebuild
@@ -0,0 +1,46 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI="6"
+# pypy fails tests; pypy3 fails even running tests
+PYTHON_COMPAT=( python2_7 python3_{4,5,6} )
+
+inherit distutils-r1
+
+DESCRIPTION="Google's Protocol Buffers - Python bindings"
+HOMEPAGE="https://developers.google.com/protocol-buffers/ https://github.com/google/protobuf"
+SRC_URI="https://github.com/google/protobuf/archive/v${PV}.tar.gz -> protobuf-${PV}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0/14"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sh ~sparc ~x86 ~amd64-linux ~arm-linux ~x86-linux ~x64-macos ~x86-macos"
+IUSE=""
+
+DEPEND="${PYTHON_DEPS}
+	~dev-libs/protobuf-${PV}
+	dev-python/namespace-google[${PYTHON_USEDEP}]
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	dev-python/six[${PYTHON_USEDEP}]
+	!<dev-libs/protobuf-3[python(-)]"
+RDEPEND="${DEPEND}"
+
+S="${WORKDIR}/protobuf-${PV}/python"
+
+python_configure_all() {
+	mydistutilsargs=(--cpp_implementation)
+}
+
+python_compile() {
+	python_is_python3 || local -x CXXFLAGS="${CXXFLAGS} -fno-strict-aliasing"
+	distutils-r1_python_compile
+}
+
+python_test() {
+	esetup.py test
+}
+
+python_install_all() {
+	distutils-r1_python_install_all
+
+	find "${D}" -name "*.pth" -delete || die
+}
-- 
cgit v1.2.3