kde-apps/ksystemlog: 23.08.2 version bump

Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

2 files changed, 67 insertions, 0 deletions

diff --git a/kde-apps/ksystemlog/Manifest b/kde-apps/ksystemlog/Manifest
new file mode 100644
index 00000000000..f1563ac05a2
--- /dev/null
+++ b/kde-apps/ksystemlog/Manifest
@@ -0,0 +1 @@
+DIST ksystemlog-23.08.2.tar.xz 2007808 BLAKE2B 6cbde7eaabb988d53a38538b2d55aad930ae3824a5c372229f385aa3ef3b0df1031504f430851c86e62b6a6757b10bdda04533d9b3090b034857b517172d95ab SHA512 9750425e814438eeddbc9de87acb538beb6ef1a23eb20a8647313ec02f4177f46ff65b196b51d3a5e73ef643136e6e9c4cf7104c13c891f6892c0556ff6d3d58
diff --git a/kde-apps/ksystemlog/ksystemlog-23.08.2.ebuild b/kde-apps/ksystemlog/ksystemlog-23.08.2.ebuild
new file mode 100644
index 00000000000..5d3801228ae
--- /dev/null
+++ b/kde-apps/ksystemlog/ksystemlog-23.08.2.ebuild
@@ -0,0 +1,66 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+ECM_HANDBOOK="optional"
+ECM_TEST="forceoptional"
+KFMIN=5.106.0
+QTMIN=5.15.9
+inherit ecm gear.kde.org
+
+DESCRIPTION="System log viewer by KDE"
+HOMEPAGE="https://apps.kde.org/ksystemlog/"
+
+LICENSE="GPL-2" # TODO: CHECK
+SLOT="5"
+KEYWORDS="~amd64 ~arm64 ~ppc64 ~riscv ~x86"
+IUSE="audit kdesu systemd"
+
+DEPEND="
+	>=dev-qt/qtgui-${QTMIN}:5
+	>=dev-qt/qtprintsupport-${QTMIN}:5
+	>=dev-qt/qtwidgets-${QTMIN}:5
+	>=kde-frameworks/karchive-${KFMIN}:5
+	>=kde-frameworks/kcompletion-${KFMIN}:5
+	>=kde-frameworks/kconfig-${KFMIN}:5
+	>=kde-frameworks/kconfigwidgets-${KFMIN}:5
+	>=kde-frameworks/kcoreaddons-${KFMIN}:5
+	>=kde-frameworks/ki18n-${KFMIN}:5
+	>=kde-frameworks/kio-${KFMIN}:5
+	>=kde-frameworks/kitemviews-${KFMIN}:5
+	>=kde-frameworks/ktextwidgets-${KFMIN}:5
+	>=kde-frameworks/kwidgetsaddons-${KFMIN}:5
+	>=kde-frameworks/kxmlgui-${KFMIN}:5
+	audit? ( sys-process/audit )
+	systemd? (
+		>=dev-qt/qtnetwork-${QTMIN}:5
+		sys-apps/systemd:=
+	)
+"
+RDEPEND="${DEPEND}
+	kdesu? ( kde-plasma/kde-cli-tools[kdesu] )
+"
+
+src_prepare() {
+	ecm_src_prepare
+	if ! use kdesu; then
+		sed -e "/^X-KDE-SubstituteUID/s:true:false:" \
+			-i src/org.kde.ksystemlog.desktop || die
+	fi
+	use systemd || ecm_punt_qt_module Network
+}
+
+src_configure() {
+	local mycmakeargs=(
+		$(cmake_use_find_package audit Audit)
+		$(cmake_use_find_package systemd Journald)
+	)
+	ecm_src_configure
+}
+
+pkg_postinst() {
+	ecm_pkg_postinst
+	use kdesu || elog "Will show only user readable logs without USE=kdesu (only in X)."
+	use kdesu && elog "Cannot be launched from application menu in Wayland with USE=kdesu."
+}