From b33c834207fbedaa2d4ad23889f473b4c4db2838 Mon Sep 17 00:00:00 2001
From: =?UTF-8?q?Micha=C5=82=20G=C3=B3rny?= <mgorny@gentoo.org>
Date: Tue, 26 Aug 2025 07:08:09 +0200
Subject: dev-python/oslo-utils: Bump to 9.1.0
MIME-Version: 1.0
Content-Type: text/plain; charset=UTF-8
Content-Transfer-Encoding: 8bit

Signed-off-by: Michał Górny <mgorny@gentoo.org>
---
 dev-python/oslo-utils/Manifest                |  1 +
 dev-python/oslo-utils/oslo-utils-9.1.0.ebuild | 66 +++++++++++++++++++++++++++
 2 files changed, 67 insertions(+)
 create mode 100644 dev-python/oslo-utils/oslo-utils-9.1.0.ebuild

(limited to 'dev-python')

diff --git a/dev-python/oslo-utils/Manifest b/dev-python/oslo-utils/Manifest
index e6d660219493..4d8a6768144e 100644
--- a/dev-python/oslo-utils/Manifest
+++ b/dev-python/oslo-utils/Manifest
@@ -1 +1,2 @@
 DIST oslo_utils-9.0.0.tar.gz 138107 BLAKE2B 5541b7574193be246c155a585fe0efebeef8717b9eba9a7ddd504c2ef74b7c6c1b58b2ed5949cb5782992ce2a17edee418bde205ee7b39bdc206356033b50336 SHA512 e548825210406a5efefc6f7f0ab8e2e4120b352002b935a7a6f917e524d2c395826390b121d80642113524525b6f8901a0dbd66cb4b4dfc0f0eab332048e5d6b
+DIST oslo_utils-9.1.0.tar.gz 138207 BLAKE2B 2cea136fe949b16daf98b7f3ec92a73c86923d9bf101c215d572a7aa40502577fe5369b56e4d18fa1a58ebaa829f8241fc1e9add398f40fe8d67e834ca479e2a SHA512 8c654c363980470f2c25bc462370019c717a59152af57d366dbf73306542a0513a007bda48d36b27f3edeb6aafd19a8cc3cbd79d50d8eab7fd0a01b197d58835
diff --git a/dev-python/oslo-utils/oslo-utils-9.1.0.ebuild b/dev-python/oslo-utils/oslo-utils-9.1.0.ebuild
new file mode 100644
index 000000000000..4c1a92b2f27f
--- /dev/null
+++ b/dev-python/oslo-utils/oslo-utils-9.1.0.ebuild
@@ -0,0 +1,66 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=pbr
+PYPI_PN=${PN/-/.}
+PYTHON_COMPAT=( python3_{11..14} )
+
+inherit check-reqs distutils-r1 pypi
+
+DESCRIPTION="Oslo Utility library"
+HOMEPAGE="
+	https://opendev.org/openstack/oslo.utils/
+	https://github.com/openstack/oslo.utils/
+	https://pypi.org/project/oslo.utils/
+"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~riscv ~x86"
+
+RDEPEND="
+	>=dev-python/iso8601-0.1.11[${PYTHON_USEDEP}]
+	>=dev-python/oslo-i18n-3.15.3[${PYTHON_USEDEP}]
+	>=dev-python/netaddr-0.10.0[${PYTHON_USEDEP}]
+	>=dev-python/debtcollector-1.2.0[${PYTHON_USEDEP}]
+	>=dev-python/pyparsing-2.1.0[${PYTHON_USEDEP}]
+	>=dev-python/packaging-20.4[${PYTHON_USEDEP}]
+	>=dev-python/pbr-6.1.0[${PYTHON_USEDEP}]
+	>=dev-python/psutil-3.2.2[${PYTHON_USEDEP}]
+	>=dev-python/pyyaml-3.13[${PYTHON_USEDEP}]
+	dev-python/tzdata[${PYTHON_USEDEP}]
+"
+# qemu needed for qemu-img
+BDEPEND="
+	test? (
+		app-cdr/cdrtools
+		app-emulation/qemu
+		>=dev-python/fixtures-3.0.0[${PYTHON_USEDEP}]
+		>=dev-python/testscenarios-0.4[${PYTHON_USEDEP}]
+		>=dev-python/testtools-2.2.0[${PYTHON_USEDEP}]
+		>=dev-python/oslotest-3.2.0[${PYTHON_USEDEP}]
+		>=dev-python/ddt-1.0.1[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests unittest
+
+# note this only applies to USE=test
+CHECKREQS_DISK_BUILD=8G
+
+pkg_pretend() {
+	use test && check-reqs_pkg_pretend
+}
+
+pkg_setup() {
+	use test && check-reqs_pkg_setup
+}
+
+src_prepare() {
+	distutils-r1_src_prepare
+
+	# require eventlet
+	rm oslo_utils/tests/test_eventletutils.py || die
+}
-- 
cgit v1.2.3