kde-misc/kweather: 23.04.1 version bump

Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

2 files changed, 56 insertions, 0 deletions

diff --git a/kde-misc/kweather/Manifest b/kde-misc/kweather/Manifest
new file mode 100644
index 00000000000..df7a858966f
--- /dev/null
+++ b/kde-misc/kweather/Manifest
@@ -0,0 +1 @@
+DIST kweather-23.04.1.tar.xz 1018640 BLAKE2B 1f616eb16940f9ac11767bef9fd5d97312dfe65d28ea654134bde465ce526a59bf808a453d02b5e39324c6d4426e9f2eeea626a3ad6e7c2d0a8689ee8834384e SHA512 bbc39084f461cef1d79427eb59cd1e8662876d53c740e7c3d0f08b97ecffec35cb96e7c3b4d044e8edc885fcc7f044b695e9b8838d19541d682699500acb32de
diff --git a/kde-misc/kweather/kweather-23.04.1.ebuild b/kde-misc/kweather/kweather-23.04.1.ebuild
new file mode 100644
index 00000000000..48cb59a05a1
--- /dev/null
+++ b/kde-misc/kweather/kweather-23.04.1.ebuild
@@ -0,0 +1,55 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+KDE_ORG_CATEGORY="utilities"
+ECM_TEST="false"
+KFMIN=5.104.0
+QTMIN=5.15.5
+inherit ecm gear.kde.org
+
+DESCRIPTION="Weather forecast application for Plasma with flat and dynamic/animated views"
+HOMEPAGE="https://apps.kde.org/kweather/"
+
+LICENSE="GPL-2+"
+SLOT="5"
+KEYWORDS="~amd64 ~arm64 ~ppc64 ~x86"
+
+DEPEND="
+	>=dev-libs/kirigami-addons-0.6:5
+	>=dev-libs/kweathercore-0.6:5
+	>=dev-qt/qtcharts-${QTMIN}:5[qml]
+	>=dev-qt/qtdeclarative-${QTMIN}:5
+	>=dev-qt/qtgui-${QTMIN}:5
+	>=dev-qt/qtnetwork-${QTMIN}:5
+	>=dev-qt/qtquickcontrols2-${QTMIN}:5
+	>=dev-qt/qtsvg-${QTMIN}:5
+	>=dev-qt/qtwidgets-${QTMIN}:5
+	>=kde-frameworks/kconfig-${KFMIN}:5
+	>=kde-frameworks/kcoreaddons-${KFMIN}:5
+	>=kde-frameworks/kholidays-${KFMIN}:5
+	>=kde-frameworks/ki18n-${KFMIN}:5
+	>=kde-frameworks/kirigami-${KFMIN}:5
+	>=kde-frameworks/knotifications-${KFMIN}:5
+	>=kde-frameworks/plasma-${KFMIN}:5
+"
+RDEPEND="${DEPEND}
+	>=dev-qt/qtgraphicaleffects-${QTMIN}:5
+	>=dev-qt/qtpositioning-${QTMIN}:5[geoclue]
+"
+
+src_prepare() {
+	ecm_src_prepare
+
+	sed -e "/include(ECMCheckOutboundLicense)/s/^/#DONT /" \
+		-e "/ecm_check_outbound_license/s/^/#DONT /" \
+		-i CMakeLists.txt || die # avoid cmake spam about python, reusetool
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DBUILD_PLASMOID=ON
+	)
+	ecm_src_configure
+}