kde-plasma: Add KDE Plasma 5.19 stable branch

Package-Manager: Portage-2.3.99, Repoman-2.3.22
Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

49 files changed, 2828 insertions, 0 deletions

diff --git a/kde-plasma/bluedevil/bluedevil-5.19.49.9999.ebuild b/kde-plasma/bluedevil/bluedevil-5.19.49.9999.ebuild
new file mode 100644
index 00000000000..dc870a66c5e
--- /dev/null
+++ b/kde-plasma/bluedevil/bluedevil-5.19.49.9999.ebuild
@@ -0,0 +1,40 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+KFMIN=5.70.0
+PVCUT=$(ver_cut 1-3)
+QTMIN=5.14.1
+inherit ecm kde.org
+
+DESCRIPTION="Bluetooth stack for KDE Plasma"
+HOMEPAGE="https://cgit.kde.org/bluedevil.git"
+
+LICENSE="GPL-2" # TODO: CHECK
+SLOT="5"
+KEYWORDS=""
+IUSE=""
+
+DEPEND="
+	>=kde-frameworks/bluez-qt-${KFMIN}:5
+	>=kde-frameworks/kconfig-${KFMIN}:5
+	>=kde-frameworks/kconfigwidgets-${KFMIN}:5
+	>=kde-frameworks/kcoreaddons-${KFMIN}:5
+	>=kde-frameworks/kded-${KFMIN}:5
+	>=kde-frameworks/kdbusaddons-${KFMIN}:5
+	>=kde-frameworks/ki18n-${KFMIN}:5
+	>=kde-frameworks/kiconthemes-${KFMIN}:5
+	>=kde-frameworks/kio-${KFMIN}:5
+	>=kde-frameworks/knotifications-${KFMIN}:5
+	>=kde-frameworks/kwidgetsaddons-${KFMIN}:5
+	>=kde-frameworks/kwindowsystem-${KFMIN}:5
+	>=kde-frameworks/plasma-${KFMIN}:5
+	>=dev-qt/qtdbus-${QTMIN}:5
+	>=dev-qt/qtdeclarative-${QTMIN}:5
+	>=dev-qt/qtgui-${QTMIN}:5
+	>=dev-qt/qtwidgets-${QTMIN}:5
+"
+RDEPEND="${DEPEND}
+	>=kde-plasma/kde-cli-tools-${PVCUT}:5
+"
diff --git a/kde-plasma/breeze-grub/breeze-grub-5.19.49.9999.ebuild b/kde-plasma/breeze-grub/breeze-grub-5.19.49.9999.ebuild
new file mode 100644
index 00000000000..f6e02671bec
--- /dev/null
+++ b/kde-plasma/breeze-grub/breeze-grub-5.19.49.9999.ebuild
@@ -0,0 +1,23 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PVCUT=$(ver_cut 1-3)
+inherit kde.org
+
+DESCRIPTION="Breeze theme for GRUB"
+
+LICENSE="GPL-3+"
+SLOT="5"
+KEYWORDS=""
+IUSE=""
+
+src_prepare() { default; }
+src_configure() { :; }
+src_compile() { :; }
+
+src_install() {
+	insinto /usr/share/grub/themes
+	doins -r breeze
+}
diff --git a/kde-plasma/breeze-gtk/breeze-gtk-5.19.49.9999.ebuild b/kde-plasma/breeze-gtk/breeze-gtk-5.19.49.9999.ebuild
new file mode 100644
index 00000000000..3e5ab24f454
--- /dev/null
+++ b/kde-plasma/breeze-gtk/breeze-gtk-5.19.49.9999.ebuild
@@ -0,0 +1,48 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{7,8} )
+PVCUT=$(ver_cut 1-3)
+inherit ecm kde.org python-any-r1
+
+DESCRIPTION="Official GTK+ port of Plasma's Breeze widget style"
+HOMEPAGE="https://cgit.kde.org/breeze-gtk.git"
+
+LICENSE="LGPL-2.1+"
+SLOT="5"
+KEYWORDS=""
+IUSE=""
+
+BDEPEND="${PYTHON_DEPS}
+	dev-lang/sassc
+	$(python_gen_any_dep 'dev-python/pycairo[${PYTHON_USEDEP}]')
+	>=kde-plasma/breeze-${PVCUT}:5
+"
+
+python_check_deps() {
+	has_version "dev-python/pycairo[${PYTHON_USEDEP}]"
+}
+
+pkg_setup() {
+	python-any-r1_pkg_setup
+	ecm_pkg_setup
+}
+
+src_prepare() {
+	ecm_src_prepare
+	if has_version "<dev-util/cmake-3.16_rc1"; then
+		eapply "${FILESDIR}"/${PN}-5.16.5-cmake-pre-3.16.patch
+	fi
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DPython3_EXECUTABLE="${PYTHON}"
+	)
+	if has_version "<dev-util/cmake-3.16_rc1"; then
+		mycmakeargs=( -DPYTHON_EXECUTABLE="${PYTHON}" )
+	fi
+	ecm_src_configure
+}
diff --git a/kde-plasma/breeze-plymouth/breeze-plymouth-5.19.49.9999.ebuild b/kde-plasma/breeze-plymouth/breeze-plymouth-5.19.49.9999.ebuild
new file mode 100644
index 00000000000..6f1828b3b67
--- /dev/null
+++ b/kde-plasma/breeze-plymouth/breeze-plymouth-5.19.49.9999.ebuild
@@ -0,0 +1,28 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+KFMIN=5.70.0
+PVCUT=$(ver_cut 1-3)
+inherit cmake kde.org
+
+DESCRIPTION="Breeze theme for Plymouth"
+
+LICENSE="GPL-2+ GPL-3+"
+SLOT="5"
+KEYWORDS=""
+IUSE=""
+
+BDEPEND=">=kde-frameworks/extra-cmake-modules-${KFMIN}:5"
+DEPEND="sys-boot/plymouth"
+RDEPEND="${DEPEND}"
+
+src_configure() {
+	local mycmakeargs=(
+		-DDISTRO_NAME="Gentoo Linux"
+		-DDISTRO_VERSION=
+	)
+
+	cmake_src_configure
+}
diff --git a/kde-plasma/breeze/breeze-5.19.49.9999.ebuild b/kde-plasma/breeze/breeze-5.19.49.9999.ebuild
new file mode 100644
index 00000000000..5c5cf88572b
--- /dev/null
+++ b/kde-plasma/breeze/breeze-5.19.49.9999.ebuild
@@ -0,0 +1,55 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+KFMIN=5.70.0
+PVCUT=$(ver_cut 1-3)
+QTMIN=5.14.1
+inherit ecm kde.org
+
+DESCRIPTION="Breeze visual style for the Plasma desktop"
+HOMEPAGE="https://cgit.kde.org/breeze.git"
+
+LICENSE="GPL-2" # TODO: CHECK
+SLOT="5"
+KEYWORDS=""
+IUSE="wayland X"
+
+RDEPEND="
+	>=kde-frameworks/frameworkintegration-${KFMIN}:5
+	>=kde-frameworks/kcmutils-${KFMIN}:5
+	>=kde-frameworks/kconfig-${KFMIN}:5
+	>=kde-frameworks/kconfigwidgets-${KFMIN}:5
+	>=kde-frameworks/kcoreaddons-${KFMIN}:5
+	>=kde-frameworks/kguiaddons-${KFMIN}:5
+	>=kde-frameworks/ki18n-${KFMIN}:5
+	>=kde-frameworks/kwidgetsaddons-${KFMIN}:5
+	>=kde-frameworks/kwindowsystem-${KFMIN}:5
+	>=kde-plasma/kdecoration-${PVCUT}:5
+	>=dev-qt/qtdbus-${QTMIN}:5
+	>=dev-qt/qtdeclarative-${QTMIN}:5
+	>=dev-qt/qtgui-${QTMIN}:5
+	>=dev-qt/qtwidgets-${QTMIN}:5
+	sci-libs/fftw:3.0=
+	wayland? ( >=kde-frameworks/kwayland-${KFMIN}:5 )
+	X? (
+		>=dev-qt/qtx11extras-${QTMIN}:5
+		x11-libs/libxcb
+	)
+"
+DEPEND="${RDEPEND}
+	>=kde-frameworks/kpackage-${KFMIN}:5
+"
+PDEPEND="
+	>=kde-frameworks/breeze-icons-${KFMIN}:5
+	>=kde-plasma/kde-cli-tools-${PVCUT}:5
+"
+
+src_configure() {
+	local mycmakeargs=(
+		$(cmake_use_find_package wayland KF5Wayland)
+		$(cmake_use_find_package X XCB)
+	)
+	ecm_src_configure
+}
diff --git a/kde-plasma/discover/discover-5.19.49.9999.ebuild b/kde-plasma/discover/discover-5.19.49.9999.ebuild
new file mode 100644
index 00000000000..6e593335585
--- /dev/null
+++ b/kde-plasma/discover/discover-5.19.49.9999.ebuild
@@ -0,0 +1,78 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+ECM_TEST="forceoptional"
+KFMIN=5.70.0
+PVCUT=$(ver_cut 1-3)
+QTMIN=5.14.1
+VIRTUALX_REQUIRED="test"
+inherit ecm kde.org
+
+DESCRIPTION="KDE Plasma resources management GUI"
+HOMEPAGE="https://userbase.kde.org/Discover"
+
+LICENSE="GPL-2" # TODO: CHECK
+SLOT="5"
+KEYWORDS=""
+IUSE="+firmware telemetry"
+
+# libmarkdown (app-text/discount) only used in PackageKitBackend
+DEPEND="
+	>=kde-frameworks/attica-${KFMIN}:5
+	>=kde-frameworks/kconfig-${KFMIN}:5
+	>=kde-frameworks/kconfigwidgets-${KFMIN}:5
+	>=kde-frameworks/kcoreaddons-${KFMIN}:5
+	>=kde-frameworks/kcrash-${KFMIN}:5
+	>=kde-frameworks/kdbusaddons-${KFMIN}:5
+	>=kde-frameworks/kdeclarative-${KFMIN}:5
+	>=kde-frameworks/ki18n-${KFMIN}:5
+	>=kde-frameworks/kio-${KFMIN}:5
+	>=kde-frameworks/kirigami-${KFMIN}:5
+	>=kde-frameworks/kitemmodels-${KFMIN}:5
+	>=kde-frameworks/knewstuff-${KFMIN}:5
+	>=kde-frameworks/knotifications-${KFMIN}:5
+	>=kde-frameworks/kwidgetsaddons-${KFMIN}:5
+	>=kde-frameworks/kxmlgui-${KFMIN}:5
+	>=dev-qt/qtconcurrent-${QTMIN}:5
+	>=dev-qt/qtdbus-${QTMIN}:5
+	>=dev-qt/qtdeclarative-${QTMIN}:5
+	>=dev-qt/qtgui-${QTMIN}:5
+	>=dev-qt/qtnetwork-${QTMIN}:5
+	>=dev-qt/qtwidgets-${QTMIN}:5
+	>=dev-qt/qtxml-${QTMIN}:5
+	firmware? ( sys-apps/fwupd )
+	telemetry? ( dev-libs/kuserfeedback:5 )
+"
+RDEPEND="${DEPEND}
+	>=kde-frameworks/kirigami-${KFMIN}:5
+"
+
+src_prepare() {
+	ecm_src_prepare
+	# we don't need it with PackageKitBackend off
+	ecm_punt_bogus_dep KF5 Archive
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DCMAKE_DISABLE_FIND_PACKAGE_packagekitqt5=ON
+		-DCMAKE_DISABLE_FIND_PACKAGE_AppStreamQt=ON
+		-DCMAKE_DISABLE_FIND_PACKAGE_Snapd=ON
+		-DBUILD_FlatpakBackend=OFF
+		-DBUILD_FwupdBackend=$(usex firmware)
+		$(cmake_use_find_package telemetry KUserFeedback)
+	)
+
+	ecm_src_configure
+}
+
+src_test() {
+	# bug 686392: needs network connection
+	local myctestargs=(
+		-E "(knsbackendtest)"
+	)
+
+	ecm_src_test
+}
diff --git a/kde-plasma/drkonqi/drkonqi-5.19.49.9999.ebuild b/kde-plasma/drkonqi/drkonqi-5.19.49.9999.ebuild
new file mode 100644
index 00000000000..94754a7adb5
--- /dev/null
+++ b/kde-plasma/drkonqi/drkonqi-5.19.49.9999.ebuild
@@ -0,0 +1,68 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+KFMIN=5.70.0
+PVCUT=$(ver_cut 1-3)
+QTMIN=5.14.1
+inherit ecm kde.org
+
+DESCRIPTION="Plasma crash handler, gives the user feedback if a program crashed"
+
+LICENSE="GPL-2" # TODO: CHECK
+SLOT="5"
+KEYWORDS=""
+IUSE="X"
+
+RDEPEND="
+	>=dev-qt/qtdbus-${QTMIN}:5
+	>=dev-qt/qtgui-${QTMIN}:5
+	>=dev-qt/qtwidgets-${QTMIN}:5
+	>=dev-qt/qtxml-${QTMIN}:5
+	>=kde-frameworks/kcompletion-${KFMIN}:5
+	>=kde-frameworks/kconfig-${KFMIN}:5
+	>=kde-frameworks/kconfigwidgets-${KFMIN}:5
+	>=kde-frameworks/kcoreaddons-${KFMIN}:5
+	>=kde-frameworks/kcrash-${KFMIN}:5
+	>=kde-frameworks/ki18n-${KFMIN}:5
+	>=kde-frameworks/kidletime-${KFMIN}:5
+	>=kde-frameworks/kio-${KFMIN}:5
+	>=kde-frameworks/kjobwidgets-${KFMIN}:5
+	>=kde-frameworks/knotifications-${KFMIN}:5
+	>=kde-frameworks/kservice-${KFMIN}:5
+	>=kde-frameworks/syntax-highlighting-${KFMIN}:5
+	>=kde-frameworks/kwallet-${KFMIN}:5
+	>=kde-frameworks/kwayland-${KFMIN}:5
+	>=kde-frameworks/kwidgetsaddons-${KFMIN}:5
+	>=kde-frameworks/kwindowsystem-${KFMIN}:5
+	>=kde-frameworks/kxmlrpcclient-${KFMIN}:5
+	X? ( >=dev-qt/qtx11extras-${QTMIN}:5 )
+"
+DEPEND="${RDEPEND}
+	>=dev-qt/qtconcurrent-${QTMIN}:5
+"
+
+src_configure() {
+	local mycmakeargs=(
+		$(cmake_use_find_package X Qt5X11Extras)
+	)
+	ecm_src_configure
+}
+
+src_test() {
+	# needs network access, bug #698510
+	local myctestargs=(
+		-E "(connectiontest)"
+	)
+
+	ecm_src_test
+}
+
+pkg_postinst() {
+	ecm_pkg_postinst
+	if ! has_version "sys-devel/gdb"; then
+		elog "For more usability consider installing the following package:"
+		elog "    sys-devel/gdb - Easier debugging support"
+	fi
+}
diff --git a/kde-plasma/kactivitymanagerd/kactivitymanagerd-5.19.49.9999.ebuild b/kde-plasma/kactivitymanagerd/kactivitymanagerd-5.19.49.9999.ebuild
new file mode 100644
index 00000000000..d1deba68bb6
--- /dev/null
+++ b/kde-plasma/kactivitymanagerd/kactivitymanagerd-5.19.49.9999.ebuild
@@ -0,0 +1,36 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+KFMIN=5.70.0
+PVCUT=$(ver_cut 1-3)
+QTMIN=5.14.1
+inherit ecm kde.org
+
+DESCRIPTION="System service to manage user's activities, track the usage patterns etc."
+
+LICENSE="|| ( GPL-2 GPL-3 )"
+SLOT="5"
+KEYWORDS=""
+IUSE=""
+
+RDEPEND="
+	>=dev-qt/qtdbus-${QTMIN}:5
+	>=dev-qt/qtgui-${QTMIN}:5
+	>=dev-qt/qtsql-${QTMIN}:5[sqlite]
+	>=dev-qt/qtwidgets-${QTMIN}:5
+	>=kde-frameworks/kconfig-${KFMIN}:5
+	>=kde-frameworks/kcoreaddons-${KFMIN}:5
+	>=kde-frameworks/kcrash-${KFMIN}:5
+	>=kde-frameworks/kdbusaddons-${KFMIN}:5
+	>=kde-frameworks/kglobalaccel-${KFMIN}:5
+	>=kde-frameworks/ki18n-${KFMIN}:5
+	>=kde-frameworks/kio-${KFMIN}:5
+	>=kde-frameworks/kservice-${KFMIN}:5
+	>=kde-frameworks/kwindowsystem-${KFMIN}:5
+	>=kde-frameworks/kxmlgui-${KFMIN}:5
+"
+DEPEND="${RDEPEND}
+	dev-libs/boost
+"
diff --git a/kde-plasma/kde-cli-tools/kde-cli-tools-5.19.49.9999.ebuild b/kde-plasma/kde-cli-tools/kde-cli-tools-5.19.49.9999.ebuild
new file mode 100644
index 00000000000..3c69d3a6683
--- /dev/null
+++ b/kde-plasma/kde-cli-tools/kde-cli-tools-5.19.49.9999.ebuild
@@ -0,0 +1,70 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+ECM_HANDBOOK="forceoptional"
+ECM_TEST="optional"
+KFMIN=5.70.0
+PVCUT=$(ver_cut 1-3)
+QTMIN=5.14.1
+VIRTUALX_REQUIRED="test"
+inherit ecm kde.org
+
+DESCRIPTION="Tools based on KDE Frameworks 5 to better interact with the system"
+HOMEPAGE="https://cgit.kde.org/kde-cli-tools.git"
+
+LICENSE="GPL-2" # TODO: CHECK
+SLOT="5"
+KEYWORDS=""
+IUSE="kdesu X"
+
+REQUIRED_USE="kdesu? ( X )"
+
+DEPEND="
+	>=dev-qt/qtdbus-${QTMIN}:5
+	>=dev-qt/qtgui-${QTMIN}:5
+	>=dev-qt/qtsvg-${QTMIN}:5
+	>=dev-qt/qtwidgets-${QTMIN}:5
+	>=kde-frameworks/kactivities-${KFMIN}:5
+	>=kde-frameworks/kcmutils-${KFMIN}:5
+	>=kde-frameworks/kcompletion-${KFMIN}:5
+	>=kde-frameworks/kconfig-${KFMIN}:5
+	>=kde-frameworks/kconfigwidgets-${KFMIN}:5
+	>=kde-frameworks/kcoreaddons-${KFMIN}:5
+	>=kde-frameworks/kdeclarative-${KFMIN}:5
+	>=kde-frameworks/ki18n-${KFMIN}:5
+	>=kde-frameworks/kiconthemes-${KFMIN}:5
+	>=kde-frameworks/kio-${KFMIN}:5
+	>=kde-frameworks/kservice-${KFMIN}:5
+	>=kde-frameworks/kwidgetsaddons-${KFMIN}:5
+	>=kde-frameworks/kwindowsystem-${KFMIN}:5
+	>=kde-plasma/libkworkspace-${PVCUT}:5
+	kdesu? ( >=kde-frameworks/kdesu-${KFMIN}:5 )
+	X? (
+		>=dev-qt/qtx11extras-${QTMIN}:5
+		x11-libs/libX11
+	)
+"
+RDEPEND="${DEPEND}
+	kdesu? ( sys-apps/dbus[X] )
+"
+
+PATCHES=( "${FILESDIR}/${PN}-5.12.80-tests-optional.patch" )
+
+# requires running kde environment
+RESTRICT+=" test"
+
+src_configure() {
+	local mycmakeargs=(
+		$(cmake_use_find_package kdesu KF5Su)
+		$(cmake_use_find_package X Qt5X11Extras)
+	)
+
+	ecm_src_configure
+}
+
+src_install() {
+	ecm_src_install
+	use kdesu && dosym ../$(get_libdir)/libexec/kf5/kdesu /usr/bin/kdesu
+}
diff --git a/kde-plasma/kde-gtk-config/kde-gtk-config-5.19.49.9999.ebuild b/kde-plasma/kde-gtk-config/kde-gtk-config-5.19.49.9999.ebuild
new file mode 100644
index 00000000000..f6b89c56b76
--- /dev/null
+++ b/kde-plasma/kde-gtk-config/kde-gtk-config-5.19.49.9999.ebuild
@@ -0,0 +1,50 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+KFMIN=5.70.0
+PVCUT=$(ver_cut 1-3)
+QTMIN=5.14.1
+VIRTUALX_REQUIRED="test"
+inherit ecm kde.org
+
+DESCRIPTION="GTK2 and GTK3 configurator for KDE Plasma"
+HOMEPAGE="https://cgit.kde.org/kde-gtk-config.git"
+
+LICENSE="GPL-3"
+SLOT="5"
+KEYWORDS=""
+IUSE=""
+
+DEPEND="
+	dev-cpp/glibmm:2
+	dev-libs/glib:2
+	>=dev-qt/qtdbus-${QTMIN}:5
+	>=dev-qt/qtgui-${QTMIN}:5
+	gnome-base/gsettings-desktop-schemas
+	>=kde-frameworks/kconfig-${KFMIN}:5
+	>=kde-frameworks/kcoreaddons-${KFMIN}:5
+	>=kde-frameworks/kdbusaddons-${KFMIN}:5
+	>=kde-frameworks/kiconthemes-${KFMIN}:5
+	x11-libs/gtk+:2
+	x11-libs/gtk+:3
+"
+RDEPEND="${DEPEND}
+	>=kde-plasma/kde-cli-tools-${PVCUT}:5
+"
+
+src_configure() {
+	local mycmakeargs=(
+		-DDATA_INSTALL_DIR="${EPREFIX}/usr/share"
+	)
+
+	ecm_src_configure
+}
+
+pkg_postinst() {
+	ecm_pkg_postinst
+	elog "If you notice missing icons in your GTK applications, you may have to install"
+	elog "the corresponding themes for GTK. A good guess would be x11-themes/oxygen-gtk"
+	elog "for example."
+}
diff --git a/kde-plasma/kdecoration/kdecoration-5.19.49.9999.ebuild b/kde-plasma/kdecoration/kdecoration-5.19.49.9999.ebuild
new file mode 100644
index 00000000000..3928312d3bc
--- /dev/null
+++ b/kde-plasma/kdecoration/kdecoration-5.19.49.9999.ebuild
@@ -0,0 +1,24 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+ECM_TEST="forceoptional"
+KFMIN=5.70.0
+PVCUT=$(ver_cut 1-3)
+QTMIN=5.14.1
+VIRTUALX_REQUIRED="test"
+inherit ecm kde.org
+
+DESCRIPTION="Plugin based library to create window decorations"
+
+LICENSE="|| ( LGPL-2.1 LGPL-3 )"
+SLOT="5"
+KEYWORDS=""
+IUSE=""
+
+DEPEND="
+	>=kde-frameworks/ki18n-${KFMIN}:5
+	>=dev-qt/qtgui-${QTMIN}:5
+"
+RDEPEND="${DEPEND}"
diff --git a/kde-plasma/kdeplasma-addons/kdeplasma-addons-5.19.49.9999.ebuild b/kde-plasma/kdeplasma-addons/kdeplasma-addons-5.19.49.9999.ebuild
new file mode 100644
index 00000000000..7c293c5c9fc
--- /dev/null
+++ b/kde-plasma/kdeplasma-addons/kdeplasma-addons-5.19.49.9999.ebuild
@@ -0,0 +1,62 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+KFMIN=5.70.0
+PVCUT=$(ver_cut 1-3)
+QTMIN=5.14.1
+inherit ecm kde.org
+
+DESCRIPTION="Extra Plasma applets and engines"
+
+LICENSE="GPL-2 LGPL-2"
+SLOT="5"
+KEYWORDS=""
+IUSE="share webengine"
+
+DEPEND="
+	>=kde-frameworks/karchive-${KFMIN}:5
+	>=kde-frameworks/kconfig-${KFMIN}:5
+	>=kde-frameworks/kconfigwidgets-${KFMIN}:5
+	>=kde-frameworks/kcmutils-${KFMIN}:5
+	>=kde-frameworks/kcompletion-${KFMIN}:5
+	>=kde-frameworks/kcoreaddons-${KFMIN}:5
+	>=kde-frameworks/kdeclarative-${KFMIN}:5
+	>=kde-frameworks/kholidays-${KFMIN}:5
+	>=kde-frameworks/ki18n-${KFMIN}:5
+	>=kde-frameworks/kiconthemes-${KFMIN}:5
+	>=kde-frameworks/kio-${KFMIN}:5
+	>=kde-frameworks/knewstuff-${KFMIN}:5
+	>=kde-frameworks/knotifications-${KFMIN}:5
+	>=kde-frameworks/kpackage-${KFMIN}:5
+	>=kde-frameworks/kross-${KFMIN}:5
+	>=kde-frameworks/krunner-${KFMIN}:5
+	>=kde-frameworks/kservice-${KFMIN}:5
+	>=kde-frameworks/kunitconversion-${KFMIN}:5
+	>=kde-frameworks/kwidgetsaddons-${KFMIN}:5
+	>=kde-frameworks/kwindowsystem-${KFMIN}:5
+	>=kde-frameworks/kxmlgui-${KFMIN}:5
+	>=kde-frameworks/plasma-${KFMIN}:5
+	>=kde-frameworks/sonnet-${KFMIN}:5
+	>=dev-qt/qtdbus-${QTMIN}:5
+	>=dev-qt/qtdeclarative-${QTMIN}:5
+	>=dev-qt/qtgui-${QTMIN}:5
+	>=dev-qt/qtwidgets-${QTMIN}:5
+	share? ( >=kde-frameworks/purpose-${KFMIN}:5 )
+	webengine? ( >=dev-qt/qtwebengine-${QTMIN}:5 )
+"
+RDEPEND="${DEPEND}
+	>=kde-plasma/plasma-workspace-${PVCUT}:5
+	>=dev-qt/qtquickcontrols-${QTMIN}:5
+	>=dev-qt/qtquickcontrols2-${QTMIN}:5
+"
+
+src_configure() {
+	local mycmakeargs=(
+		$(cmake_use_find_package share KF5Purpose)
+		$(cmake_use_find_package webengine Qt5WebEngine)
+	)
+
+	ecm_src_configure
+}
diff --git a/kde-plasma/kgamma/kgamma-5.19.49.9999.ebuild b/kde-plasma/kgamma/kgamma-5.19.49.9999.ebuild
new file mode 100644
index 00000000000..b0e4af8524e
--- /dev/null
+++ b/kde-plasma/kgamma/kgamma-5.19.49.9999.ebuild
@@ -0,0 +1,32 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+ECM_HANDBOOK="forceoptional"
+KDE_ORG_NAME="${PN}5"
+KFMIN=5.70.0
+PVCUT=$(ver_cut 1-3)
+QTMIN=5.14.1
+inherit ecm kde.org
+
+DESCRIPTION="Screen gamma values kcontrol module"
+
+LICENSE="GPL-2" # TODO: CHECK
+SLOT="5"
+KEYWORDS=""
+IUSE=""
+
+RDEPEND="
+	>=kde-frameworks/kconfig-${KFMIN}:5
+	>=kde-frameworks/kconfigwidgets-${KFMIN}:5
+	>=kde-frameworks/kcoreaddons-${KFMIN}:5
+	>=kde-frameworks/ki18n-${KFMIN}:5
+	>=dev-qt/qtgui-${QTMIN}:5
+	>=dev-qt/qtwidgets-${QTMIN}:5
+	x11-libs/libX11
+	x11-libs/libXxf86vm
+"
+DEPEND="${RDEPEND}
+	x11-base/xorg-proto
+"
diff --git a/kde-plasma/khotkeys/khotkeys-5.19.49.9999.ebuild b/kde-plasma/khotkeys/khotkeys-5.19.49.9999.ebuild
new file mode 100644
index 00000000000..19cf132f696
--- /dev/null
+++ b/kde-plasma/khotkeys/khotkeys-5.19.49.9999.ebuild
@@ -0,0 +1,50 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2