blob: fd5014c3c82034b85b809afdbb372dcd4f7f0af4 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
|
# Copyright 2019-2025 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
inherit meson vala
DESCRIPTION="glib library for communicating with snapd"
HOMEPAGE="https://snapcraft.io/"
SRC_URI="https://github.com/canonical/snapd-glib/archive/refs/tags/${PV}.tar.gz -> ${P}.tar.gz"
LICENSE="LGPL-3"
SLOT="0/1"
KEYWORDS="~amd64"
IUSE="doc introspection qml qt6 vala"
REQUIRED_USE="
qml? ( qt6 )
vala? ( introspection )
"
BDEPEND="
virtual/pkgconfig
sys-devel/gettext
qt6? ( dev-qt/qttools:6[linguist] )
"
DEPEND="
dev-libs/json-glib
dev-libs/glib:2
dev-util/glib-utils
net-libs/libsoup:3.0
doc? (
dev-build/gtk-doc-am
dev-util/gi-docgen
dev-util/gtk-doc
)
introspection? ( >=dev-libs/gobject-introspection-1.82.0-r2 )
qml? (
qt6? ( dev-qt/qtdeclarative:6 )
)
qt6? (
dev-qt/qtbase:6[network,widgets]
)
vala? ( $(vala_depend) )
"
RDEPEND="${DEPEND}
app-containers/snapd
"
pkg_setup() {
vala_setup
}
src_configure() {
local emesonargs=(
"$(meson_use doc docs)"
"$(meson_use introspection)"
"$(meson_use qml qml-bindings)"
"$(meson_use qt6)"
"$(meson_use vala vala-bindings)"
-Dsoup2=false
-Dqt5=false
)
meson_src_configure
}
src_install() {
meson_src_install
if use doc; then
dodir /usr/share/gtk-doc/html/
mv "${ED}/usr/share/doc/${PN}" "${ED}/usr/share/gtk-doc/html/${PF}" || die
fi
}
|
