kde-plasma/libkworkspace: 5.27.1 version bump

Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

2 files changed, 53 insertions, 0 deletions

diff --git a/kde-plasma/libkworkspace/Manifest b/kde-plasma/libkworkspace/Manifest
new file mode 100644
index 00000000000..9450f4797ee
--- /dev/null
+++ b/kde-plasma/libkworkspace/Manifest
@@ -0,0 +1 @@
+DIST plasma-workspace-5.27.1.tar.xz 18626768 BLAKE2B 9562b437551bd387927a93862b985c3f6a83856e74bf17a248a927d23b0d4d115d7e3f698cfcd2e392d905cfc9723138f2fee5a2187e4fc16eb682fb9e3cf47f SHA512 eb8b3acc76452637791f3cdcb44ec77edd2e09d3f599dfaff5116471971fb0966b98d5383d3f2a1e05e1b741a348f4f254241d0fc9df26e9d89846478e4688ae
diff --git a/kde-plasma/libkworkspace/libkworkspace-5.27.1.ebuild b/kde-plasma/libkworkspace/libkworkspace-5.27.1.ebuild
new file mode 100644
index 00000000000..8e90fde047c
--- /dev/null
+++ b/kde-plasma/libkworkspace/libkworkspace-5.27.1.ebuild
@@ -0,0 +1,52 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+ECM_TEST="true"
+KDE_ORG_NAME="plasma-workspace"
+KFMIN=5.102.0
+PVCUT=$(ver_cut 1-3)
+QTMIN=5.15.7
+inherit ecm plasma.kde.org
+
+DESCRIPTION="Workspace library to interact with the Plasma session manager"
+
+LICENSE="GPL-2" # TODO: CHECK
+SLOT="5"
+KEYWORDS="~amd64 ~arm ~arm64 ~loong ~ppc64 ~riscv ~x86"
+IUSE=""
+
+RDEPEND="
+	>=dev-qt/qtdbus-${QTMIN}:5
+	>=dev-qt/qtx11extras-${QTMIN}:5
+	>=kde-frameworks/kconfig-${KFMIN}:5
+	>=kde-frameworks/kcoreaddons-${KFMIN}:5
+	>=kde-frameworks/ki18n-${KFMIN}:5
+	>=kde-frameworks/kwindowsystem-${KFMIN}:5
+	>=kde-plasma/kscreenlocker-${PVCUT}:5
+	x11-libs/libICE
+	x11-libs/libSM
+	x11-libs/libX11
+	x11-libs/libXau
+"
+DEPEND="${RDEPEND}
+	>=kde-plasma/kwin-${PVCUT}:5
+"
+
+S="${S}/${PN}"
+
+src_prepare() {
+	# delete colliding libkworkspace translations, let ecm_src_prepare do its magic
+	find ../po -type f -name "*po" -and -not -name "libkworkspace*" -delete || die
+	rm -rf po/*/docs || die
+	cp -a ../po ./ || die
+
+	eapply "${FILESDIR}/${PN}-5.22.80-standalone.patch"
+	sed -e "/set/s/GENTOO_PV/$(ver_cut 1-3)/" -i CMakeLists.txt || die
+	cat >> CMakeLists.txt <<- _EOF_ || die
+		ki18n_install(po)
+	_EOF_
+
+	ecm_src_prepare
+}