From 5adfa9399276b5f857ae79fa10c11ae3fd4e2ff4 Mon Sep 17 00:00:00 2001
From: =?UTF-8?q?Micha=C5=82=20G=C3=B3rny?= <mgorny@gentoo.org>
Date: Fri, 11 Jul 2025 06:12:45 +0200
Subject: dev-python/xmlsec: Bump to 1.3.16
MIME-Version: 1.0
Content-Type: text/plain; charset=UTF-8
Content-Transfer-Encoding: 8bit

Signed-off-by: Michał Górny <mgorny@gentoo.org>
---
 dev-python/xmlsec/Manifest             |  1 +
 dev-python/xmlsec/xmlsec-1.3.16.ebuild | 59 ++++++++++++++++++++++++++++++++++
 2 files changed, 60 insertions(+)
 create mode 100644 dev-python/xmlsec/xmlsec-1.3.16.ebuild

(limited to 'dev-python')

diff --git a/dev-python/xmlsec/Manifest b/dev-python/xmlsec/Manifest
index f90f5a629747..5010c73eab56 100644
--- a/dev-python/xmlsec/Manifest
+++ b/dev-python/xmlsec/Manifest
@@ -1 +1,2 @@
 DIST python-xmlsec-1.3.15.gh.tar.gz 80101 BLAKE2B a810fa8cb16c55ac01ca360b70519bebc4c709bbf48c03560b85f149b3e70fd4b9d81f4b4aefc229dbcfa8ed2e80f0967fe46bccc9c3bf085e92464ecfcb6476 SHA512 7b55661499050ccf46c51703c9730f3c1ee0f483daec74dd7f8a97dfcf1bdc693f052ea0324165a70dadc2810d330488f6878d0423e32740f7553b04d665acdf
+DIST python-xmlsec-1.3.16.gh.tar.gz 80406 BLAKE2B 1be23867ae44a108dc0596698b712a4d2c8cff4206a9518cab3960368f5242981b8c4e4ba70b9183c298e5a35d2ab823d926019d7292d0a697e7bd3127f88bcc SHA512 1ed39d613c8c656b8d6898730212a3c990f1ab5b807dfdacc0a1c9db1ffaf79cbcc403e771d19faebdf170de7dc886df5582ee8589b6d0d72e3cb9ddc193012a
diff --git a/dev-python/xmlsec/xmlsec-1.3.16.ebuild b/dev-python/xmlsec/xmlsec-1.3.16.ebuild
new file mode 100644
index 000000000000..e8bf5b96d640
--- /dev/null
+++ b/dev-python/xmlsec/xmlsec-1.3.16.ebuild
@@ -0,0 +1,59 @@
+# Copyright 2021-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_EXT=1
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{11..14} )
+
+inherit distutils-r1
+
+MY_P=python-xmlsec-${PV}
+DESCRIPTION="Python bindings for the XML Security Library"
+HOMEPAGE="
+	https://github.com/xmlsec/python-xmlsec/
+	https://pypi.org/project/xmlsec/
+"
+SRC_URI="
+	https://github.com/xmlsec/python-xmlsec/archive/${PV}.tar.gz
+		-> ${MY_P}.gh.tar.gz
+"
+S=${WORKDIR}/${MY_P}
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~riscv ~x86"
+
+DEPEND="
+	dev-libs/xmlsec:=[openssl]
+"
+RDEPEND="
+	${DEPEND}
+	dev-python/lxml[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	dev-python/lxml[${PYTHON_USEDEP}]
+	dev-python/pkgconfig[${PYTHON_USEDEP}]
+	dev-python/setuptools-scm[${PYTHON_USEDEP}]
+	dev-python/wheel[${PYTHON_USEDEP}]
+"
+
+EPYTEST_DESELECT=(
+	# Fragile based on black version?
+	tests/test_type_stubs.py::test_xmlsec_constants_stub
+)
+
+EPYTEST_PLUGINS=()
+distutils_enable_tests pytest
+
+src_configure() {
+	export SETUPTOOLS_SCM_PRETEND_VERSION=${PV}
+
+	export PYXMLSEC_OPTIMIZE_SIZE=
+	if use debug; then
+		# we don't want to use PYXMLSEC_ENABLE_DEBUG envvar,
+		# as it forces -O0
+		export CPPFLAGS="${CPPFLAGS} -DPYXMLSEC_ENABLE_DEBUG=1"
+	fi
+}
-- 
cgit v1.2.3