kde-apps/kate-addons: 24.11.90 version bump

Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

2 files changed, 101 insertions, 0 deletions

diff --git a/kde-apps/kate-addons/Manifest b/kde-apps/kate-addons/Manifest
index 4831ca0ebe2..253f6db0e90 100644
--- a/kde-apps/kate-addons/Manifest
+++ b/kde-apps/kate-addons/Manifest
@@ -1 +1,2 @@
 DIST kate-24.11.80.tar.xz 8297320 BLAKE2B 9fca56748a3d14f4b2b2b603bd1bca67c9bf489c7aa1390410927870d840feddffc8db997870376fd046806031357847a22c954feda6b222a54fc0f353c73eb1 SHA512 974f147f24400646d43a345ed4dbdb38f0e2648ee05cc43396c00c1cb2376a3d8be85fc199a7f99b9dfeb03c0f885931672708b711ee43078743432531797841
+DIST kate-24.11.90.tar.xz 8299616 BLAKE2B 7d8b395e8ea54a51271b37c15c6e80e3d780e8d59951b11cae6f6402def1a5e33ff8c977007734f1da65d49173efddf4604dfeab63818fd88afb198dc9ae0b47 SHA512 e4ebedd8d263d2a6a541ed115edcb7ed8248db48f7bd6daaf9c11bc2d5d0a0978d2e4edf40c2db72a02a95b364e5ae897315f606ee4c7b0c01e4d3277c43588c
diff --git a/kde-apps/kate-addons/kate-addons-24.11.90.ebuild b/kde-apps/kate-addons/kate-addons-24.11.90.ebuild
new file mode 100644
index 00000000000..ca09b93c813
--- /dev/null
+++ b/kde-apps/kate-addons/kate-addons-24.11.90.ebuild
@@ -0,0 +1,100 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+KDE_ORG_CATEGORY="utilities"
+KDE_ORG_NAME="kate"
+ECM_TEST="true"
+KFMIN=6.5.0
+QTMIN=6.7.2
+inherit ecm flag-o-matic gear.kde.org optfeature
+
+DESCRIPTION="Addons used by Kate"
+HOMEPAGE="https://kate-editor.org/ https://apps.kde.org/kate/"
+
+LICENSE="LGPL-2 LGPL-2+ MIT"
+SLOT="6"
+KEYWORDS="~amd64 ~arm64 ~ppc64 ~riscv ~x86"
+IUSE="+filebrowser lspclient +projects +snippets sql"
+
+DEPEND="
+	>=dev-qt/qtbase-${QTMIN}:6[concurrent,dbus,gui,network,widgets,xml]
+	~kde-apps/kate-lib-${PV}:6
+	>=kde-frameworks/kcodecs-${KFMIN}:6
+	>=kde-frameworks/kcompletion-${KFMIN}:6
+	>=kde-frameworks/kconfig-${KFMIN}:6
+	>=kde-frameworks/kconfigwidgets-${KFMIN}:6
+	>=kde-frameworks/kcoreaddons-${KFMIN}:6
+	>=kde-frameworks/kcrash-${KFMIN}:6
+	>=kde-frameworks/kdbusaddons-${KFMIN}:6
+	>=kde-frameworks/kguiaddons-${KFMIN}:6
+	>=kde-frameworks/ki18n-${KFMIN}:6
+	>=kde-frameworks/kiconthemes-${KFMIN}:6
+	>=kde-frameworks/kio-${KFMIN}:6
+	>=kde-frameworks/kitemviews-${KFMIN}:6
+	>=kde-frameworks/kjobwidgets-${KFMIN}:6
+	>=kde-frameworks/kparts-${KFMIN}:6
+	>=kde-frameworks/kservice-${KFMIN}:6
+	>=kde-frameworks/ktexteditor-${KFMIN}:6
+	>=kde-frameworks/kwidgetsaddons-${KFMIN}:6
+	>=kde-frameworks/kwindowsystem-${KFMIN}:6
+	>=kde-frameworks/kxmlgui-${KFMIN}:6
+	>=kde-frameworks/syntax-highlighting-${KFMIN}:6
+	filebrowser? ( >=kde-frameworks/kbookmarks-${KFMIN}:6 )
+	lspclient? ( >=kde-frameworks/kitemmodels-${KFMIN}:6 )
+	projects? (
+		>=kde-frameworks/knewstuff-${KFMIN}:6
+		>=kde-frameworks/threadweaver-${KFMIN}:6
+	)
+	snippets? ( >=kde-frameworks/knewstuff-${KFMIN}:6 )
+	sql? (
+		>=dev-libs/qtkeychain-0.14.2:=[qt6(+)]
+		>=dev-qt/qtbase-${QTMIN}:6[sql]
+		>=kde-frameworks/kwallet-${KFMIN}:6
+	)
+"
+RDEPEND="${DEPEND}
+	>=kde-apps/kate-common-${PV}
+"
+
+src_prepare() {
+	ecm_src_prepare
+	ecm_punt_po_install
+
+	# these tests are run in kde-apps/kate-lib
+	cmake_run_in apps/lib cmake_comment_add_subdirectory autotests
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DBUILD_kate=FALSE
+		-DBUILD_kwrite=FALSE
+		-DCMAKE_DISABLE_FIND_PACKAGE_KF6DocTools=ON # docs in kate/kwrite
+		-DBUILD_filebrowser=$(usex filebrowser)
+		-DBUILD_lspclient=$(usex lspclient)
+		-DBUILD_project=$(usex projects)
+		-DBUILD_snippets=$(usex snippets)
+		-DBUILD_katesql=$(usex sql)
+	)
+
+	# provided by kde-apps/kate-lib
+	append-libs -lkateprivate
+
+	ecm_src_configure
+}
+
+src_install() {
+	ecm_src_install
+
+	# provided by kde-apps/kate-lib
+	rm -v "${ED}"/usr/$(get_libdir)/libkateprivate.so.* || die
+}
+
+pkg_postinst() {
+	if [[ -z "${REPLACING_VERSIONS}" ]]; then
+		optfeature "Markdown text previews" "kde-misc/markdownpart:${SLOT}"
+		optfeature "DOT graph file previews" "media-gfx/kgraphviewer"
+	fi
+	ecm_pkg_postinst
+}