kde-frameworks/purpose: 5.93.0 version bump

Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

2 files changed, 70 insertions, 0 deletions

diff --git a/kde-frameworks/purpose/Manifest b/kde-frameworks/purpose/Manifest
new file mode 100644
index 00000000000..5620a1e4993
--- /dev/null
+++ b/kde-frameworks/purpose/Manifest
@@ -0,0 +1 @@
+DIST purpose-5.93.0.tar.xz 173380 BLAKE2B 50fe2c210f2cca7bac12aed67d26876ea0501bf34f6cb23b849925d465cbb931bce20c6bf463b932aa7f01959358c41fba4567f331cccec13f23e97d5c04e490 SHA512 946dd6474f58100981e155d3dcae34260068d84b1e2931b8f1f794381e0e8d68e178287d0c702e7b8890d938c60952226dcbbef97e27d642decaa072a456d34c
diff --git a/kde-frameworks/purpose/purpose-5.93.0.ebuild b/kde-frameworks/purpose/purpose-5.93.0.ebuild
new file mode 100644
index 00000000000..0d2e408ffe6
--- /dev/null
+++ b/kde-frameworks/purpose/purpose-5.93.0.ebuild
@@ -0,0 +1,69 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+ECM_QTHELP="false"
+ECM_TEST="forceoptional"
+PVCUT=$(ver_cut 1-2)
+QTMIN=5.15.2
+inherit ecm kde.org optfeature xdg-utils
+
+DESCRIPTION="Library for providing abstractions to get the developer's purposes fulfilled"
+LICENSE="LGPL-2.1+"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~riscv ~x86"
+IUSE="bluetooth +kaccounts"
+
+# requires running environment
+RESTRICT="test"
+
+DEPEND="
+	>=dev-qt/qtdeclarative-${QTMIN}:5
+	>=dev-qt/qtgui-${QTMIN}:5
+	>=dev-qt/qtnetwork-${QTMIN}:5
+	>=dev-qt/qtwidgets-${QTMIN}:5
+	=kde-frameworks/kcoreaddons-${PVCUT}*:5
+	=kde-frameworks/ki18n-${PVCUT}*:5
+	=kde-frameworks/kio-${PVCUT}*:5
+	=kde-frameworks/kirigami-${PVCUT}*:5
+	=kde-frameworks/knotifications-${PVCUT}*:5
+	=kde-frameworks/prison-${PVCUT}*:5
+	kaccounts? (
+		>=kde-apps/kaccounts-integration-19.04.3:5
+		net-libs/accounts-qt
+	)
+"
+RDEPEND="${DEPEND}
+	>=dev-qt/qtquickcontrols-${QTMIN}:5
+	>=dev-qt/qtquickcontrols2-${QTMIN}:5
+	>=kde-frameworks/kdeclarative-${PVCUT}:5
+	bluetooth? ( =kde-frameworks/bluez-qt-${PVCUT}*:5 )
+	kaccounts? ( net-libs/accounts-qml )
+"
+
+src_prepare() {
+	ecm_src_prepare
+
+	use bluetooth ||
+		cmake_run_in src/plugins cmake_comment_add_subdirectory bluetooth
+}
+
+src_configure() {
+	local mycmakeargs=(
+		$(cmake_use_find_package kaccounts KAccounts)
+	)
+
+	ecm_src_configure
+}
+
+pkg_postinst() {
+	if [[ -z "${REPLACING_VERSIONS}" ]]; then
+		optfeature "Send through KDE Connect" kde-misc/kdeconnect
+	fi
+	ecm_pkg_postinst
+	xdg_icon_cache_update
+}
+
+pkg_postrm() {
+	xdg_icon_cache_update
+}