From d662313393f0dbfa4ab6e0835530cac5364577a6 Mon Sep 17 00:00:00 2001
From: Marek Szuba <marecki@gentoo.org>
Date: Sat, 29 Jul 2023 16:09:21 +0100
Subject: dev-python/python-rtmidi: add 1.5.5, drop 1.5.4

Closes: https://bugs.gentoo.org/898712
Signed-off-by: Marek Szuba <marecki@gentoo.org>
---
 .../python-rtmidi/python-rtmidi-1.5.5.ebuild       | 60 ++++++++++++++++++++++
 1 file changed, 60 insertions(+)
 create mode 100644 dev-python/python-rtmidi/python-rtmidi-1.5.5.ebuild

(limited to 'dev-python/python-rtmidi/python-rtmidi-1.5.5.ebuild')

diff --git a/dev-python/python-rtmidi/python-rtmidi-1.5.5.ebuild b/dev-python/python-rtmidi/python-rtmidi-1.5.5.ebuild
new file mode 100644
index 000000000000..18e140eddb8a
--- /dev/null
+++ b/dev-python/python-rtmidi/python-rtmidi-1.5.5.ebuild
@@ -0,0 +1,60 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{10..12} )
+DOCS_BUILDER="sphinx"
+DOCS_DEPEND="dev-python/myst-parser"
+DOCS_DIR="docs"
+DISTUTILS_EXT=1
+DISTUTILS_USE_PEP517=meson-python
+
+inherit distutils-r1 docs pypi
+
+DESCRIPTION="Python bindings for media-libs/rtmidi implemented using Cython"
+HOMEPAGE="
+	https://pypi.org/project/python-rtmidi/
+	https://spotlightkid.github.io/python-rtmidi/
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64"
+IUSE="+alsa jack"
+
+# Most of these tests do not play nicely with the sandbox, some only
+# work with exactly the same version of rtmidi as the bundled one, and
+# several fail even with disabled sandbox unless there are actual MIDI
+# I/O devices present.
+RESTRICT="test"
+
+DEPEND="media-libs/rtmidi[alsa?,jack?]"
+RDEPEND="${DEPEND}"
+BDEPEND="<dev-python/cython-2.99[${PYTHON_USEDEP}]
+	virtual/pkgconfig"
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-1.5.1-unbundle_rtmidi.patch
+)
+
+distutils_enable_tests unittest
+
+src_prepare() {
+	distutils-r1_src_prepare
+
+	# Just in case
+	rm -r src/rtmidi || die
+	rm src/_rtmidi.cpp || die
+
+	# Needed by USE=doc because documentation generation happens in ${S}
+	# but the version.py generated by Meson end up in respective ${BUILD_DIR}s.
+	# The version put in ${S} should be ignored by everything except Sphinx but
+	# just in case, be consistent and generate it unconditionally.
+	sed -e "s|@VERSION@|${PV}|" < rtmidi/version.py.in > rtmidi/version.py || die
+}
+
+python_test() {
+	cd "${T}" || die
+	eunittest "${S}"/tests
+}
-- 
cgit v1.2.3