kde-frameworks/kdelibs4support: 5.84.0 version bump

Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

2 files changed, 99 insertions, 0 deletions

diff --git a/kde-frameworks/kdelibs4support/Manifest b/kde-frameworks/kdelibs4support/Manifest
new file mode 100644
index 00000000000..1b6c255f160
--- /dev/null
+++ b/kde-frameworks/kdelibs4support/Manifest
@@ -0,0 +1 @@
+DIST kdelibs4support-5.84.0.tar.xz 3553320 BLAKE2B ba9ed75ef8a187411a72677dd57c13b8fa9db5df5f151f14cfe4bfa4a59998f3d56bf0ef9a5df0c99a2ec9670977b741ad041ec27fb02a53dcaa519c7f56caad SHA512 9c4cfd20ad16ba8bd4f8feeade4142e8126c37d5967f61672282e6f98f5cd505f2e4fec36700b15451c08549416c0bb81ce3bf450bdd25e5ef11670c093c51ff
diff --git a/kde-frameworks/kdelibs4support/kdelibs4support-5.84.0.ebuild b/kde-frameworks/kdelibs4support/kdelibs4support-5.84.0.ebuild
new file mode 100644
index 00000000000..8cf2a1aa39d
--- /dev/null
+++ b/kde-frameworks/kdelibs4support/kdelibs4support-5.84.0.ebuild
@@ -0,0 +1,98 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+ECM_HANDBOOK="true"
+ECM_QTHELP="false"
+PVCUT=$(ver_cut 1-2)
+QTMIN=5.15.2
+VIRTUALX_REQUIRED="test"
+inherit ecm kde.org
+
+DESCRIPTION="Framework easing the development transition from KDELibs 4 to KF 5"
+LICENSE="LGPL-2+"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~x86"
+IUSE="X"
+
+RESTRICT+=" test"
+
+BDEPEND="
+	dev-lang/perl
+	dev-perl/URI
+"
+COMMON_DEPEND="
+	app-text/docbook-xml-dtd:4.2
+	dev-libs/openssl:0
+	>=dev-qt/qtdbus-${QTMIN}:5
+	>=dev-qt/qtgui-${QTMIN}:5
+	>=dev-qt/qtnetwork-${QTMIN}:5[ssl]
+	>=dev-qt/qtprintsupport-${QTMIN}:5
+	>=dev-qt/qtsvg-${QTMIN}:5
+	>=dev-qt/qttest-${QTMIN}:5
+	>=dev-qt/qtwidgets-${QTMIN}:5
+	=kde-frameworks/kauth-${PVCUT}*:5
+	=kde-frameworks/kcodecs-${PVCUT}*:5
+	=kde-frameworks/kcompletion-${PVCUT}*:5
+	=kde-frameworks/kconfig-${PVCUT}*:5
+	=kde-frameworks/kconfigwidgets-${PVCUT}*:5
+	=kde-frameworks/kcoreaddons-${PVCUT}*:5
+	=kde-frameworks/kcrash-${PVCUT}*:5
+	=kde-frameworks/kdbusaddons-${PVCUT}*:5
+	>=kde-frameworks/kded-${PVCUT}:5
+	=kde-frameworks/kdoctools-${PVCUT}*:5
+	=kde-frameworks/kemoticons-${PVCUT}*:5
+	=kde-frameworks/kglobalaccel-${PVCUT}*:5
+	=kde-frameworks/kguiaddons-${PVCUT}*:5
+	=kde-frameworks/ki18n-${PVCUT}*:5
+	=kde-frameworks/kiconthemes-${PVCUT}*:5
+	=kde-frameworks/kio-${PVCUT}*:5
+	=kde-frameworks/kitemviews-${PVCUT}*:5
+	=kde-frameworks/kjobwidgets-${PVCUT}*:5
+	=kde-frameworks/knotifications-${PVCUT}*:5
+	=kde-frameworks/kparts-${PVCUT}*:5
+	=kde-frameworks/kservice-${PVCUT}*:5
+	=kde-frameworks/ktextwidgets-${PVCUT}*:5
+	=kde-frameworks/kunitconversion-${PVCUT}*:5
+	=kde-frameworks/kwidgetsaddons-${PVCUT}*:5
+	=kde-frameworks/kwindowsystem-${PVCUT}*:5
+	=kde-frameworks/kxmlgui-${PVCUT}*:5
+	=kde-frameworks/solid-${PVCUT}*:5
+	virtual/libintl
+	X? (
+		>=dev-qt/qtx11extras-${QTMIN}:5
+		x11-libs/libICE
+		x11-libs/libSM
+		x11-libs/libX11
+		x11-libs/libxcb
+	)
+"
+DEPEND="${COMMON_DEPEND}
+	test? ( >=dev-qt/qtconcurrent-${QTMIN}:5 )
+	X? ( x11-base/xorg-proto )
+"
+RDEPEND="${COMMON_DEPEND}
+	>=dev-qt/qtxml-${QTMIN}:5
+	=kde-frameworks/kinit-${PVCUT}*:5
+	=kde-frameworks/kitemmodels-${PVCUT}*:5
+"
+
+PATCHES=(
+	"${FILESDIR}/${PN}-5.80.0-no-kdesignerplugin.patch"
+	"${FILESDIR}/${PN}-5.82.0-unused-dep.patch"
+)
+
+src_prepare() {
+	ecm_src_prepare
+	if ! use handbook; then
+		sed -e "/kdoctools_install/ s/^/#DONT/" -i CMakeLists.txt || die
+	fi
+}
+
+src_configure() {
+	local mycmakeargs=(
+		$(cmake_use_find_package X X11)
+	)
+
+	ecm_src_configure
+}