kde-frameworks/kfilemetadata: 5.85.0 version bump

Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

2 files changed, 67 insertions, 0 deletions

diff --git a/kde-frameworks/kfilemetadata/Manifest b/kde-frameworks/kfilemetadata/Manifest
new file mode 100644
index 00000000000..f141e1e8f44
--- /dev/null
+++ b/kde-frameworks/kfilemetadata/Manifest
@@ -0,0 +1 @@
+DIST kfilemetadata-5.85.0.tar.xz 426336 BLAKE2B f68125f17afb6f3f9c65486670ad2eca8ad057927c30ad3f765d6551cf3cb1801512c9432c70f2e87a992e7ef8f81ef23908cfdcac0df5c466eb4a0e932e58ab SHA512 f531a1519ee3efc8b6973bf979ce2ee1380c9b425f06233267d007c1b79f6b7c2166e47212093ec8250f75dc9897dbb0d9b8b17ee4d999c487f10451a725ffd7
diff --git a/kde-frameworks/kfilemetadata/kfilemetadata-5.85.0.ebuild b/kde-frameworks/kfilemetadata/kfilemetadata-5.85.0.ebuild
new file mode 100644
index 00000000000..09ccbeab9dd
--- /dev/null
+++ b/kde-frameworks/kfilemetadata/kfilemetadata-5.85.0.ebuild
@@ -0,0 +1,66 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{8..10} )
+PVCUT=$(ver_cut 1-2)
+QTMIN=5.15.2
+inherit ecm kde.org optfeature python-any-r1
+
+DESCRIPTION="Library for extracting file metadata"
+LICENSE="LGPL-2+"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~x86"
+IUSE="epub exif ffmpeg kernel_linux office pdf taglib"
+
+RESTRICT+=" test"
+
+BDEPEND="
+	test? ( ${PYTHON_DEPS} )
+"
+RDEPEND="
+	>=dev-qt/qtxml-${QTMIN}:5
+	=kde-frameworks/kcoreaddons-${PVCUT}*:5
+	=kde-frameworks/ki18n-${PVCUT}*:5
+	epub? ( app-text/ebook-tools )
+	exif? ( media-gfx/exiv2:= )
+	ffmpeg? ( media-video/ffmpeg:0= )
+	office? ( =kde-frameworks/karchive-${PVCUT}*:5 )
+	pdf? ( app-text/poppler[qt5] )
+	taglib? ( media-libs/taglib )
+"
+DEPEND="${RDEPEND}
+	kernel_linux? ( sys-apps/attr )
+"
+
+pkg_setup() {
+	use test && python-any-r1_pkg_setup
+	ecm_pkg_setup
+}
+
+src_configure() {
+	local mycmakeargs=(
+		$(cmake_use_find_package epub EPub)
+		$(cmake_use_find_package exif LibExiv2)
+		$(cmake_use_find_package ffmpeg FFmpeg)
+		$(cmake_use_find_package office KF5Archive)
+		$(cmake_use_find_package pdf Poppler)
+		$(cmake_use_find_package taglib Taglib)
+	)
+
+	ecm_src_configure
+}
+
+src_test() {
+	# FIXME: bug 644650, fails on tmpfs (but not for everyone)
+	local myctestargs=( -E "(usermetadatawritertest)" )
+	ecm_src_test
+}
+
+pkg_postinst() {
+	if [[ -z "${REPLACING_VERSIONS}" ]]; then
+		optfeature "Microsoft Word/Powerpoint file indexing" app-text/catdoc
+		optfeature "Microsoft Excel file indexing" dev-libs/libxls
+	fi
+	ecm_pkg_postinst
+}