From c1694bf6284cf83ed6370739989d95bfbeb01db7 Mon Sep 17 00:00:00 2001
From: Arfrever Frehtes Taifersar Arahesis <Arfrever@Apache.Org>
Date: Sun, 24 Jun 2018 17:25:46 +0200
Subject: dev-python/protobuf-python: Version bump (3.6.0.1).

---
 .../protobuf-python/protobuf-python-3.6.0.1.ebuild | 50 ++++++++++++++++++++++
 1 file changed, 50 insertions(+)
 create mode 100644 dev-python/protobuf-python/protobuf-python-3.6.0.1.ebuild

(limited to 'dev-python/protobuf-python/protobuf-python-3.6.0.1.ebuild')

diff --git a/dev-python/protobuf-python/protobuf-python-3.6.0.1.ebuild b/dev-python/protobuf-python/protobuf-python-3.6.0.1.ebuild
new file mode 100644
index 000000000000..766a0febd0ea
--- /dev/null
+++ b/dev-python/protobuf-python/protobuf-python-3.6.0.1.ebuild
@@ -0,0 +1,50 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI="6"
+PYTHON_COMPAT=(python{2_7,3_4,3_5,3_6})
+
+inherit distutils-r1
+
+DESCRIPTION="Google's Protocol Buffers - Python bindings"
+HOMEPAGE="https://developers.google.com/protocol-buffers/ https://github.com/google/protobuf"
+SRC_URI="https://github.com/google/protobuf/archive/v${PV}.tar.gz -> protobuf-${PV}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0/16"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sh ~sparc ~x86 ~amd64-linux ~arm-linux ~x86-linux ~x64-macos ~x86-macos"
+IUSE=""
+
+DEPEND="${PYTHON_DEPS}
+	~dev-libs/protobuf-${PV}
+	dev-python/namespace-google[${PYTHON_USEDEP}]
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	dev-python/six[${PYTHON_USEDEP}]"
+RDEPEND="${DEPEND}
+	!<dev-libs/protobuf-3[python(-)]"
+
+S="${WORKDIR}/protobuf-${PV}/python"
+
+python_prepare_all() {
+	eapply -p2 "${FILESDIR}/${PN}-3.5.2-google.protobuf.pyext._message.MessageMeta.patch"
+	distutils-r1_python_prepare_all
+}
+
+python_configure_all() {
+	mydistutilsargs=(--cpp_implementation)
+}
+
+python_compile() {
+	python_is_python3 || local -x CXXFLAGS="${CXXFLAGS} -fno-strict-aliasing"
+	distutils-r1_python_compile
+}
+
+python_test() {
+	esetup.py test
+}
+
+python_install_all() {
+	distutils-r1_python_install_all
+
+	find "${D}" -name "*.pth" -delete || die
+}
-- 
cgit v1.2.3