From c07672e604992879ebec37ae4dfe03aa80702d4b Mon Sep 17 00:00:00 2001
From: Hans de Graaff <graaff@gentoo.org>
Date: Thu, 7 Aug 2025 08:37:10 +0200
Subject: dev-ruby/async-container: add 0.25.0

Signed-off-by: Hans de Graaff <graaff@gentoo.org>
---
 .../async-container/async-container-0.25.0.ebuild  | 43 ++++++++++++++++++++++
 1 file changed, 43 insertions(+)
 create mode 100644 dev-ruby/async-container/async-container-0.25.0.ebuild

(limited to 'dev-ruby/async-container/async-container-0.25.0.ebuild')

diff --git a/dev-ruby/async-container/async-container-0.25.0.ebuild b/dev-ruby/async-container/async-container-0.25.0.ebuild
new file mode 100644
index 000000000000..306e20fb906b
--- /dev/null
+++ b/dev-ruby/async-container/async-container-0.25.0.ebuild
@@ -0,0 +1,43 @@
+# Copyright 2022-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+USE_RUBY="ruby32 ruby33 ruby34"
+
+RUBY_FAKEGEM_RECIPE_TEST="sus"
+RUBY_FAKEGEM_EXTRADOC="readme.md releases.md"
+RUBY_FAKEGEM_GEMSPEC="${PN}.gemspec"
+
+inherit ruby-fakegem
+
+DESCRIPTION="Abstract container-based parallelism using threads and processes"
+HOMEPAGE="https://github.com/socketry/async-container"
+SRC_URI="https://github.com/socketry/async-container/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="$(ver_cut 1)"
+KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~ppc ~ppc64 ~riscv ~sparc ~x86"
+IUSE="test"
+
+ruby_add_rdepend ">=dev-ruby/async-2.22:2"
+
+ruby_add_bdepend "test? (
+	dev-ruby/bundler
+)"
+
+all_ruby_prepare() {
+	sed -i -E 's/require_relative "(.+)"/require File.expand_path("\1")/g' "${RUBY_FAKEGEM_GEMSPEC}" || die
+
+	# spec/async/container/notify/pipe_spec.rb directly executes "bundler" command,
+	# so we can't just wipe out gems.rb as usual.  also must remove covered from gemspec
+	# for this reason.
+	sed -i -E 's/gem ".+"//g' "gems.rb" || die
+	sed -i -e '/spec.add_development_dependency "covered"/ s:^:#:' ${RUBY_FAKEGEM_GEMSPEC} || die
+
+	# Avoid test that depends on unpackaged "bake"
+	rm -f test/async/container/notify/log.rb || die
+
+	# Avoid test dependency on unpackaged covered
+	rm -f config/sus.rb || die
+}
-- 
cgit v1.2.3