From 62f9f61a67f6ea60702e55b8f27c5ede6a7e0a91 Mon Sep 17 00:00:00 2001
From: =?UTF-8?q?Micha=C5=82=20G=C3=B3rny?= <mgorny@gentoo.org>
Date: Sun, 11 May 2025 05:17:17 +0200
Subject: dev-python/rq: Revert "Bump to 2.3.3"
MIME-Version: 1.0
Content-Type: text/plain; charset=UTF-8
Content-Transfer-Encoding: 8bit

Accidental push, need to address test issues.

Reverts: 8e39616c00deb2e1593b57a3620ccf713437406a
Signed-off-by: Michał Górny <mgorny@gentoo.org>
---
 dev-python/rq/Manifest        |  1 -
 dev-python/rq/rq-2.3.3.ebuild | 76 -------------------------------------------
 2 files changed, 77 deletions(-)
 delete mode 100644 dev-python/rq/rq-2.3.3.ebuild

(limited to 'dev-python')

diff --git a/dev-python/rq/Manifest b/dev-python/rq/Manifest
index a9145e0be00d..83fb33c2beb1 100644
--- a/dev-python/rq/Manifest
+++ b/dev-python/rq/Manifest
@@ -1,2 +1 @@
 DIST rq-2.3.2.tar.gz 649216 BLAKE2B 8fca0c9008717353b99d7fba502554cd85378e69bef3f5b78acfdc168ecfc95f1644e3ae30a6ace7958a9ad8cc982b155a606b1ae745fabd0caecd1ae353d374 SHA512 b218a6ed7129cab4c148712d2f7ac889ba09d635684c7176ec196338316a2d8bb675a375a93c7ddf672b6834d08ac59106bbc83222efe1d76e677075cd3bab51
-DIST rq-2.3.3.tar.gz 649348 BLAKE2B cf69810289c32e1d363617aecc9ef45ed5b85bb47938b51ceb0e7ae61c186de2b84eea82ac96ca9ece80118de1b77eb8cd4a879ea7fd73e5606e49b68b547cee SHA512 974bbb952c36cbc538ef5cd6a1a426de79f359da431165724d9aed0beeefc9b1d6abd664ca7641997ee0b5d153d760cf631ee6dabfbd06f9a414bbc79867853c
diff --git a/dev-python/rq/rq-2.3.3.ebuild b/dev-python/rq/rq-2.3.3.ebuild
deleted file mode 100644
index b171c55a11d4..000000000000
--- a/dev-python/rq/rq-2.3.3.ebuild
+++ /dev/null
@@ -1,76 +0,0 @@
-# Copyright 1999-2025 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-
-DISTUTILS_USE_PEP517=hatchling
-PYTHON_COMPAT=( python3_{11..13} )
-
-inherit distutils-r1 pypi
-
-DESCRIPTION="Simple, lightweight library for creating and processing background jobs"
-HOMEPAGE="
-	https://python-rq.org/
-	https://github.com/rq/rq/
-	https://pypi.org/project/rq/
-"
-
-LICENSE="BSD"
-SLOT="0"
-KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~riscv ~sparc ~x86"
-
-RDEPEND="
-	>=dev-python/click-5.0[${PYTHON_USEDEP}]
-	>=dev-python/redis-4.5.0[${PYTHON_USEDEP}]
-"
-BDEPEND="
-	test? (
-		dev-db/redis
-		dev-python/psutil[${PYTHON_USEDEP}]
-	)
-"
-
-distutils_enable_tests pytest
-
-src_prepare() {
-	distutils-r1_src_prepare
-
-	# unnecessary typechecking deps
-	sed -i -e '/types-/d' pyproject.toml || die
-}
-
-src_test() {
-	local redis_pid="${T}"/redis.pid
-	local redis_port=6379
-	local redis_test_config="daemonize yes
-		pidfile ${redis_pid}
-		port ${redis_port}
-		bind 127.0.0.1
-	"
-
-	# Spawn Redis itself for testing purposes
-	# NOTE: On sam@'s machine, spawning Redis can hang in the sandbox.
-	# I'm not restricting tests yet because this doesn't happen for anyone else AFAICT.
-	einfo "Spawning Redis"
-	einfo "NOTE: Port ${redis_port} must be free"
-	/usr/sbin/redis-server - <<< "${redis_test_config}" || die
-
-	# Run the actual tests
-	distutils-r1_src_test
-
-	# Clean up afterwards
-	kill "$(<"${redis_pid}")" || die
-}
-
-python_test() {
-	local EPYTEST_DESELECT=(
-		# requires <sentry-sdk-2
-		tests/test_sentry.py::TestSentry::test_failure_capture
-		# hang
-		tests/test_commands.py::TestCommands::test_shutdown_command
-		tests/test_worker_pool.py::TestWorkerPool::test_check_workers
-	)
-
-	local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
-	epytest
-}
-- 
cgit v1.2.3