From 71202b24fefcf9bb4388384c4bae02bd0f67b104 Mon Sep 17 00:00:00 2001
From: Hans de Graaff <graaff@gentoo.org>
Date: Wed, 1 Aug 2018 07:30:53 +0200
Subject: dev-ruby/elasticsearch-api: add 6.1.0

Package-Manager: Portage-2.3.40, Repoman-2.3.9
---
 .../elasticsearch-api-6.1.0.ebuild                 | 50 ++++++++++++++++++++++
 1 file changed, 50 insertions(+)
 create mode 100644 dev-ruby/elasticsearch-api/elasticsearch-api-6.1.0.ebuild

(limited to 'dev-ruby/elasticsearch-api/elasticsearch-api-6.1.0.ebuild')

diff --git a/dev-ruby/elasticsearch-api/elasticsearch-api-6.1.0.ebuild b/dev-ruby/elasticsearch-api/elasticsearch-api-6.1.0.ebuild
new file mode 100644
index 000000000000..3cfa06e9494e
--- /dev/null
+++ b/dev-ruby/elasticsearch-api/elasticsearch-api-6.1.0.ebuild
@@ -0,0 +1,50 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+USE_RUBY="ruby23 ruby24 ruby25"
+RUBY_FAKEGEM_GEMSPEC="${PN}.gemspec"
+RUBY_FAKEGEM_TASK_DOC=doc
+
+inherit ruby-fakegem eapi7-ver
+
+MY_P=elasticsearch-ruby-${PV}
+DESCRIPTION="Ruby integrations for ES, elasticsearch-api module"
+HOMEPAGE="https://github.com/elastic/elasticsearch-ruby"
+SRC_URI="https://github.com/elastic/elasticsearch-ruby/archive/v${PV}.tar.gz -> ${MY_P}.tar.gz"
+
+LICENSE="Apache-2.0"
+SLOT="$(ver_cut 1)"
+KEYWORDS="~amd64"
+IUSE=""
+
+ruby_add_rdepend "
+	dev-ruby/multi_json
+"
+ruby_add_bdepend "
+	doc? ( dev-ruby/yard )
+	test? (
+		dev-ruby/ansi
+		dev-ruby/elasticsearch-transport
+		dev-ruby/mocha:1.0
+		dev-ruby/pry
+		dev-ruby/shoulda-context
+	)
+"
+
+# Tests need additional modules (at least 'turn') packaged. Then someone
+# should look into running them and so on.
+RESTRICT="test"
+
+RUBY_S=${MY_P}/${PN}
+
+all_ruby_prepare() {
+	# fix to work without git
+	sed -i -e 's/git ls-files/find -type f/' *.gemspec || die
+
+	# remove useless dependencies from Rakefile
+	sed -e '/bundler/d' \
+		-e '/require.*cane/,/end/d' \
+		-i Rakefile || die
+}
-- 
cgit v1.2.3