kde-frameworks/plasma: pkgmove to kde-plasma/libplasma

Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

2 files changed, 89 insertions, 0 deletions

diff --git a/kde-plasma/libplasma/libplasma-5.9999.ebuild b/kde-plasma/libplasma/libplasma-5.9999.ebuild
new file mode 100644
index 00000000000..f9657fa594c
--- /dev/null
+++ b/kde-plasma/libplasma/libplasma-5.9999.ebuild
@@ -0,0 +1,72 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+ECM_NONGUI="true"
+ECM_QTHELP="true"
+ECM_TEST="true"
+KFMIN=$(ver_cut 1-2)
+QTMIN=5.15.9
+inherit ecm frameworks.kde.org
+
+DESCRIPTION="Plasma library and runtime components based upon KF5 and Qt5"
+
+LICENSE="LGPL-2+"
+KEYWORDS=""
+IUSE="gles2-only man wayland"
+
+RESTRICT="test"
+
+# kde-frameworks/kwindowsystem[X]: Unconditional use of KX11Extras
+RDEPEND="
+	>=dev-qt/qtdbus-${QTMIN}:5
+	>=dev-qt/qtdeclarative-${QTMIN}:5
+	>=dev-qt/qtgui-${QTMIN}:5[gles2-only=,X]
+	>=dev-qt/qtquickcontrols-${QTMIN}:5
+	>=dev-qt/qtsql-${QTMIN}:5
+	>=dev-qt/qtsvg-${QTMIN}:5
+	>=dev-qt/qtwidgets-${QTMIN}:5
+	>=dev-qt/qtx11extras-${QTMIN}:5
+	=kde-frameworks/kactivities-${KFMIN}*:5
+	=kde-frameworks/karchive-${KFMIN}*:5
+	=kde-frameworks/kconfig-${KFMIN}*:5[qml]
+	=kde-frameworks/kconfigwidgets-${KFMIN}*:5
+	=kde-frameworks/kcoreaddons-${KFMIN}*:5
+	=kde-frameworks/kdeclarative-${KFMIN}*:5
+	=kde-frameworks/kglobalaccel-${KFMIN}*:5
+	=kde-frameworks/kguiaddons-${KFMIN}*:5
+	=kde-frameworks/ki18n-${KFMIN}*:5
+	=kde-frameworks/kiconthemes-${KFMIN}*:5
+	=kde-frameworks/kio-${KFMIN}*:5
+	=kde-frameworks/kirigami-${KFMIN}*:5
+	=kde-frameworks/knotifications-${KFMIN}*:5
+	=kde-frameworks/kpackage-${KFMIN}*:5
+	=kde-frameworks/kservice-${KFMIN}*:5
+	=kde-frameworks/kwidgetsaddons-${KFMIN}*:5
+	=kde-frameworks/kwindowsystem-${KFMIN}*:5[X]
+	=kde-frameworks/kxmlgui-${KFMIN}*:5
+	x11-libs/libX11
+	x11-libs/libxcb
+	!gles2-only? ( media-libs/libglvnd[X] )
+	wayland? (
+		=kde-frameworks/kwayland-${KFMIN}*:5
+		media-libs/libglvnd
+	)
+"
+DEPEND="${RDEPEND}
+	x11-base/xorg-proto
+"
+BDEPEND="man? ( >=kde-frameworks/kdoctools-${KFMIN}:5 )"
+
+src_configure() {
+	local mycmakeargs=(
+		-DBUILD_DESKTOPTHEMES=ON # TODO: switch for KF6 compat
+		$(cmake_use_find_package !gles2-only OpenGL)
+		$(cmake_use_find_package man KF5DocTools)
+		$(cmake_use_find_package wayland EGL)
+		$(cmake_use_find_package wayland KF5Wayland)
+	)
+
+	ecm_src_configure
+}
diff --git a/kde-plasma/libplasma/metadata.xml b/kde-plasma/libplasma/metadata.xml
new file mode 100644
index 00000000000..936dd6d7c06
--- /dev/null
+++ b/kde-plasma/libplasma/metadata.xml
@@ -0,0 +1,17 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "https://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+	<maintainer type="project">
+		<email>kde@gentoo.org</email>
+		<name>Gentoo KDE Project</name>
+	</maintainer>
+	<upstream>
+		<bugs-to>https://bugs.kde.org/</bugs-to>
+		<remote-id type="kde-invent">plasma/libplasma</remote-id>
+	</upstream>
+	<slots>
+		<subslots>
+			Must only be used by packages that are known to use private parts of the Frameworks API.
+		</subslots>
+	</slots>
+</pkgmetadata>