kde-apps/k3b: 24.12.0 version bump

Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

2 files changed, 111 insertions, 0 deletions

diff --git a/kde-apps/k3b/Manifest b/kde-apps/k3b/Manifest
index f82bd0f88fe..d57cba1f3e7 100644
--- a/kde-apps/k3b/Manifest
+++ b/kde-apps/k3b/Manifest
@@ -1 +1,2 @@
 DIST k3b-24.11.90.tar.xz 10697116 BLAKE2B a2e15507f4f66cca8b3ac14ae61181a6e93a9f02050b8ffc3ead839dd23b68d22c69fcc4490f765b9e8ed56094ddc95894fc7359fef24fefabaf9d8ae68bfbc7 SHA512 f97cb28395f00cea0a2091151d3986b7d20a408df948f0d48830f9c8d856daa3810c88f485d295508a3db7c19d2c486de947715bf641ade2ecba7a39e955aff6
+DIST k3b-24.12.0.tar.xz 10696880 BLAKE2B 9f91b638898500a68a263dc931d878438f06f03358315b7ad6cb4e5e68cbe784ca78e1a3b71934ee6351d46a052215c58fd964090794f6fab8a60ce4a63e9536 SHA512 e312233ca2bdb5ef3654fb4d62f3e411d808c37223ad190d4bb4a2ce143c002f6033c794174b0cd3d7078d010a4433d11fa06bf6d022f33594188c64a2730e66
diff --git a/kde-apps/k3b/k3b-24.12.0.ebuild b/kde-apps/k3b/k3b-24.12.0.ebuild
new file mode 100644
index 00000000000..aae01d054b7
--- /dev/null
+++ b/kde-apps/k3b/k3b-24.12.0.ebuild
@@ -0,0 +1,110 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+ECM_HANDBOOK="forceoptional"
+ECM_TEST="true"
+PVCUT=$(ver_cut 1-3)
+KFMIN=6.5.0
+QTMIN=6.7.2
+inherit ecm flag-o-matic gear.kde.org
+
+DESCRIPTION="Full-featured burning and ripping application based on KDE Frameworks"
+HOMEPAGE="https://apps.kde.org/k3b/ https://userbase.kde.org/K3b"
+
+LICENSE="GPL-2 FDL-1.2"
+SLOT="6"
+KEYWORDS="~amd64 ~arm64 ~ppc64 ~riscv ~x86"
+IUSE="dvd ffmpeg flac lame mad musepack sndfile sox taglib vcd vorbis webengine"
+
+REQUIRED_USE="flac? ( taglib ) lame? ( taglib ) sox? ( taglib )"
+
+DEPEND="
+	>=dev-qt/qtbase-${QTMIN}:6[dbus,gui,network,widgets,xml]
+	>=kde-apps/libkcddb-${PVCUT}:6
+	>=kde-frameworks/karchive-${KFMIN}:6
+	>=kde-frameworks/kbookmarks-${KFMIN}:6
+	>=kde-frameworks/kcmutils-${KFMIN}:6
+	>=kde-frameworks/kcompletion-${KFMIN}:6
+	>=kde-frameworks/kconfig-${KFMIN}:6
+	>=kde-frameworks/kconfigwidgets-${KFMIN}:6
+	>=kde-frameworks/kcoreaddons-${KFMIN}:6
+	>=kde-frameworks/kfilemetadata-${KFMIN}:6[taglib?]
+	>=kde-frameworks/ki18n-${KFMIN}:6
+	>=kde-frameworks/kiconthemes-${KFMIN}:6
+	>=kde-frameworks/kio-${KFMIN}:6
+	>=kde-frameworks/kjobwidgets-${KFMIN}:6
+	>=kde-frameworks/knewstuff-${KFMIN}:6
+	>=kde-frameworks/knotifications-${KFMIN}:6
+	>=kde-frameworks/knotifyconfig-${KFMIN}:6
+	>=kde-frameworks/kwidgetsaddons-${KFMIN}:6
+	>=kde-frameworks/kxmlgui-${KFMIN}:6
+	>=kde-frameworks/solid-${KFMIN}:6
+	media-libs/libsamplerate
+	dvd? ( media-libs/libdvdread:= )
+	ffmpeg? ( >=media-video/ffmpeg-4.4.0:0= )
+	flac? ( >=media-libs/flac-1.2:=[cxx] )
+	lame? ( media-sound/lame )
+	mad? ( media-libs/libmad )
+	musepack? ( >=media-sound/musepack-tools-444 )
+	sndfile? ( media-libs/libsndfile )
+	taglib? ( >=media-libs/taglib-1.5:= )
+	vorbis? (
+		media-libs/libogg
+		media-libs/libvorbis
+	)
+	webengine? ( >=dev-qt/qtwebengine-${QTMIN}:6 )
+"
+RDEPEND="${DEPEND}
+	app-cdr/cdrdao
+	app-cdr/cdrtools
+	dev-libs/libburn
+	media-sound/cdparanoia
+	dvd? ( >=app-cdr/dvd+rw-tools-7 )
+	sox? ( media-sound/sox )
+	vcd? ( media-video/vcdimager )
+"
+
+DOCS+=( ChangeLog {FAQ,PERMISSIONS,README}.txt )
+
+src_configure() {
+	# -Werror=odr, -Werror=lto-type-mismatch
+	# https://bugs.gentoo.org/924376
+	# https://bugs.kde.org/show_bug.cgi?id=492571
+	filter-lto
+
+	local mycmakeargs=(
+		-DK3B_BUILD_API_DOCS=OFF
+		-DK3B_BUILD_EXTERNAL_ENCODER_PLUGIN=ON
+		-DK3B_BUILD_WAVE_DECODER_PLUGIN=ON
+		-DK3B_ENABLE_HAL_SUPPORT=OFF
+		-DK3B_DEBUG=$(usex debug)
+		-DK3B_ENABLE_DVD_RIPPING=$(usex dvd)
+		-DK3B_BUILD_FFMPEG_DECODER_PLUGIN=$(usex ffmpeg)
+		-DK3B_BUILD_FLAC_DECODER_PLUGIN=$(usex flac)
+		-DK3B_BUILD_LAME_ENCODER_PLUGIN=$(usex lame)
+		-DK3B_BUILD_MAD_DECODER_PLUGIN=$(usex mad)
+		-DK3B_BUILD_MUSE_DECODER_PLUGIN=$(usex musepack)
+		-DK3B_BUILD_SNDFILE_DECODER_PLUGIN=$(usex sndfile)
+		-DK3B_BUILD_SOX_ENCODER_PLUGIN=$(usex sox)
+		-DK3B_ENABLE_TAGLIB=$(usex taglib)
+		-DK3B_BUILD_OGGVORBIS_DECODER_PLUGIN=$(usex vorbis)
+		-DK3B_BUILD_OGGVORBIS_ENCODER_PLUGIN=$(usex vorbis)
+		$(cmake_use_find_package webengine Qt6WebEngineWidgets)
+	)
+
+	ecm_src_configure
+}
+
+pkg_postinst() {
+	ecm_pkg_postinst
+
+	elog "If you get warnings on start-up, uncheck the \"Check system"
+	elog "configuration\" option in the \"Misc\" settings window."
+	elog
+	local group=cdrom
+	use kernel_linux || group=operator
+	elog "Make sure you have proper read/write permissions on optical device(s)."
+	elog "Usually, it is sufficient to be in the ${group} group."
+}