kde-apps/kmix: 22.12.2 version bump

Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

2 files changed, 69 insertions, 0 deletions

diff --git a/kde-apps/kmix/Manifest b/kde-apps/kmix/Manifest
new file mode 100644
index 00000000000..62bb338a878
--- /dev/null
+++ b/kde-apps/kmix/Manifest
@@ -0,0 +1 @@
+DIST kmix-22.12.2.tar.xz 1195092 BLAKE2B a609a6139645ac1daaee4e1f322101d468d312d5038f7052fc463a31bfc1dd30ddb78a3157487f113a98d5dbdf3f273c4da7cec53be275e4c1b9489c72f36ae6 SHA512 a34e1c872da889b76398adcb06d914517235ffedb0b2ae04e9e547312d7a7c119b81466a3e07e157b57c4d11a880d8823732416677187ce5e36394db46615986
diff --git a/kde-apps/kmix/kmix-22.12.2.ebuild b/kde-apps/kmix/kmix-22.12.2.ebuild
new file mode 100644
index 00000000000..34858692ca9
--- /dev/null
+++ b/kde-apps/kmix/kmix-22.12.2.ebuild
@@ -0,0 +1,68 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+ECM_HANDBOOK="forceoptional"
+ECM_TEST="false"
+KFMIN=5.101.0
+QTMIN=5.15.5
+inherit ecm gear.kde.org
+
+DESCRIPTION="Volume control gui based on KDE Frameworks"
+HOMEPAGE="https://apps.kde.org/kmix/"
+
+LICENSE="GPL-2" # TODO: CHECK
+SLOT="5"
+KEYWORDS="~amd64 ~arm64 ~ppc64 ~riscv ~x86"
+IUSE="alsa plasma pulseaudio"
+
+DEPEND="
+	>=dev-qt/qtdbus-${QTMIN}:5
+	>=dev-qt/qtgui-${QTMIN}:5
+	>=dev-qt/qtwidgets-${QTMIN}:5
+	>=dev-qt/qtxml-${QTMIN}:5
+	>=kde-frameworks/kconfig-${KFMIN}:5
+	>=kde-frameworks/kconfigwidgets-${KFMIN}:5
+	>=kde-frameworks/kcoreaddons-${KFMIN}:5
+	>=kde-frameworks/kdbusaddons-${KFMIN}:5
+	>=kde-frameworks/kglobalaccel-${KFMIN}:5
+	>=kde-frameworks/ki18n-${KFMIN}:5
+	>=kde-frameworks/knotifications-${KFMIN}:5
+	>=kde-frameworks/kwidgetsaddons-${KFMIN}:5
+	>=kde-frameworks/kwindowsystem-${KFMIN}:5
+	>=kde-frameworks/kxmlgui-${KFMIN}:5
+	>=kde-frameworks/solid-${KFMIN}:5
+	alsa? ( >=media-libs/alsa-lib-1.0.14a )
+	plasma? ( >=kde-frameworks/plasma-${KFMIN}:5 )
+	pulseaudio? (
+		media-libs/libcanberra
+		media-libs/libpulse
+	)
+"
+RDEPEND="${DEPEND}
+	kde-plasma/kde-cli-tools:5
+"
+
+src_configure() {
+	local mycmakeargs=(
+		$(cmake_use_find_package alsa ALSA)
+		-DBUILD_DATAENGINE=$(usex plasma)
+		$(cmake_use_find_package pulseaudio Canberra)
+		$(cmake_use_find_package pulseaudio PulseAudio)
+	)
+
+	ecm_src_configure
+}
+
+pkg_postinst() {
+	if use pulseaudio && has_version kde-plasma/plasma-pa; then
+		elog "In KDE Plasma, kde-plasma/plasma-pa is the default audio volume handler."
+		elog "Should you prefer this to be kde-apps/kmix instead, do the following:"
+		elog " - In system tray, right click on [Show hidden items]"
+		elog " - Select [Configure System Tray]"
+		elog " - In [Entries],  search for [Audio Volume] and set it to [Disabled]"
+		elog "KMix will be shown as [Volume Control]."
+	fi
+	ecm_pkg_postinst
+}