From 97dd93355d6ccaca04d15f3d3d2fa76d794839f7 Mon Sep 17 00:00:00 2001
From: Hans de Graaff <graaff@gentoo.org>
Date: Sun, 23 Oct 2022 11:41:47 +0200
Subject: dev-ruby/async: add 2.2.1, fix tests for 1.x

Signed-off-by: Hans de Graaff <graaff@gentoo.org>
---
 dev-ruby/async/async-2.2.1.ebuild | 42 +++++++++++++++++++++++++++++++++++++++
 1 file changed, 42 insertions(+)
 create mode 100644 dev-ruby/async/async-2.2.1.ebuild

(limited to 'dev-ruby/async/async-2.2.1.ebuild')

diff --git a/dev-ruby/async/async-2.2.1.ebuild b/dev-ruby/async/async-2.2.1.ebuild
new file mode 100644
index 000000000000..6e2688dbe2b7
--- /dev/null
+++ b/dev-ruby/async/async-2.2.1.ebuild
@@ -0,0 +1,42 @@
+# Copyright 2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+USE_RUBY="ruby31"
+
+RUBY_FAKEGEM_RECIPE_TEST="rspec3"
+RUBY_FAKEGEM_EXTRADOC="readme.md"
+RUBY_FAKEGEM_GEMSPEC="${PN}.gemspec"
+
+inherit ruby-fakegem
+
+DESCRIPTION="A concurrency framework for Ruby"
+HOMEPAGE="https://github.com/socketry/async"
+SRC_URI="https://github.com/socketry/async/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="$(ver_cut 1)"
+KEYWORDS="~amd64 ~sparc"
+IUSE=""
+
+ruby_add_rdepend ">=dev-ruby/console-1.10:1
+	dev-ruby/io-event:1.1
+	>=dev-ruby/timers-4.1:4"
+
+ruby_add_bdepend "test? (
+	>=dev-ruby/async-rspec-1.1:1
+	dev-ruby/benchmark-ips
+)"
+
+all_ruby_prepare() {
+	sed -i -E 's/require_relative "(.+)"/require File.expand_path("\1")/g' "${RUBY_FAKEGEM_GEMSPEC}" || die
+
+	# network tests
+	rm -f \
+		"spec/net/http_spec.rb" \
+		"spec/async/scheduler/address_spec.rb" \
+		"spec/async/scheduler/io_spec.rb" || die
+
+	sed -i -E 's/require '"'"'covered\/rspec'"'"'//g' "spec/spec_helper.rb" || die
+}
-- 
cgit v1.2.3