From a454764b8f57dd5de8ab0678ff7099ac670720bd Mon Sep 17 00:00:00 2001
From: Arfrever Frehtes Taifersar Arahesis <Arfrever@Apache.Org>
Date: Thu, 18 Apr 2019 19:32:06 +0000
Subject: dev-python/protobuf-python: Version bump (3.7.1).

Signed-off-by: Arfrever Frehtes Taifersar Arahesis <Arfrever@Apache.Org>
Signed-off-by: Mike Gilbert <floppym@gentoo.org>
---
 .../protobuf-python/protobuf-python-3.7.1.ebuild   | 62 ++++++++++++++++++++++
 1 file changed, 62 insertions(+)
 create mode 100644 dev-python/protobuf-python/protobuf-python-3.7.1.ebuild

(limited to 'dev-python/protobuf-python/protobuf-python-3.7.1.ebuild')

diff --git a/dev-python/protobuf-python/protobuf-python-3.7.1.ebuild b/dev-python/protobuf-python/protobuf-python-3.7.1.ebuild
new file mode 100644
index 000000000000..7b3d970ead20
--- /dev/null
+++ b/dev-python/protobuf-python/protobuf-python-3.7.1.ebuild
@@ -0,0 +1,62 @@
+# Copyright 2008-2019 Arfrever Frehtes Taifersar Arahesis and others
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI="7"
+PYTHON_COMPAT=(python{2_7,3_5,3_6,3_7})
+
+inherit distutils-r1
+
+if [[ "${PV}" == "9999" ]]; then
+	inherit git-r3
+
+	EGIT_REPO_URI="https://github.com/protocolbuffers/protobuf"
+	EGIT_SUBMODULES=()
+fi
+
+DESCRIPTION="Google's Protocol Buffers - Python bindings"
+HOMEPAGE="https://developers.google.com/protocol-buffers/ https://github.com/protocolbuffers/protobuf"
+if [[ "${PV}" == "9999" ]]; then
+	SRC_URI=""
+else
+	SRC_URI="https://github.com/protocolbuffers/protobuf/archive/v${PV}.tar.gz -> protobuf-${PV}.tar.gz"
+fi
+
+LICENSE="BSD"
+SLOT="0/18"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sh ~sparc ~x86 ~amd64-linux ~x86-linux ~x64-macos ~x86-macos"
+IUSE=""
+
+BDEPEND="${PYTHON_DEPS}
+	~dev-libs/protobuf-${PV}
+	dev-python/namespace-google[${PYTHON_USEDEP}]
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	dev-python/six[${PYTHON_USEDEP}]"
+DEPEND="${PYTHON_DEPS}
+	~dev-libs/protobuf-${PV}"
+RDEPEND="${BDEPEND}
+	!<dev-libs/protobuf-3[python(-)]"
+
+S="${WORKDIR}/protobuf-${PV}/python"
+
+if [[ "${PV}" == "9999" ]]; then
+	EGIT_CHECKOUT_DIR="${WORKDIR}/protobuf-${PV}"
+fi
+
+python_configure_all() {
+	mydistutilsargs=(--cpp_implementation)
+}
+
+python_compile() {
+	python_is_python3 || local -x CXXFLAGS="${CXXFLAGS} -fno-strict-aliasing"
+	distutils-r1_python_compile
+}
+
+python_test() {
+	esetup.py test
+}
+
+python_install_all() {
+	distutils-r1_python_install_all
+
+	find "${D}" -name "*.pth" -delete || die
+}
-- 
cgit v1.2.3