From b0bd22da34f13ff938f5f1dcf0244aa32b6ced78 Mon Sep 17 00:00:00 2001
From: Andrew Ammerlaan <andrewammerlaan@gentoo.org>
Date: Tue, 12 Jul 2022 20:56:45 +0200
Subject: dev-python/python-lsp-server: add 1.5.0

Signed-off-by: Andrew Ammerlaan <andrewammerlaan@gentoo.org>
---
 dev-python/python-lsp-server/Manifest              |  1 +
 .../python-lsp-server-1.5.0-allow-mccabe-0.7.patch | 22 +++++
 .../python-lsp-server-1.5.0.ebuild                 | 94 ++++++++++++++++++++++
 3 files changed, 117 insertions(+)
 create mode 100644 dev-python/python-lsp-server/files/python-lsp-server-1.5.0-allow-mccabe-0.7.patch
 create mode 100644 dev-python/python-lsp-server/python-lsp-server-1.5.0.ebuild

(limited to 'dev-python/python-lsp-server')

diff --git a/dev-python/python-lsp-server/Manifest b/dev-python/python-lsp-server/Manifest
index f1d239e48ddf..7c7e9eae8388 100644
--- a/dev-python/python-lsp-server/Manifest
+++ b/dev-python/python-lsp-server/Manifest
@@ -1 +1,2 @@
 DIST python-lsp-server-1.4.1.tar.gz 76416 BLAKE2B 65638b876182c478434c563371b802367fb8439820ccf57e4404dc1507f3cd514ae5d738d418386607db606025fe5126a533c656ec3fede53fdcfd364a4292cf SHA512 4c9171adc88d219c80055ebbc76566583925129969467c156277b52de9b5981b74b11b9961247045ea98cd9e51e146b2d606c8351a7be5db76f6f4e0e4d7195c
+DIST python-lsp-server-1.5.0.tar.gz 82371 BLAKE2B 3ff388a95f7ae9f4a8e1b41244da1d05e9310e1edcbc7cbd2b17bd4fa0cbe696f31885b2093afb12e879c875b2bfa721cf4e5e9876002f145cf1633238f6238a SHA512 4e3463dc737b4f5f2af0faa8ab2eb10bea8208d4633c22acde9c8ffa2a888b2350e5994dca2a66031e301224a2646660f627d7fc238cbf5103e82a0453a9a809
diff --git a/dev-python/python-lsp-server/files/python-lsp-server-1.5.0-allow-mccabe-0.7.patch b/dev-python/python-lsp-server/files/python-lsp-server-1.5.0-allow-mccabe-0.7.patch
new file mode 100644
index 000000000000..ae8d0944b8f4
--- /dev/null
+++ b/dev-python/python-lsp-server/files/python-lsp-server-1.5.0-allow-mccabe-0.7.patch
@@ -0,0 +1,22 @@
+diff --git a/pyproject.toml b/pyproject.toml
+index ff60a18..2d292b7 100644
+--- a/pyproject.toml
++++ b/pyproject.toml
+@@ -28,7 +28,7 @@ Homepage = "https://github.com/python-lsp/python-lsp-server"
+ all = [
+     "autopep8>=1.6.0,<1.7.0",
+     "flake8>=4.0.0,<4.1.0",
+-    "mccabe>=0.6.0,<0.7.0",
++    "mccabe>=0.6.0,<0.8.0",
+     "pycodestyle>=2.8.0,<2.9.0",
+     "pydocstyle>=2.0.0",
+     "pyflakes>=2.4.0,<2.5.0",
+@@ -39,7 +39,7 @@ all = [
+ ]
+ autopep8 = ["autopep8>=1.6.0,<1.7.0"]
+ flake8 = ["flake8>=4.0.0,<4.1.0"]
+-mccabe = ["mccabe>=0.6.0,<0.7.0"]
++mccabe = ["mccabe>=0.6.0,<0.8.0"]
+ pycodestyle = ["pycodestyle>=2.8.0,<2.9.0"]
+ pydocstyle = ["pydocstyle>=2.0.0"]
+ pyflakes = ["pyflakes>=2.4.0,<2.5.0"]
diff --git a/dev-python/python-lsp-server/python-lsp-server-1.5.0.ebuild b/dev-python/python-lsp-server/python-lsp-server-1.5.0.ebuild
new file mode 100644
index 000000000000..fc684a0c4a68
--- /dev/null
+++ b/dev-python/python-lsp-server/python-lsp-server-1.5.0.ebuild
@@ -0,0 +1,94 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{8..10} )
+
+inherit distutils-r1 optfeature
+
+DESCRIPTION="Python Language Server for the Language Server Protocol"
+HOMEPAGE="https://github.com/python-lsp/python-lsp-server"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64"
+
+IUSE="all-plugins"
+
+BDEPEND="
+	test? (
+		>=dev-python/autopep8-1.6.0[${PYTHON_USEDEP}]
+		<dev-python/autopep8-1.7.0[${PYTHON_USEDEP}]
+		dev-python/flaky[${PYTHON_USEDEP}]
+		>=dev-python/flake8-4.0.0[${PYTHON_USEDEP}]
+		<dev-python/flake8-4.1.0[${PYTHON_USEDEP}]
+		dev-python/matplotlib[${PYTHON_USEDEP}]
+		>=dev-python/mccabe-0.6.0[${PYTHON_USEDEP}]
+		<dev-python/mccabe-0.8.0[${PYTHON_USEDEP}]
+		<dev-python/numpy-1.23.0[${PYTHON_USEDEP}]
+		dev-python/pandas[${PYTHON_USEDEP}]
+		>=dev-python/pycodestyle-2.8.0[${PYTHON_USEDEP}]
+		<dev-python/pycodestyle-2.9.0[${PYTHON_USEDEP}]
+		>=dev-python/pydocstyle-2.0.0[${PYTHON_USEDEP}]
+		>=dev-python/pyflakes-2.4.0[${PYTHON_USEDEP}]
+		<dev-python/pyflakes-2.5.0[${PYTHON_USEDEP}]
+		>=dev-python/pylint-2.5.0[${PYTHON_USEDEP}]
+		dev-python/QtPy[gui,testlib,${PYTHON_USEDEP}]
+		>=dev-python/rope-0.10.5[${PYTHON_USEDEP}]
+		dev-python/yapf[${PYTHON_USEDEP}]
+		>=dev-python/whatthepatch-1.0.2[${PYTHON_USEDEP}]
+		<dev-python/whatthepatch-2.0.0[${PYTHON_USEDEP}]
+	)
+"
+
+RDEPEND="
+	>=dev-python/jedi-0.17.2[${PYTHON_USEDEP}]
+	<dev-python/jedi-0.19.0[${PYTHON_USEDEP}]
+	>=dev-python/python-lsp-jsonrpc-1.0.0[${PYTHON_USEDEP}]
+	dev-python/pluggy[${PYTHON_USEDEP}]
+	all-plugins? (
+		>=dev-python/autopep8-1.6.0[${PYTHON_USEDEP}]
+		<dev-python/autopep8-1.7.0[${PYTHON_USEDEP}]
+		>=dev-python/flake8-4.0.0[${PYTHON_USEDEP}]
+		<dev-python/flake8-4.1.0[${PYTHON_USEDEP}]
+		>=dev-python/mccabe-0.6.0[${PYTHON_USEDEP}]
+		<dev-python/mccabe-0.8.0[${PYTHON_USEDEP}]
+		>=dev-python/pycodestyle-2.8.0[${PYTHON_USEDEP}]
+		<dev-python/pycodestyle-2.9.0[${PYTHON_USEDEP}]
+		>=dev-python/pydocstyle-2.0.0[${PYTHON_USEDEP}]
+		>=dev-python/pyflakes-2.4.0[${PYTHON_USEDEP}]
+		<dev-python/pyflakes-2.5.0[${PYTHON_USEDEP}]
+		>=dev-python/pylint-2.5.0[${PYTHON_USEDEP}]
+		>=dev-python/rope-0.10.5[${PYTHON_USEDEP}]
+		dev-python/yapf[${PYTHON_USEDEP}]
+		>=dev-python/whatthepatch-1.0.2[${PYTHON_USEDEP}]
+		<dev-python/whatthepatch-2.0.0[${PYTHON_USEDEP}]
+	)
+"
+
+PATCHES=(
+	"${FILESDIR}/${P}-allow-mccabe-0.7.patch"
+)
+
+distutils_enable_tests pytest
+
+python_prepare_all() {
+	# remove pytest-cov dep
+	sed -i -e '/addopts =/d' pyproject.toml || die
+	distutils-r1_python_prepare_all
+}
+
+pkg_postinst() {
+	optfeature "Automatically format Python code to conform to the PEP 8 style guide" dev-python/autopep8
+	optfeature "A wrapper around PyFlakes, pep8 & mccabe" dev-python/flake8
+	optfeature "flake8 plugin: McCabe complexity checker" dev-python/mccabe
+	optfeature "Python style guide checker (fka pep8)" dev-python/pycodestyle
+	optfeature "Python docstring style checker" dev-python/pydocstyle
+	optfeature "Passive checker for Python programs" dev-python/pyflakes
+	optfeature "Python code static checker" dev-python/pylint
+	optfeature "Python refactoring library" dev-python/rope
+	optfeature "A formatter for Python files" dev-python/yapf
+}
-- 
cgit v1.2.3