2 files changed, 64 insertions, 0 deletions
diff --git a/dev-libs/kopeninghours/Manifest b/dev-libs/kopeninghours/Manifest
new file mode 100644
index 00000000000..591160b3718
--- /dev/null
+++ b/dev-libs/kopeninghours/Manifest
@@ -0,0 +1 @@
+DIST kopeninghours-24.12.2.tar.xz 74836 BLAKE2B b24fe6c3117f15f9e06f1185f4c5e6f38918dbe99843e592d4d62512d7e0ee7cd65aeaeb6d90488e4782fd5f2063c1c16aae39acea3167a30ae7709708953d9e SHA512 3d15286f71632ed983df6e28f96ba0556c35231ab7501dc55250fdef0903988d953f7d5e3cf9ed0b2104b7355307d7b63f2402378849a4059c17e9abcf360adb
diff --git a/dev-libs/kopeninghours/kopeninghours-24.12.2.ebuild b/dev-libs/kopeninghours/kopeninghours-24.12.2.ebuild
new file mode 100644
index 00000000000..3182b121a37
--- /dev/null
+++ b/dev-libs/kopeninghours/kopeninghours-24.12.2.ebuild
@@ -0,0 +1,63 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+ECM_QTHELP="true"
+ECM_TEST="true"
+PVCUT=$(ver_cut 1-3)
+KFMIN=6.7.0
+QTMIN=6.7.2
+PYTHON_COMPAT=( python3_{10..12} )
+inherit ecm gear.kde.org python-single-r1
+
+DESCRIPTION="Library for parsing and evaluating OSM opening hours expressions"
+HOMEPAGE="https://api.kde.org/kopeninghours/html/index.html
+https://invent.kde.org/libraries/kopeninghours"
+
+LICENSE="LGPL-2+"
+SLOT="6"
+KEYWORDS="~amd64 ~arm64"
+IUSE="python"
+
+REQUIRED_USE="python? ( ${PYTHON_REQUIRED_USE} )"
+
+DEPEND="
+	>=dev-libs/kpublictransport-${PVCUT}:6
+	>=dev-qt/qtdeclarative-${QTMIN}:6
+	>=kde-frameworks/kholidays-${KFMIN}:6
+	>=kde-frameworks/ki18n-${KFMIN}:6
+	sys-libs/zlib
+	python? (
+		$(python_gen_cond_dep '
+			>=dev-libs/boost-1.70:=[python,${PYTHON_USEDEP}]
+		')
+	)
+"
+RDEPEND="${DEPEND}
+	${PYTHON_DEPS}
+"
+BDEPEND="
+	app-alternatives/lex
+	app-alternatives/yacc
+"
+
+PATCHES=( "${FILESDIR}"/${PN}-22.04.0-boostpython.patch )
+
+pkg_setup() {
+	ecm_pkg_setup
+	python_setup
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DBOOSTPYTHON_VERSION_MAJOR_MINOR=${EPYTHON}
+		$(cmake_use_find_package python Boost)
+	)
+	ecm_src_configure
+}
+
+src_install() {
+	ecm_src_install
+	python_optimize
+}