From d3bc506da0364483b8ef1494711e4d9c2dc45bbc Mon Sep 17 00:00:00 2001
From: Arthur Zamarin <arthurzam@gentoo.org>
Date: Thu, 13 Mar 2025 21:20:01 +0200
Subject: dev-python/translate-toolkit: add 3.15.1

Signed-off-by: Arthur Zamarin <arthurzam@gentoo.org>
---
 dev-python/translate-toolkit/Manifest              |   1 +
 .../translate-toolkit-3.15.1.ebuild                | 119 +++++++++++++++++++++
 2 files changed, 120 insertions(+)
 create mode 100644 dev-python/translate-toolkit/translate-toolkit-3.15.1.ebuild

(limited to 'dev-python')

diff --git a/dev-python/translate-toolkit/Manifest b/dev-python/translate-toolkit/Manifest
index 7651e2f53849..fdf3fbdc8f7a 100644
--- a/dev-python/translate-toolkit/Manifest
+++ b/dev-python/translate-toolkit/Manifest
@@ -1 +1,2 @@
 DIST translate-3.15.0.gh.tar.gz 1174826 BLAKE2B 56168081bd67e101f734c55642cbcfe017a1773483a8fbc3d57b51a8494f5069bd3c735a90b935e53cdc1997eaf040161f38c19ba461941733b34084811ee3c4 SHA512 1dbfaa1bf85c74cf5121daa71087e87fd8f642af1883c7d0a7f502bd1d8a29d9dd4b7d8a096cbd9e2fbc038907c0c2c6b417fcf7eed1a31e5fb5ad45af62c6f7
+DIST translate-3.15.1.gh.tar.gz 1169823 BLAKE2B f9db9be1c90c82000e5a35c9a1321a7a4de46f3efaddeaa57a418443203b04dc6d2c1ab9bd4d126c91fb86024d991682ed5e1acecb9e1aa6078ce140dcccba4e SHA512 e9e2eb5995e69827d10dff31e506e23f3aeea08a7edcfa11a02c7e02fe6ece3612aaf4d3109fe27a71e224f52488cf77690c786c4af4781a018af715a7eff145
diff --git a/dev-python/translate-toolkit/translate-toolkit-3.15.1.ebuild b/dev-python/translate-toolkit/translate-toolkit-3.15.1.ebuild
new file mode 100644
index 000000000000..9af4d0313f20
--- /dev/null
+++ b/dev-python/translate-toolkit/translate-toolkit-3.15.1.ebuild
@@ -0,0 +1,119 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{10..12} )
+PYTHON_REQ_USE="sqlite"
+
+inherit distutils-r1
+
+MY_P=translate-${PV}
+DESCRIPTION="Toolkit to convert between many translation formats"
+HOMEPAGE="
+	https://github.com/translate/translate/
+	https://pypi.org/project/translate-toolkit/
+"
+SRC_URI="
+	https://github.com/translate/translate/archive/${PV}.tar.gz
+		-> ${MY_P}.gh.tar.gz
+"
+S="${WORKDIR}"/${MY_P}
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~x86"
+IUSE="+html +ical +ini +subtitles +yaml"
+
+RDEPEND="
+	app-text/iso-codes
+	>=dev-python/chardet-3.0.4[${PYTHON_USEDEP}]
+	dev-python/cheroot[${PYTHON_USEDEP}]
+	>=dev-python/levenshtein-0.12.0[${PYTHON_USEDEP}]
+	>=dev-python/lxml-4.3.1[${PYTHON_USEDEP}]
+	>=dev-python/mistletoe-1.1.0[${PYTHON_USEDEP}]
+	>=dev-python/pyparsing-3[${PYTHON_USEDEP}]
+	dev-python/ruamel-yaml[${PYTHON_USEDEP}]
+	>=dev-python/cwcwidth-0.1.9[${PYTHON_USEDEP}]
+	sys-devel/gettext
+	html? ( dev-python/utidylib[${PYTHON_USEDEP}] )
+	ical? ( dev-python/vobject[${PYTHON_USEDEP}] )
+	ini? ( >=dev-python/iniparse-0.5[${PYTHON_USEDEP}] )
+	subtitles? ( media-video/gaupol[${PYTHON_USEDEP}] )
+	yaml? ( dev-python/pyyaml[${PYTHON_USEDEP}] )
+"
+# Technically, the test suite also has undeclared dependency
+# on dev-python/snapshottest but all the tests using it are broken
+# anyway, so we skip them.
+BDEPEND="
+	test? (
+		dev-python/phply[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+src_test() {
+	# unfortunately, this bad quality package doesn't support XDG_DATA_DIRS
+	# correctly, so we need to reassemble all data files in a single directory
+	local -x XDG_DATA_HOME=${T}/share
+	cp -r translate/share "${T}/" || die
+	cp -r "${ESYSROOT}/usr/share"/gaupol "${XDG_DATA_HOME}"/ || die
+
+	distutils-r1_src_test
+}
+
+python_test() {
+	local EPYTEST_DESELECT=(
+		# Fails with network-sandbox (and even with it off but w/ softer fail)
+		'tests/xliff_conformance/test_xliff_conformance.py::test_open_office_to_xliff'
+		'tests/xliff_conformance/test_xliff_conformance.py::test_po_to_xliff'
+		# all tests based on snapshottest are broken and I'm too tired
+		# to figure this out
+		tests/translate/tools/test_pocount.py::test_{cases,output}
+		tests/translate/tools/test_junitmsgfmt.py::test_output
+	)
+	local EPYTEST_IGNORE=(
+		# unpackaged fluent.*
+		tests/translate/storage/test_fluent.py
+		# changes directory and does not change it back, sigh
+		tests/odf_xliff/test_odf_xliff.py
+	)
+
+	if ! use ini; then
+		EPYTEST_IGNORE+=(
+			translate/convert/test_ini2po.py
+			translate/convert/test_po2ini.py
+		)
+	fi
+
+	if ! use subtitles; then
+		EPYTEST_IGNORE+=(
+			translate/storage/test_subtitles.py
+		)
+	fi
+
+	local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+	epytest
+}
+
+python_install_all() {
+	distutils-r1_python_install_all
+
+	insinto /usr
+	doins -r translate/share
+
+	if ! use html; then
+		rm "${ED}"/usr/bin/{html2po,po2html} || die
+	fi
+	if ! use ical; then
+		rm "${ED}"/usr/bin/{ical2po,po2ical} || die
+	fi
+	if ! use ini; then
+		rm "${ED}"/usr/bin/{ini2po,po2ini} || die
+	fi
+	if ! use subtitles; then
+		rm "${ED}"/usr/bin/{sub2po,po2sub} || die
+	fi
+}
-- 
cgit v1.2.3