2 files changed, 58 insertions, 0 deletions
diff --git a/kde-frameworks/kidletime/Manifest b/kde-frameworks/kidletime/Manifest
new file mode 100644
index 00000000000..6fb8cf5fcaa
--- /dev/null
+++ b/kde-frameworks/kidletime/Manifest
@@ -0,0 +1 @@
+DIST kidletime-6.13.0.tar.xz 30752 BLAKE2B 558bb4a52612511a74ddebfead0ad20c9a906ef052ad3818fc61a0e2f0bd0a00a7351d68ba524b7691139fcc6c2b327defea73400495727b6018b1bb635784a8 SHA512 87f562d535b01763d34db20f90b263011b07cdd6d1dcc1c9aa0ce8ccf2140bfb8b17bd6c2159a212c0d04edcd35dc430bb7e2a4ff832b6656eb5635537db2932
diff --git a/kde-frameworks/kidletime/kidletime-6.13.0.ebuild b/kde-frameworks/kidletime/kidletime-6.13.0.ebuild
new file mode 100644
index 00000000000..5043bf338c2
--- /dev/null
+++ b/kde-frameworks/kidletime/kidletime-6.13.0.ebuild
@@ -0,0 +1,57 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+ECM_TEST="false"
+QTMIN=6.7.2
+inherit ecm frameworks.kde.org
+
+DESCRIPTION="Framework for detection and notification of device idle time"
+
+LICENSE="LGPL-2+"
+KEYWORDS="~amd64 ~arm64 ~ppc64 ~riscv ~x86"
+IUSE="wayland X xscreensaver"
+
+REQUIRED_USE="xscreensaver? ( X )"
+
+RDEPEND="
+	>=dev-qt/qtbase-${QTMIN}:6[gui]
+	wayland? (
+		dev-libs/wayland
+		>=dev-qt/qtbase-${QTMIN}:6=[wayland]
+		>=dev-qt/qtwayland-${QTMIN}:6
+	)
+	X? (
+		x11-libs/libX11
+		x11-libs/libxcb
+		x11-libs/libXext
+	)
+	xscreensaver? (
+		>=dev-qt/qtbase-${QTMIN}:6[dbus]
+		x11-libs/libXScrnSaver
+	)
+"
+DEPEND="${RDEPEND}
+	wayland? (
+		>=dev-libs/plasma-wayland-protocols-1.11.1
+		>=dev-libs/wayland-protocols-1.27:0
+	)
+"
+BDEPEND="wayland? ( >=dev-qt/qtwayland-${QTMIN}:6 )"
+
+src_prepare() {
+	ecm_src_prepare
+	if ! use xscreensaver; then
+		sed -i -e "s/\${X11_Xscreensaver_FOUND}/0/" CMakeLists.txt || die
+	fi
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DWITH_WAYLAND=$(usex wayland)
+		-DWITH_X11=$(usex X)
+	)
+
+	ecm_src_configure
+}