From e7aeb7d77a48ea4592b12afbe7be93a4f2d62d99 Mon Sep 17 00:00:00 2001
From: =?UTF-8?q?Micha=C5=82=20G=C3=B3rny?= <mgorny@gentoo.org>
Date: Mon, 24 Jun 2024 04:11:53 +0200
Subject: dev-python/pyftpdlib: Bump to 1.5.10
MIME-Version: 1.0
Content-Type: text/plain; charset=UTF-8
Content-Transfer-Encoding: 8bit

Signed-off-by: Michał Górny <mgorny@gentoo.org>
---
 dev-python/pyftpdlib/pyftpdlib-1.5.10.ebuild | 61 ++++++++++++++++++++++++++++
 1 file changed, 61 insertions(+)
 create mode 100644 dev-python/pyftpdlib/pyftpdlib-1.5.10.ebuild

(limited to 'dev-python/pyftpdlib/pyftpdlib-1.5.10.ebuild')

diff --git a/dev-python/pyftpdlib/pyftpdlib-1.5.10.ebuild b/dev-python/pyftpdlib/pyftpdlib-1.5.10.ebuild
new file mode 100644
index 000000000000..2016e5ca927f
--- /dev/null
+++ b/dev-python/pyftpdlib/pyftpdlib-1.5.10.ebuild
@@ -0,0 +1,61 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{10..12} )
+PYTHON_REQ_USE="ssl(+)"
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="Python FTP server library"
+HOMEPAGE="
+	https://github.com/giampaolo/pyftpdlib/
+	https://pypi.org/project/pyftpdlib/
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos"
+IUSE="examples ssl"
+
+RDEPEND="
+	ssl? ( dev-python/pyopenssl[${PYTHON_USEDEP}] )
+"
+BDEPEND="
+	test? (
+		dev-python/psutil[${PYTHON_USEDEP}]
+		dev-python/pyopenssl[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+distutils_enable_sphinx docs dev-python/sphinx-rtd-theme
+
+python_test() {
+	rm -rf pyftpdlib || die
+	# Some of these tests tend to fail
+	local EPYTEST_DESELECT=(
+		# fail because they process sys.argv and expect program args
+		# rather than pytest args, sigh
+		test/test_misc.py
+		# TODO
+		test/test_functional_ssl.py::TestFtpListingCmdsTLSMixin::test_nlst
+	)
+	# Tests fail with TZ=GMT, see https://bugs.gentoo.org/666623
+	local -x TZ=UTC+1
+	# Skips some shoddy tests plus increases timeouts
+	local -x TRAVIS=1
+	local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+	epytest --pyargs pyftpdlib
+}
+
+python_install_all() {
+	if use examples; then
+		docinto examples
+		dodoc -r demo/.
+		docompress -x /usr/share/doc/${PF}/examples
+	fi
+	distutils-r1_python_install_all
+}
-- 
cgit v1.2.3