blob: 7485aac0512e612ee6c3bba659296f88983e732e (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
|
# Copyright 1999-2025 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
DISTUTILS_USE_PEP517=setuptools
PYTHON_COMPAT=( python3_{11..13} )
inherit distutils-r1 toolchain-funcs desktop
MY_PV="$(ver_cut 1-2)"
DESCRIPTION="Additional userspace utils to assist with AppArmor profile management"
HOMEPAGE="https://gitlab.com/apparmor/apparmor/wikis/home"
SRC_URI="https://launchpad.net/apparmor/${MY_PV}/${PV}/+download/apparmor-${PV}.tar.gz"
S=${WORKDIR}/apparmor-${PV}
LICENSE="GPL-2"
SLOT="0"
KEYWORDS="amd64 arm64 ~ppc64 ~riscv"
REQUIRED_USE="${PYTHON_REQUIRED_USE}"
# Needs fixing to use the right Python
RESTRICT="test"
COMMON_DEPEND="
~sys-libs/libapparmor-${PV}
${PYTHON_DEPS}
"
DEPEND="
${COMMON_DEPEND}
sys-devel/gettext
"
RDEPEND="
${COMMON_DEPEND}
dev-python/notify2[${PYTHON_USEDEP}]
dev-python/psutil[${PYTHON_USEDEP}]
~sys-apps/apparmor-${PV}
~sys-libs/libapparmor-${PV}[python,${PYTHON_USEDEP}]
"
PATCHES=(
"${FILESDIR}/${PN}-4.0.3-binutils-Fix-missing-include-limits.h.patch"
"${FILESDIR}/${PN}-4.0.3-py3.13.patch"
)
src_prepare() {
default
sed -i binutils/Makefile \
-e 's/Bstatic/Bdynamic/g' || die
sed -i utils/aa-remove-unknown \
-e 's#^\(APPARMOR_FUNCTIONS=\).*#\1/usr/libexec/rc.apparmor.functions#' || die
}
src_compile() {
python_setup
pushd utils > /dev/null || die
# launches non-make subprocesses causing "make jobserver unavailable"
# error messages to appear in generated code
emake -j1
popd > /dev/null || die
pushd binutils > /dev/null || die
export EXTRA_CFLAGS="${CFLAGS}"
emake CC="$(tc-getCC)" USE_SYSTEM=1
popd > /dev/null || die
}
src_test() {
pushd utils > /dev/null || die
python_foreach_impl emake USE_SYSTEM=1 PYFLAKES=true check
popd > /dev/null || die
}
src_install() {
pushd utils > /dev/null || die
emake DESTDIR="${D}" VIM_INSTALL_PATH="${D}/usr/share/vim/vimfiles/syntax" install
install_python() {
local -x PYTHONDONTWRITEBYTECODE=
"${PYTHON}" "${S}"/utils/python-tools-setup.py install \
--prefix="${EPREFIX}"/usr \
--root="${D}" \
--optimize 2 \
--version=${PV} || die
}
python_foreach_impl install_python
python_replicate_script "${D}"/usr/bin/aa-easyprof \
"${D}"/usr/sbin/aa-{audit,autodep,cleanprof,complain,disable,enforce,genprof,logprof,mergeprof,notify,unconfined}
domenu aa-notify.desktop
popd > /dev/null || die
pushd binutils > /dev/null || die
emake install DESTDIR="${D}" USE_SYSTEM=1
popd > /dev/null || die
}
|
