net-irc/konversation: 21.12.1 version bump

Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

2 files changed, 74 insertions, 0 deletions

diff --git a/net-irc/konversation/Manifest b/net-irc/konversation/Manifest
new file mode 100644
index 00000000000..d09a43de32d
--- /dev/null
+++ b/net-irc/konversation/Manifest
@@ -0,0 +1 @@
+DIST konversation-21.12.1.tar.xz 4254944 BLAKE2B 180317e871900420a4c1cad20cac1633b3fe08e7b9541d36d9ca13d6beb3401f86a8c2385b26aa680458a30807cb325c30395085c1e673203395afc2d945a031 SHA512 a0df7526baba9c614e61dc9dd06d4a812f8a179ad072c81831b6efe15d3e04d85ce7cdf04769fa27cf22e7cf096692b01d8703372a7176f8f76d135ee0796a59
diff --git a/net-irc/konversation/konversation-21.12.1.ebuild b/net-irc/konversation/konversation-21.12.1.ebuild
new file mode 100644
index 00000000000..2b52ddfc3f4
--- /dev/null
+++ b/net-irc/konversation/konversation-21.12.1.ebuild
@@ -0,0 +1,73 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+ECM_HANDBOOK="forceoptional"
+KDE_GEAR="true"
+KFMIN=5.88.0
+QTMIN=5.15.2
+inherit ecm kde.org
+
+DESCRIPTION="User friendly IRC Client"
+HOMEPAGE="https://konversation.kde.org https://apps.kde.org/konversation/"
+
+LICENSE="GPL-2"
+SLOT="5"
+KEYWORDS="~amd64 ~arm64 ~ppc64 ~riscv ~x86"
+IUSE="+crypt"
+
+BDEPEND="sys-devel/gettext"
+DEPEND="
+	>=dev-qt/qtdbus-${QTMIN}:5
+	>=dev-qt/qtgui-${QTMIN}:5
+	>=dev-qt/qtnetwork-${QTMIN}:5
+	>=dev-qt/qtwidgets-${QTMIN}:5
+	>=dev-qt/qtxml-${QTMIN}:5
+	>=kde-frameworks/karchive-${KFMIN}:5
+	>=kde-frameworks/kbookmarks-${KFMIN}:5
+	>=kde-frameworks/kcodecs-${KFMIN}:5
+	>=kde-frameworks/kcompletion-${KFMIN}:5
+	>=kde-frameworks/kconfig-${KFMIN}:5
+	>=kde-frameworks/kconfigwidgets-${KFMIN}:5
+	>=kde-frameworks/kcoreaddons-${KFMIN}:5
+	>=kde-frameworks/kcrash-${KFMIN}:5
+	>=kde-frameworks/kdbusaddons-${KFMIN}:5
+	>=kde-frameworks/kglobalaccel-${KFMIN}:5
+	>=kde-frameworks/ki18n-${KFMIN}:5
+	>=kde-frameworks/kidletime-${KFMIN}:5
+	>=kde-frameworks/kio-${KFMIN}:5
+	>=kde-frameworks/kitemviews-${KFMIN}:5
+	>=kde-frameworks/knewstuff-${KFMIN}:5
+	>=kde-frameworks/knotifications-${KFMIN}:5
+	>=kde-frameworks/knotifyconfig-${KFMIN}:5
+	>=kde-frameworks/kparts-${KFMIN}:5
+	>=kde-frameworks/kservice-${KFMIN}:5
+	>=kde-frameworks/ktextwidgets-${KFMIN}:5
+	>=kde-frameworks/kwallet-${KFMIN}:5
+	>=kde-frameworks/kwidgetsaddons-${KFMIN}:5
+	>=kde-frameworks/kwindowsystem-${KFMIN}:5
+	>=kde-frameworks/kxmlgui-${KFMIN}:5
+	>=media-libs/phonon-4.11.0
+	crypt? ( >=app-crypt/qca-2.3.0:2 )
+"
+RDEPEND="${DEPEND}
+	>=dev-qt/qtsvg-${QTMIN}:5
+	crypt? ( >=app-crypt/qca-2.3.0:2[ssl] )
+"
+
+src_configure() {
+	local mycmakeargs=(
+		$(cmake_use_find_package crypt Qca-qt5)
+	)
+
+	ecm_src_configure
+}
+
+src_install() {
+	ecm_src_install
+
+	# Bug 616162
+	insinto /etc/xdg
+	doins "${FILESDIR}"/konversationrc
+}