2 files changed, 0 insertions, 81 deletions
diff --git a/kde-apps/ark/Manifest b/kde-apps/ark/Manifest
deleted file mode 100644
index d1ff82573c1..00000000000
--- a/kde-apps/ark/Manifest
+++ /dev/null
@@ -1 +0,0 @@
-DIST ark-25.08.2.tar.xz 3018076 BLAKE2B 9ab2cd6afe06168bd33be6e81a76c286af9f4c7a5f335fd418a29556b3daabe6f874a6b67ea55f366ab03bec4b12db4385aacd397aa032c70869d4f2994a865f SHA512 67a87c711797c971da6573b4932ee1190656bd16b044817a4d3af5956ad21b3bf36afa8e508c35754edbe98f1135f45da34ec9917d3a61e54d0221e84fe5467a
diff --git a/kde-apps/ark/ark-25.08.2.ebuild b/kde-apps/ark/ark-25.08.2.ebuild
deleted file mode 100644
index 841b72db52b..00000000000
--- a/kde-apps/ark/ark-25.08.2.ebuild
+++ /dev/null
@@ -1,80 +0,0 @@
-# Copyright 1999-2025 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-
-ECM_HANDBOOK="optional"
-ECM_TEST="true"
-KFMIN=6.16.0
-QTMIN=6.9.1
-inherit ecm gear.kde.org optfeature xdg
-
-DESCRIPTION="File archiver by KDE"
-HOMEPAGE="https://apps.kde.org/ark/"
-
-LICENSE="GPL-2" # TODO: CHECK
-SLOT="6"
-KEYWORDS="~amd64 ~arm64 ~loong ~ppc64 ~riscv ~x86"
-IUSE="zip"
-
-RDEPEND="
-	>=app-arch/libarchive-3.5.3:=[bzip2,lzma]
-	>=dev-qt/qtbase-${QTMIN}:6[dbus,gui,widgets]
-	>=kde-frameworks/kcompletion-${KFMIN}:6
-	>=kde-frameworks/kconfig-${KFMIN}:6
-	>=kde-frameworks/kconfigwidgets-${KFMIN}:6
-	>=kde-frameworks/kcoreaddons-${KFMIN}:6
-	>=kde-frameworks/kcrash-${KFMIN}:6
-	>=kde-frameworks/kdbusaddons-${KFMIN}:6
-	>=kde-frameworks/kfilemetadata-${KFMIN}:6
-	>=kde-frameworks/ki18n-${KFMIN}:6
-	>=kde-frameworks/kio-${KFMIN}:6
-	>=kde-frameworks/kjobwidgets-${KFMIN}:6
-	>=kde-frameworks/kparts-${KFMIN}:6
-	>=kde-frameworks/kpty-${KFMIN}:6
-	>=kde-frameworks/kservice-${KFMIN}:6
-	>=kde-frameworks/kwidgetsaddons-${KFMIN}:6
-	>=kde-frameworks/kwindowsystem-${KFMIN}:6
-	>=kde-frameworks/kxmlgui-${KFMIN}:6
-	sys-libs/zlib
-	zip? ( >=dev-libs/libzip-1.6.0:= )
-"
-DEPEND="${RDEPEND}
-	>=kde-frameworks/kiconthemes-${KFMIN}:6
-	>=dev-qt/qtbase-${QTMIN}:6[concurrent]
-	test? ( >=dev-libs/libzip-1.6.0:= )
-"
-# app-arch/rar is binary only
-BDEPEND="
-	sys-devel/gettext
-	elibc_glibc? ( test? ( amd64? ( app-arch/rar ) x86? ( app-arch/rar ) ) )
-"
-
-src_configure() {
-	local mycmakeargs=(
-		$(cmake_use_find_package zip LibZip)
-	)
-
-	ecm_src_configure
-}
-
-src_test() {
-	local myctestargs=(
-		# bug 822177: kerfuffle-addtoarchivetest: may segfault or hang indefinitely
-		# bug 827840: plugins-clirartest: continuously broken with translations installed
-		-E "(kerfuffle-addtoarchivetest|plugins-clirartest)"
-	)
-
-	ecm_src_test
-}
-
-pkg_postinst() {
-	if [[ -z "${REPLACING_VERSIONS}" ]]; then
-		optfeature "rar archive creation/extraction" "app-arch/rar"
-		optfeature "rar archive extraction only" "app-arch/unar" "app-arch/unrar"
-		optfeature "7-Zip archive support" ">=app-arch/7zip-24.09[symlink(+)]" "app-arch/p7zip"
-		optfeature "lrz archive support" "app-arch/lrzip"
-		optfeature "Markdown support in text previews" "kde-misc/markdownpart:${SLOT}"
-	fi
-	xdg_pkg_postinst
-}