From e52081b704cf6da9a243b7ba34008a18c43aba0d Mon Sep 17 00:00:00 2001
From: =?UTF-8?q?Micha=C5=82=20G=C3=B3rny?= <mgorny@gentoo.org>
Date: Thu, 20 Feb 2025 12:05:56 +0100
Subject: dev-python/python-tests: Bump to 3.10.16_p2
MIME-Version: 1.0
Content-Type: text/plain; charset=UTF-8
Content-Transfer-Encoding: 8bit

Signed-off-by: Michał Górny <mgorny@gentoo.org>
---
 .../python-tests/python-tests-3.10.16_p2.ebuild    | 74 ++++++++++++++++++++++
 1 file changed, 74 insertions(+)
 create mode 100644 dev-python/python-tests/python-tests-3.10.16_p2.ebuild

(limited to 'dev-python/python-tests/python-tests-3.10.16_p2.ebuild')

diff --git a/dev-python/python-tests/python-tests-3.10.16_p2.ebuild b/dev-python/python-tests/python-tests-3.10.16_p2.ebuild
new file mode 100644
index 000000000000..1956d41c179e
--- /dev/null
+++ b/dev-python/python-tests/python-tests-3.10.16_p2.ebuild
@@ -0,0 +1,74 @@
+# Copyright 2024-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_10 )
+
+inherit python-r1 verify-sig
+
+MY_PV=${PV}
+MY_P="Python-${MY_PV%_p*}"
+PYVER=$(ver_cut 1-2)
+PATCHSET="python-gentoo-patches-${MY_PV}"
+
+DESCRIPTION="Test modules from dev-lang/python"
+HOMEPAGE="
+	https://www.python.org/
+	https://github.com/python/cpython/
+"
+SRC_URI="
+	https://www.python.org/ftp/python/${PV%%_*}/${MY_P}.tar.xz
+	https://dev.gentoo.org/~mgorny/dist/python/${PATCHSET}.tar.xz
+	verify-sig? (
+		https://www.python.org/ftp/python/${PV%%_*}/${MY_P}.tar.xz.asc
+	)
+"
+S="${WORKDIR}/${MY_P}/Lib"
+
+LICENSE="PSF-2"
+SLOT="${PYVER}"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+RDEPEND="
+	${PYTHON_DEPS}
+	~dev-lang/python-${PV}:${PYVER}
+	!<dev-lang/python-3.10.14_p3-r1:${PYVER}
+"
+BDEPEND="
+	${RDEPEND}
+	verify-sig? ( >=sec-keys/openpgp-keys-python-20221025 )
+"
+
+VERIFY_SIG_OPENPGP_KEY_PATH=/usr/share/openpgp-keys/python.org.asc
+
+src_unpack() {
+	if use verify-sig; then
+		verify-sig_verify_detached "${DISTDIR}"/${MY_P}.tar.xz{,.asc}
+	fi
+	default
+}
+
+src_prepare() {
+	local PATCHES=(
+		"${WORKDIR}/${PATCHSET}"
+	)
+
+	cd .. || die
+	default
+}
+
+src_install() {
+	python_setup
+	# keep in sync with TESTSUBDIRS in Makefile.pre.in
+	local dirs=(
+		ctypes/test distutils/tests idlelib/idle_test lib2to3/tests
+		sqlite3/test ./test tkinter/test unittest/test
+	)
+	local dir
+	for dir in "${dirs[@]}"; do
+		python_moduleinto "/usr/lib/python${PYVER}/${dir%/*}"
+		python_domodule "${dir}"
+	done
+}
-- 
cgit v1.2.3