1 files changed, 51 insertions, 0 deletions
diff --git a/dev-util/kdevelop-python/kdevelop-python-4.90.91.ebuild b/dev-util/kdevelop-python/kdevelop-python-4.90.91.ebuild
new file mode 100644
index 00000000000..ac7b5eda62c
--- /dev/null
+++ b/dev-util/kdevelop-python/kdevelop-python-4.90.91.ebuild
@@ -0,0 +1,51 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=6
+
+KDEBASE="kdevelop"
+KMNAME="kdev-python"
+PYTHON_COMPAT=( python3_5 )
+inherit kde5 python-any-r1
+
+DESCRIPTION="Python plugin for KDevelop"
+IUSE=""
+KEYWORDS="~amd64"
+
+DEPEND="
+	$(add_frameworks_dep kcompletion)
+	$(add_frameworks_dep kconfig)
+	$(add_frameworks_dep kcoreaddons)
+	$(add_frameworks_dep ki18n)
+	$(add_frameworks_dep kio)
+	$(add_frameworks_dep kitemmodels)
+	$(add_frameworks_dep knewstuff)
+	$(add_frameworks_dep kparts)
+	$(add_frameworks_dep ktexteditor)
+	$(add_frameworks_dep kwidgetsaddons)
+	$(add_frameworks_dep kxmlgui)
+	$(add_frameworks_dep threadweaver)
+	$(add_qt_dep qtgui)
+	$(add_qt_dep qtwidgets)
+	dev-util/kdevplatform:5
+	${PYTHON_DEPS}
+"
+RDEPEND="${DEPEND}
+	dev-util/kdevelop:5
+"
+
+RESTRICT+=" test"
+
+pkg_setup() {
+	python-any-r1_pkg_setup
+	kde5_pkg_setup
+}
+
+src_compile() {
+	pushd "${WORKDIR}"/${P}_build > /dev/null || die
+	emake parser
+	popd > /dev/null || die
+
+	kde5_src_compile
+}