2 files changed, 0 insertions, 75 deletions
diff --git a/kde-frameworks/purpose/Manifest b/kde-frameworks/purpose/Manifest
deleted file mode 100644
index f06c4084002..00000000000
--- a/kde-frameworks/purpose/Manifest
+++ /dev/null
@@ -1 +0,0 @@
-DIST purpose-6.11.0.tar.xz 188056 BLAKE2B 5bf26165cd60da956e9a5fcb95ba4cf3fc0362376f77ac3799bcabe9d0835a862178d642e068194f55354c439bf6fd1c4341847e6ffdc147fca0560c3fd947e0 SHA512 9f4780fb49b7895d145586eac7179e11790d1ef7029e83d9bb00f809ba60238c470174e9d7dbf8b5f443b79aac5d1b78e452135fb66eded6d0d67a6aad0356d4
diff --git a/kde-frameworks/purpose/purpose-6.11.0.ebuild b/kde-frameworks/purpose/purpose-6.11.0.ebuild
deleted file mode 100644
index 972c7c33d25..00000000000
--- a/kde-frameworks/purpose/purpose-6.11.0.ebuild
+++ /dev/null
@@ -1,74 +0,0 @@
-# Copyright 1999-2025 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-
-ECM_QTHELP="false"
-ECM_TEST="forceoptional"
-QTMIN=6.7.2
-inherit ecm frameworks.kde.org optfeature xdg
-
-DESCRIPTION="Library for providing abstractions to get the developer's purposes fulfilled"
-
-LICENSE="LGPL-2.1+"
-KEYWORDS="~amd64 ~arm64 ~ppc64 ~riscv ~x86"
-IUSE="bluetooth webengine"
-
-# requires running environment
-RESTRICT="test"
-
-DEPEND="
-	>=dev-qt/qtbase-${QTMIN}:6[dbus,gui,network,widgets]
-	>=dev-qt/qtdeclarative-${QTMIN}:6
-	=kde-frameworks/kconfig-${KDE_CATV}*:6
-	=kde-frameworks/kcoreaddons-${KDE_CATV}*:6
-	=kde-frameworks/ki18n-${KDE_CATV}*:6
-	=kde-frameworks/kio-${KDE_CATV}*:6
-	=kde-frameworks/kirigami-${KDE_CATV}*:6
-	=kde-frameworks/knotifications-${KDE_CATV}*:6
-	=kde-frameworks/kservice-${KDE_CATV}*:6
-	=kde-frameworks/prison-${KDE_CATV}*:6
-	webengine? (
-		kde-apps/kaccounts-integration:6
-		>=net-libs/accounts-qt-1.17[qt6(+)]
-	)
-"
-RDEPEND="${DEPEND}
-	>=kde-frameworks/kdeclarative-${KDE_CATV}:6
-	bluetooth? ( =kde-frameworks/bluez-qt-${KDE_CATV}*:6 )
-	webengine? (
-		>=kde-frameworks/purpose-kaccounts-services-${KDE_CATV}
-		>=net-libs/accounts-qml-0.7_p20231028[qt6(+)]
-	)
-"
-BDEPEND="webengine? ( dev-util/intltool )"
-
-src_prepare() {
-	ecm_src_prepare
-
-	use bluetooth ||
-		cmake_run_in src/plugins cmake_comment_add_subdirectory bluetooth
-}
-
-src_configure() {
-	local mycmakeargs=(
-		$(cmake_use_find_package webengine KAccounts6)
-	)
-
-	ecm_src_configure
-}
-
-src_install() {
-	# Shipped by kde-frameworks/purpose-kaccounts-services package for shared use w/ SLOT 5
-	use webengine && ECM_REMOVE_FROM_INSTALL=(
-		/usr/share/accounts/services/kde/{google-youtube,nextcloud-upload}.service
-	)
-	ecm_src_install
-}
-
-pkg_postinst() {
-	if [[ -z "${REPLACING_VERSIONS}" ]]; then
-		optfeature "Send through KDE Connect" kde-misc/kdeconnect
-	fi
-	xdg_pkg_postinst
-}