kde-apps/dolphin-plugins-subversion: 20.08.2 version bump

Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

2 files changed, 67 insertions, 0 deletions

diff --git a/kde-apps/dolphin-plugins-subversion/Manifest b/kde-apps/dolphin-plugins-subversion/Manifest
new file mode 100644
index 00000000000..39d905585ff
--- /dev/null
+++ b/kde-apps/dolphin-plugins-subversion/Manifest
@@ -0,0 +1 @@
+DIST dolphin-plugins-20.08.2.tar.xz 229440 BLAKE2B 53d8c1c16a9ba5abcb3164cd4d30769506c4dfaaab148eed070185b17d00fc5583b5dbb28b163794e187da8e0d64435d904fb8ffc99e8625b8096bd96dbd94ab SHA512 c854c3a7c918c9a8be1da41d9d4f8039b9c8e38ba4782ae064ea688fed51966b9749ce009b2f96bcac0f92dbe36e5f826a45265eb29e3f2ec4740902485099d7
diff --git a/kde-apps/dolphin-plugins-subversion/dolphin-plugins-subversion-20.08.2.ebuild b/kde-apps/dolphin-plugins-subversion/dolphin-plugins-subversion-20.08.2.ebuild
new file mode 100644
index 00000000000..2bf6fd44a2d
--- /dev/null
+++ b/kde-apps/dolphin-plugins-subversion/dolphin-plugins-subversion-20.08.2.ebuild
@@ -0,0 +1,66 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+ECM_HANDBOOK="false"
+KDE_ORG_NAME="dolphin-plugins"
+MY_PLUGIN_NAME="svn"
+PVCUT=$(ver_cut 1-3)
+KFMIN=5.72.0
+QTMIN=5.14.2
+inherit ecm kde.org
+
+DESCRIPTION="Dolphin plugin for Subversion integration"
+HOMEPAGE="https://kde.org/applications/system/org.kde.dolphin_plugins"
+
+LICENSE="GPL-2" # TODO: CHECK
+SLOT="5"
+KEYWORDS="~amd64 ~arm64 ~x86"
+IUSE=""
+
+DEPEND="
+	>=dev-qt/qtgui-${QTMIN}:5
+	>=dev-qt/qtwidgets-${QTMIN}:5
+	>=kde-apps/dolphin-${PVCUT}:5
+	>=kde-frameworks/kcoreaddons-${KFMIN}:5
+	>=kde-frameworks/ki18n-${KFMIN}:5
+	>=kde-frameworks/kio-${KFMIN}:5
+	>=kde-frameworks/ktextwidgets-${KFMIN}:5
+"
+RDEPEND="${DEPEND}
+	!kde-apps/dolphin-plugins:5
+	dev-vcs/subversion
+	>=kde-apps/kompare-${PVCUT}:5
+"
+
+src_prepare() {
+	ecm_src_prepare
+	# solid, qtdbus only required by mountiso
+	ecm_punt_bogus_dep Qt5 DBus
+	ecm_punt_bogus_dep KF5 Solid
+	# kxmlgui, qtnetwork only required by dropbox
+	ecm_punt_bogus_dep Qt5 Network
+	ecm_punt_bogus_dep KF5 XmlGui
+	# delete non-${PN} translations
+	if [[ ${KDE_BUILD_TYPE} = release ]]; then
+		find po -type f -name "*po" -and -not -name "*${MY_PLUGIN_NAME}plugin" -delete || die
+	fi
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DBUILD_${MY_PLUGIN_NAME}=ON
+		-DBUILD_bazaar=OFF
+		-DBUILD_dropbox=OFF
+		-DBUILD_git=OFF
+		-DBUILD_hg=OFF
+		-DBUILD_mountiso=OFF
+	)
+	ecm_src_configure
+}
+
+src_install() {
+	ecm_src_install
+	rm "${D}"/usr/share/metainfo/org.kde.dolphin-plugins.metainfo.xml || die
+}