From 66e7fed08f7e030043d32bfc3eda49bcc407718f Mon Sep 17 00:00:00 2001
From: Sam James <sam@gentoo.org>
Date: Thu, 14 Aug 2025 03:05:04 +0100
Subject: dev-python/msgspec: new package, add 0.19.0

New dependency of dev-util/cvise (live). No py3.14 yet: there's an
upstream PR to fix the annotation issue but there's another refcount
one (and fixing/working around that on our end involves a large sed).

Signed-off-by: Sam James <sam@gentoo.org>
---
 dev-python/msgspec/Manifest              |  1 +
 dev-python/msgspec/metadata.xml          | 12 +++++++
 dev-python/msgspec/msgspec-0.19.0.ebuild | 55 ++++++++++++++++++++++++++++++++
 3 files changed, 68 insertions(+)
 create mode 100644 dev-python/msgspec/Manifest
 create mode 100644 dev-python/msgspec/metadata.xml
 create mode 100644 dev-python/msgspec/msgspec-0.19.0.ebuild

(limited to 'dev-python')

diff --git a/dev-python/msgspec/Manifest b/dev-python/msgspec/Manifest
new file mode 100644
index 000000000000..db5fe85d96e9
--- /dev/null
+++ b/dev-python/msgspec/Manifest
@@ -0,0 +1 @@
+DIST msgspec-0.19.0.gh.tar.gz 1313340 BLAKE2B c6e0757e4fbd2c2afbd239e483eed09fd872d8c85d14153b13ada3ef39adcd41b2f2b8f249e9747e6eef7627b4c238973593d87733cc8d5c36c5a14c15142279 SHA512 bd44052e58afc0c2653780b4dee75d20de93210950d4cd408abc810e3935d1bfdd30b926c34cd48f3095d4b3c1f45ac7aa4a957dcbc562ebd8b817c81abd16d8
diff --git a/dev-python/msgspec/metadata.xml b/dev-python/msgspec/metadata.xml
new file mode 100644
index 000000000000..16677dcb882e
--- /dev/null
+++ b/dev-python/msgspec/metadata.xml
@@ -0,0 +1,12 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "https://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+	<maintainer type="project">
+		<email>python@gentoo.org</email>
+		<name>Python</name>
+	</maintainer>
+	<upstream>
+		<remote-id type="github">jcrist/msgspec</remote-id>
+		<remote-id type="pypi">msgspec</remote-id>
+	</upstream>
+</pkgmetadata>
diff --git a/dev-python/msgspec/msgspec-0.19.0.ebuild b/dev-python/msgspec/msgspec-0.19.0.ebuild
new file mode 100644
index 000000000000..0d32d9479c8b
--- /dev/null
+++ b/dev-python/msgspec/msgspec-0.19.0.ebuild
@@ -0,0 +1,55 @@
+# Copyright 2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_EXT=1
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{11..13} )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="Fast serialization and validation library, with builtin support for many formats"
+HOMEPAGE="
+	https://jcristharif.com/msgspec/
+	https://github.com/jcrist/msgspec
+	https://pypi.org/project/msgspec/
+"
+# No tests in sdist
+SRC_URI="https://github.com/jcrist/msgspec/archive/refs/tags/${PV}.tar.gz -> ${P}.gh.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64"
+
+BDEPEND="
+	dev-python/cython[${PYTHON_USEDEP}]
+	dev-python/versioneer[${PYTHON_USEDEP}]
+	test? (
+		dev-python/attrs[${PYTHON_USEDEP}]
+		dev-python/msgpack[${PYTHON_USEDEP}]
+		dev-python/pyyaml[${PYTHON_USEDEP}]
+	)
+"
+
+EPYTEST_IGNORE=(
+	# Lint tests
+	tests/test_cpylint.py
+	tests/test_mypy.py
+	tests/test_pyright.py
+)
+
+EPYTEST_PLUGINS=()
+
+distutils_enable_tests pytest
+
+src_prepare() {
+	# remove outdated bundled versioneer
+	rm versioneer.py || die
+	distutils-r1_src_prepare
+}
+
+python_test() {
+	rm -rf msgspec || die
+	epytest
+}
-- 
cgit v1.2.3