kde-apps/kmix: 23.08.4 version bump

Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

2 files changed, 76 insertions, 0 deletions

diff --git a/kde-apps/kmix/Manifest b/kde-apps/kmix/Manifest
new file mode 100644
index 00000000000..debf5d2b5d8
--- /dev/null
+++ b/kde-apps/kmix/Manifest
@@ -0,0 +1 @@
+DIST kmix-23.08.4.tar.xz 1208572 BLAKE2B ffa5abccc79e3c0cb5f72ef89f726ef4d068227edecfa89ad93f55f7f0f2cd9291aa5a404a266a2ebac2ddbc645f96d2d0d0ae510a43fe288c32c222bbb7011c SHA512 a981c93080748b854b35fa0048b7fc0878237e114f2c59d86ba479b456b6d537af381cfe4c8c1698776eb25f1eecb7eb3075ec3c3df86c24c4f3f5a1a3bd374b
diff --git a/kde-apps/kmix/kmix-23.08.4.ebuild b/kde-apps/kmix/kmix-23.08.4.ebuild
new file mode 100644
index 00000000000..94e7584a5b6
--- /dev/null
+++ b/kde-apps/kmix/kmix-23.08.4.ebuild
@@ -0,0 +1,75 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+ECM_HANDBOOK="forceoptional"
+ECM_TEST="false"
+KFMIN=5.106.0
+QTMIN=5.15.9
+inherit ecm gear.kde.org
+
+DESCRIPTION="Volume control gui based on KDE Frameworks"
+HOMEPAGE="https://apps.kde.org/kmix/"
+
+LICENSE="GPL-2" # TODO: CHECK
+SLOT="5"
+KEYWORDS="~amd64 ~arm64 ~ppc64 ~riscv ~x86"
+IUSE="alsa plasma pulseaudio"
+
+# kde-frameworks/kwindowsystem[X]: Unconditional use of KX11Extras
+DEPEND="
+	>=dev-qt/qtdbus-${QTMIN}:5
+	>=dev-qt/qtgui-${QTMIN}:5
+	>=dev-qt/qtwidgets-${QTMIN}:5
+	>=dev-qt/qtxml-${QTMIN}:5
+	>=kde-frameworks/kconfig-${KFMIN}:5
+	>=kde-frameworks/kconfigwidgets-${KFMIN}:5
+	>=kde-frameworks/kcoreaddons-${KFMIN}:5
+	>=kde-frameworks/kdbusaddons-${KFMIN}:5
+	>=kde-frameworks/kglobalaccel-${KFMIN}:5
+	>=kde-frameworks/ki18n-${KFMIN}:5
+	>=kde-frameworks/knotifications-${KFMIN}:5
+	>=kde-frameworks/kwidgetsaddons-${KFMIN}:5
+	>=kde-frameworks/kwindowsystem-${KFMIN}:5[X]
+	>=kde-frameworks/kxmlgui-${KFMIN}:5
+	>=kde-frameworks/solid-${KFMIN}:5
+	alsa? ( >=media-libs/alsa-lib-1.0.14a )
+	plasma? ( >=kde-plasma/libplasma-${KFMIN}:5 )
+	pulseaudio? (
+		media-libs/libcanberra
+		media-libs/libpulse
+	)
+"
+RDEPEND="${DEPEND}
+	kde-plasma/kde-cli-tools:*
+"
+
+PATCHES=( "${FILESDIR}/${PN}-23.04.2-autostart_disable.patch" ) # TODO: upstream
+
+src_configure() {
+	local mycmakeargs=(
+		$(cmake_use_find_package alsa ALSA)
+		-DBUILD_DATAENGINE=$(usex plasma)
+		$(cmake_use_find_package pulseaudio Canberra)
+		$(cmake_use_find_package pulseaudio PulseAudio)
+	)
+
+	ecm_src_configure
+}
+
+pkg_postinst() {
+	if use pulseaudio && has_version kde-plasma/plasma-pa; then
+		elog "In KDE Plasma, kde-plasma/plasma-pa is the default audio volume handler,"
+		elog "therefore, autostart by default was disabled for KMix."
+		elog
+		elog "Should you prefer to still use kde-apps/kmix instead, do the following:"
+		elog " - In system tray, right click on [Show hidden items]"
+		elog " - Select [Configure System Tray]"
+		elog " - In [Entries],  search for [Audio Volume] and set it to [Disabled]"
+		elog
+	fi
+	elog "KMix will be shown as [Volume Control] after manually starting it once"
+	elog "and will be autostarted after configuring such in KMix startup settings."
+	ecm_pkg_postinst
+}