2 files changed, 61 insertions, 0 deletions
diff --git a/kde-apps/yakuake/Manifest b/kde-apps/yakuake/Manifest
index f6ab3e1fff1..f5557f056c2 100644
--- a/kde-apps/yakuake/Manifest
+++ b/kde-apps/yakuake/Manifest
@@ -1 +1,2 @@
 DIST yakuake-22.07.90.tar.xz 413568 BLAKE2B 8a8b9c5cd44e621e2458f09e188a35da9ddeb818d4f581d8f0d951f520453b194dcd58540c9115e199be4d37dce20485bea8ed7c59156edd611897e81f00d742 SHA512 09075c817d4298b25e6beef310c67d2e8b2f8aedad86ec40227445c25471bb576af966b6df403813aeaba5bcce2f987ab40bb8ac1d7f9bf77f23bba21a03961c
+DIST yakuake-22.08.0.tar.xz 413520 BLAKE2B 4f75c026ac00ce5cb1284c2cb88ca3255b683745dbdd96725fe9c45632ce14b75fcf9c00156ed617daabd95dc9dbce610f483fe634d076ea42ce5a6ceb25cb41 SHA512 6f82363bed5fda135723a434511a2f488279a35f1a38e1222a240659d01ed4aa1342e40041aca1433d2d2eda8799f028ee0bc0acb4211de729f73b4b6aacdc3d
diff --git a/kde-apps/yakuake/yakuake-22.08.0.ebuild b/kde-apps/yakuake/yakuake-22.08.0.ebuild
new file mode 100644
index 00000000000..c33cbfc2a4d
--- /dev/null
+++ b/kde-apps/yakuake/yakuake-22.08.0.ebuild
@@ -0,0 +1,60 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PVCUT=$(ver_cut 1-3)
+KFMIN=5.96.0
+QTMIN=5.15.5
+inherit ecm gear.kde.org
+
+DESCRIPTION="Quake-style terminal emulator based on konsole"
+HOMEPAGE="https://apps.kde.org/yakuake/"
+
+LICENSE="GPL-2 LGPL-2"
+SLOT="5"
+KEYWORDS="~amd64 ~arm64 ~ppc64 ~x86"
+IUSE="absolute-position X"
+
+DEPEND="
+	>=dev-qt/qtdbus-${QTMIN}:5
+	>=dev-qt/qtgui-${QTMIN}:5
+	>=dev-qt/qtsvg-${QTMIN}:5
+	>=dev-qt/qtwidgets-${QTMIN}:5
+	>=kde-apps/konsole-${PVCUT}:5
+	>=kde-frameworks/karchive-${KFMIN}:5
+	>=kde-frameworks/kconfig-${KFMIN}:5
+	>=kde-frameworks/kconfigwidgets-${KFMIN}:5
+	>=kde-frameworks/kcoreaddons-${KFMIN}:5
+	>=kde-frameworks/kcrash-${KFMIN}:5
+	>=kde-frameworks/kdbusaddons-${KFMIN}:5
+	>=kde-frameworks/kglobalaccel-${KFMIN}:5
+	>=kde-frameworks/ki18n-${KFMIN}:5
+	>=kde-frameworks/kiconthemes-${KFMIN}:5
+	>=kde-frameworks/kio-${KFMIN}:5
+	>=kde-frameworks/knewstuff-${KFMIN}:5
+	>=kde-frameworks/knotifications-${KFMIN}:5
+	>=kde-frameworks/knotifyconfig-${KFMIN}:5
+	>=kde-frameworks/kparts-${KFMIN}:5
+	>=kde-frameworks/kservice-${KFMIN}:5
+	>=kde-frameworks/kwidgetsaddons-${KFMIN}:5
+	>=kde-frameworks/kwindowsystem-${KFMIN}:5
+	>=kde-frameworks/kxmlgui-${KFMIN}:5
+	absolute-position? ( >=kde-frameworks/kwayland-${KFMIN}:5 )
+	X? (
+		>=dev-qt/qtx11extras-${QTMIN}:5
+		x11-libs/libX11
+	)
+"
+RDEPEND="${DEPEND}"
+
+PATCHES=( "${FILESDIR}/${PN}-22.07.90-without_x11.patch" )
+
+src_configure() {
+	local mycmakeargs=(
+		$(cmake_use_find_package absolute-position KF5Wayland)
+		-DWITHOUT_X11=$(usex !X)
+	)
+
+	ecm_src_configure
+}