From 63dbdb6cfc186e7906d976380b3aa052d2ef75d7 Mon Sep 17 00:00:00 2001
From: =?UTF-8?q?Micha=C5=82=20G=C3=B3rny?= <mgorny@gentoo.org>
Date: Tue, 12 Dec 2023 17:33:25 +0100
Subject: dev-python/python-gnupg: Bump to 0.5.2
MIME-Version: 1.0
Content-Type: text/plain; charset=UTF-8
Content-Transfer-Encoding: 8bit

Signed-off-by: Michał Górny <mgorny@gentoo.org>
---
 dev-python/python-gnupg/python-gnupg-0.5.2.ebuild | 48 +++++++++++++++++++++++
 1 file changed, 48 insertions(+)
 create mode 100644 dev-python/python-gnupg/python-gnupg-0.5.2.ebuild

(limited to 'dev-python/python-gnupg/python-gnupg-0.5.2.ebuild')

diff --git a/dev-python/python-gnupg/python-gnupg-0.5.2.ebuild b/dev-python/python-gnupg/python-gnupg-0.5.2.ebuild
new file mode 100644
index 000000000000..cdf196218ee3
--- /dev/null
+++ b/dev-python/python-gnupg/python-gnupg-0.5.2.ebuild
@@ -0,0 +1,48 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( pypy3 python3_{10..12} )
+
+inherit distutils-r1 verify-sig
+
+DESCRIPTION="A Python wrapper for GnuPG"
+HOMEPAGE="
+	https://docs.red-dove.com/python-gnupg/
+	https://github.com/vsajip/python-gnupg/
+	https://pypi.org/project/python-gnupg/
+"
+SRC_URI="
+	https://github.com/vsajip/python-gnupg/releases/download/${PV}/${P}.tar.gz
+	verify-sig? (
+		https://github.com/vsajip/python-gnupg/releases/download/${PV}/${P}.tar.gz.asc
+	)
+"
+
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~sparc ~x86"
+LICENSE="BSD"
+SLOT="0"
+
+# Need gnupg[nls] for avoiding decode errors and possible hangs
+# w/ e.g. sec-keys/openpgp-keys-gentoo-developers but other pkgs too.
+DEPEND="
+	app-crypt/gnupg[nls]
+"
+RDEPEND="
+	${DEPEND}
+"
+BDEPEND="
+	verify-sig? ( sec-keys/openpgp-keys-vinaysajip )
+"
+
+distutils_enable_tests unittest
+
+VERIFY_SIG_OPENPGP_KEY_PATH=/usr/share/openpgp-keys/vinaysajip.asc
+
+python_test() {
+	# NO_EXTERNAL_TESTS must be enabled,
+	# to disable all tests, which need internet access.
+	NO_EXTERNAL_TESTS=1 eunittest
+}
-- 
cgit v1.2.3