From 070ae94ecd70d7c22d8f7d7ad1ceb6543ca69439 Mon Sep 17 00:00:00 2001
From: Hans de Graaff <graaff@gentoo.org>
Date: Wed, 16 Apr 2025 19:15:21 +0200
Subject: dev-ruby/elasticsearch: add 8.18.0

Signed-off-by: Hans de Graaff <graaff@gentoo.org>
---
 dev-ruby/elasticsearch/elasticsearch-8.18.0.ebuild | 55 ++++++++++++++++++++++
 1 file changed, 55 insertions(+)
 create mode 100644 dev-ruby/elasticsearch/elasticsearch-8.18.0.ebuild

(limited to 'dev-ruby/elasticsearch/elasticsearch-8.18.0.ebuild')

diff --git a/dev-ruby/elasticsearch/elasticsearch-8.18.0.ebuild b/dev-ruby/elasticsearch/elasticsearch-8.18.0.ebuild
new file mode 100644
index 000000000000..de8538d090f6
--- /dev/null
+++ b/dev-ruby/elasticsearch/elasticsearch-8.18.0.ebuild
@@ -0,0 +1,55 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+USE_RUBY="ruby31 ruby32 ruby33"
+
+RUBY_FAKEGEM_GEMSPEC="${PN}.gemspec"
+RUBY_FAKEGEM_RECIPE_TEST="rspec3"
+
+inherit ruby-fakegem
+
+MY_P=elasticsearch-ruby-${PV}
+DESCRIPTION="Ruby integrations for ES, elasticsearch module"
+HOMEPAGE="https://github.com/elastic/elasticsearch-ruby"
+SRC_URI="https://github.com/elastic/elasticsearch-ruby/archive/v${PV}.tar.gz -> ${MY_P}.tar.gz"
+
+LICENSE="Apache-2.0"
+SLOT="$(ver_cut 1)"
+KEYWORDS="~amd64"
+IUSE="test"
+
+ruby_add_rdepend "
+	~dev-ruby/elasticsearch-api-${PV}
+	>=dev-ruby/elastic-transport-8.3:8
+"
+ruby_add_bdepend "
+	doc? ( dev-ruby/yard )
+	test? (
+		dev-ruby/ansi
+		dev-ruby/base64
+		dev-ruby/mocha:2
+		dev-ruby/pry
+		dev-ruby/shoulda-context
+	)
+"
+
+RUBY_S=${MY_P}/${PN}
+
+all_ruby_prepare() {
+	# fix to work without git
+	sed -i -e 's/git ls-files/find * -type f/' *.gemspec || die
+
+	# remove useless dependencies from Rakefile
+	sed -e '/bundler/d' \
+		-e '/require.*cane/,/end/d' \
+		-i Rakefile || die
+
+	sed -e '/documentation/ s:^:#:' \
+		-i spec/spec_helper.rb || die
+
+	# Avoid spec requiring a running elasticsearch server
+	rm -f spec/integration/{characters_escaping,client_integration,validation_integration}_spec.rb || die
+	rm -f spec/integration/helpers/*_helper_spec.rb || die
+}
-- 
cgit v1.2.3