From ce0e2d800023e9b405aaf99cd459111cc2fe651a Mon Sep 17 00:00:00 2001
From: =?UTF-8?q?Micha=C5=82=20G=C3=B3rny?= <mgorny@gentoo.org>
Date: Tue, 20 May 2025 03:50:29 +0200
Subject: dev-python/python-tests: Add 3.14.9999* live ebuilds
MIME-Version: 1.0
Content-Type: text/plain; charset=UTF-8
Content-Transfer-Encoding: 8bit

Signed-off-by: Michał Górny <mgorny@gentoo.org>
---
 .../python-tests/python-tests-3.14.9999.ebuild     | 58 ++++++++++++++++++++++
 1 file changed, 58 insertions(+)
 create mode 100644 dev-python/python-tests/python-tests-3.14.9999.ebuild

(limited to 'dev-python/python-tests/python-tests-3.14.9999.ebuild')

diff --git a/dev-python/python-tests/python-tests-3.14.9999.ebuild b/dev-python/python-tests/python-tests-3.14.9999.ebuild
new file mode 100644
index 000000000000..ea2da946d1f2
--- /dev/null
+++ b/dev-python/python-tests/python-tests-3.14.9999.ebuild
@@ -0,0 +1,58 @@
+# Copyright 2024-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_14 )
+
+inherit git-r3 python-r1
+
+PYVER=$(ver_cut 1-2)
+PATCHSET="python-gentoo-patches-3.14.0b1"
+
+DESCRIPTION="Test modules from dev-lang/python"
+HOMEPAGE="
+	https://www.python.org/
+	https://github.com/python/cpython/
+"
+SRC_URI="
+	https://dev.gentoo.org/~mgorny/dist/python/${PATCHSET}.tar.xz
+"
+EGIT_REPO_URI="https://github.com/python/cpython.git"
+EGIT_BRANCH=${PYVER}
+S="${WORKDIR}/${P}/Lib"
+
+LICENSE="PSF-2"
+SLOT="${PYVER}"
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+RDEPEND="
+	${PYTHON_DEPS}
+	~dev-lang/python-${PV}:${PYVER}
+"
+BDEPEND="
+	${PYTHON_DEPS}
+"
+
+src_unpack() {
+	git-r3_src_unpack
+	default
+}
+
+src_prepare() {
+	local PATCHES=(
+		"${WORKDIR}/${PATCHSET}"
+	)
+
+	cd .. || die
+	default
+}
+
+src_install() {
+	python_setup
+	# keep in sync with TESTSUBDIRS in Makefile.pre.in
+	python_moduleinto "/usr/lib/python${PYVER}"
+	python_domodule test
+	python_moduleinto "/usr/lib/python${PYVER}/idlelib"
+	python_domodule idlelib/idle_test
+}
-- 
cgit v1.2.3