kde-apps/dolphin: drop 24.12.0

Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

2 files changed, 0 insertions, 92 deletions

diff --git a/kde-apps/dolphin/Manifest b/kde-apps/dolphin/Manifest
deleted file mode 100644
index fdf33e37c1b..00000000000
--- a/kde-apps/dolphin/Manifest
+++ /dev/null
@@ -1 +0,0 @@
-DIST dolphin-24.12.0.tar.xz 5692976 BLAKE2B 90a656ce7a7bab9ef735082d13a4ee84e378faab43b3f63b82c4adee6c367e69517d9c4164d6dce11f2d65c3f40138befa46e06fbc86340ff419ef6281100df4 SHA512 80c0858d67909c0d7bf39146f294d53126254e8e6f261439bdd449b590c6b1d7b17a7a628666cedf89dfbaa1c7f0edb90ad2efcea5bf4106c47a3e2845295144
diff --git a/kde-apps/dolphin/dolphin-24.12.0.ebuild b/kde-apps/dolphin/dolphin-24.12.0.ebuild
deleted file mode 100644
index 3294010f72e..00000000000
--- a/kde-apps/dolphin/dolphin-24.12.0.ebuild
+++ /dev/null
@@ -1,91 +0,0 @@
-# Copyright 1999-2024 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-
-ECM_HANDBOOK="optional"
-ECM_TEST="true"
-PVCUT=$(ver_cut 1-3)
-KFMIN=6.5.0
-QTMIN=6.7.2
-inherit ecm gear.kde.org optfeature
-
-DESCRIPTION="Plasma filemanager focusing on usability"
-HOMEPAGE="https://apps.kde.org/dolphin/ https://userbase.kde.org/Dolphin"
-
-LICENSE="GPL-2" # TODO: CHECK
-SLOT="6"
-KEYWORDS="~amd64 ~arm64 ~ppc64 ~riscv ~x86"
-IUSE="semantic-desktop telemetry"
-
-# slot op: Uses Qt::GuiPrivate for qtx11extras_p.h
-DEPEND="
-	>=dev-qt/qtbase-${QTMIN}:6=[concurrent,dbus,gui,widgets,X,xml]
-	>=kde-frameworks/kbookmarks-${KFMIN}:6
-	>=kde-frameworks/kcmutils-${KFMIN}:6
-	>=kde-frameworks/kcodecs-${KFMIN}:6
-	>=kde-frameworks/kcompletion-${KFMIN}:6
-	>=kde-frameworks/kconfig-${KFMIN}:6
-	>=kde-frameworks/kconfigwidgets-${KFMIN}:6
-	>=kde-frameworks/kcoreaddons-${KFMIN}:6
-	>=kde-frameworks/kcrash-${KFMIN}:6
-	>=kde-frameworks/kdbusaddons-${KFMIN}:6
-	>=kde-frameworks/kfilemetadata-${KFMIN}:6
-	>=kde-frameworks/kguiaddons-${KFMIN}:6
-	>=kde-frameworks/ki18n-${KFMIN}:6
-	>=kde-frameworks/kiconthemes-${KFMIN}:6
-	>=kde-frameworks/kio-${KFMIN}:6=
-	>=kde-frameworks/kitemviews-${KFMIN}:6
-	>=kde-frameworks/kjobwidgets-${KFMIN}:6
-	>=kde-frameworks/knewstuff-${KFMIN}:6
-	>=kde-frameworks/knotifications-${KFMIN}:6
-	>=kde-frameworks/kparts-${KFMIN}:6
-	>=kde-frameworks/kservice-${KFMIN}:6
-	>=kde-frameworks/ktextwidgets-${KFMIN}:6
-	>=kde-frameworks/kwidgetsaddons-${KFMIN}:6
-	>=kde-frameworks/kwindowsystem-${KFMIN}:6
-	>=kde-frameworks/kxmlgui-${KFMIN}:6
-	>=kde-frameworks/solid-${KFMIN}:6
-	>=media-libs/phonon-4.12.0[qt6(+)]
-	semantic-desktop? (
-		>=kde-apps/baloo-widgets-${PVCUT}:6
-		>=kde-frameworks/baloo-${KFMIN}:6
-	)
-	telemetry? ( >=kde-frameworks/kuserfeedback-${KFMIN}:6 )
-"
-RDEPEND="${DEPEND}
-	>=kde-apps/kio-extras-${PVCUT}:6
-	>=kde-apps/thumbnailers-${PVCUT}:6
-"
-
-src_configure() {
-	local mycmakeargs=(
-		-DCMAKE_DISABLE_FIND_PACKAGE_PackageKitQt6=ON
-		$(cmake_use_find_package semantic-desktop KF6Baloo)
-		$(cmake_use_find_package semantic-desktop KF6BalooWidgets)
-		$(cmake_use_find_package telemetry KF6UserFeedback)
-	)
-	use test && mycmakeargs+=(
-		-DCMAKE_DISABLE_FIND_PACKAGE_SeleniumWebDriverATSPI=ON # not packaged
-	)
-	ecm_src_configure
-}
-
-src_test() {
-	local myctestargs=(
-		# servicemenuinstaller requires ruby, no thanks
-		# dolphinmainwindowtest, kitemlistcontrollertest, kfileitemlistviewtest, kfileitemmodeltest hang forever
-		# placesitemmodeltest requires DBus
-		-E "(servicemenuinstaller|dolphinmainwindowtest|kfileitemlistviewtest|kfileitemmodeltest|kitemlistcontrollertest|placesitemmodeltest)"
-	)
-	ecm_src_test
-}
-
-pkg_postinst() {
-	if [[ -z "${REPLACING_VERSIONS}" ]]; then
-		optfeature "compress/extract and other actions" "kde-apps/ark:${SLOT}"
-		optfeature "crypto actions" "kde-apps/kleopatra:${SLOT}"
-		optfeature "'Share' context menu actions" "kde-frameworks/purpose:${SLOT}"
-	fi
-	ecm_pkg_postinst
-}