From bb69ad6f2b22c88725d00ce1f07800d01de7caf2 Mon Sep 17 00:00:00 2001
From: =?UTF-8?q?Micha=C5=82=20G=C3=B3rny?= <mgorny@gentoo.org>
Date: Fri, 5 Dec 2025 21:49:59 +0100
Subject: dev-python/python-tests: Bump to 3.13.11
MIME-Version: 1.0
Content-Type: text/plain; charset=UTF-8
Content-Transfer-Encoding: 8bit

Signed-off-by: Michał Górny <mgorny@gentoo.org>
---
 .../python-tests/python-tests-3.13.11.ebuild       | 71 ++++++++++++++++++++++
 1 file changed, 71 insertions(+)
 create mode 100644 dev-python/python-tests/python-tests-3.13.11.ebuild

(limited to 'dev-python/python-tests/python-tests-3.13.11.ebuild')

diff --git a/dev-python/python-tests/python-tests-3.13.11.ebuild b/dev-python/python-tests/python-tests-3.13.11.ebuild
new file mode 100644
index 000000000000..eebb0ba084ee
--- /dev/null
+++ b/dev-python/python-tests/python-tests-3.13.11.ebuild
@@ -0,0 +1,71 @@
+# Copyright 2024-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_13 )
+
+inherit python-r1 verify-sig
+
+MY_PV=${PV}
+MY_P="Python-${MY_PV%_p*}"
+PYVER=$(ver_cut 1-2)
+PATCHSET="python-gentoo-patches-${MY_PV}"
+
+DESCRIPTION="Test modules from dev-lang/python"
+HOMEPAGE="
+	https://www.python.org/
+	https://github.com/python/cpython/
+"
+SRC_URI="
+	https://www.python.org/ftp/python/${PV%%_*}/${MY_P}.tar.xz
+	https://dev.gentoo.org/~mgorny/dist/python/${PATCHSET}.tar.xz
+	verify-sig? (
+		https://www.python.org/ftp/python/${PV%%_*}/${MY_P}.tar.xz.asc
+	)
+"
+S="${WORKDIR}/${MY_P}/Lib"
+
+LICENSE="PSF-2"
+SLOT="${PYVER}"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+# enable by default to help CI handle it (we have no additional deps)
+IUSE="+python_targets_${PYTHON_COMPAT[0]}"
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+RDEPEND="
+	${PYTHON_DEPS}
+	~dev-lang/python-${PV}:${PYVER}
+	!<dev-lang/python-3.13.0_rc1_p3-r1:${PYVER}
+"
+BDEPEND="
+	${PYTHON_DEPS}
+	verify-sig? ( >=sec-keys/openpgp-keys-python-20221025 )
+"
+
+VERIFY_SIG_OPENPGP_KEY_PATH=/usr/share/openpgp-keys/python.org.asc
+
+src_unpack() {
+	if use verify-sig; then
+		verify-sig_verify_detached "${DISTDIR}"/${MY_P}.tar.xz{,.asc}
+	fi
+	default
+}
+
+src_prepare() {
+	local PATCHES=(
+		"${WORKDIR}/${PATCHSET}"
+	)
+
+	cd .. || die
+	default
+}
+
+src_install() {
+	python_setup
+	# keep in sync with TESTSUBDIRS in Makefile.pre.in
+	python_moduleinto "/usr/lib/python${PYVER}"
+	python_domodule test
+	python_moduleinto "/usr/lib/python${PYVER}/idlelib"
+	python_domodule idlelib/idle_test
+}
-- 
cgit v1.2.3