2 files changed, 51 insertions, 0 deletions
diff --git a/kde-frameworks/knotifications/Manifest b/kde-frameworks/knotifications/Manifest
new file mode 100644
index 00000000000..1840d60a57d
--- /dev/null
+++ b/kde-frameworks/knotifications/Manifest
@@ -0,0 +1 @@
+DIST knotifications-5.103.0.tar.xz 2372848 BLAKE2B e2299861e9fc5c679b279fdee62ee37eff628e38ccc10225ec90767d147be6e47b435447d403d5f0fa32b23a129f99b0b5c3a4c78d500628cf47a9267e9caca3 SHA512 12fb8b75cb57940d182a2c485d1620183745d1ada389c24aafb39a4a5ef3ca806e9c1bd527441109c5d1245f6c8f6dd81a8b747a5f8d813e77b5c150ffbba32f
diff --git a/kde-frameworks/knotifications/knotifications-5.103.0.ebuild b/kde-frameworks/knotifications/knotifications-5.103.0.ebuild
new file mode 100644
index 00000000000..cd8094d8aec
--- /dev/null
+++ b/kde-frameworks/knotifications/knotifications-5.103.0.ebuild
@@ -0,0 +1,50 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+ECM_TEST="false"
+PVCUT=$(ver_cut 1-2)
+QTMIN=5.15.5
+inherit ecm frameworks.kde.org
+
+DESCRIPTION="Framework for notifying the user of an event"
+
+LICENSE="LGPL-2.1+"
+KEYWORDS="~amd64 ~arm ~arm64 ~loong ~ppc64 ~riscv ~x86"
+IUSE="dbus phonon qml speech X"
+
+RDEPEND="
+	>=dev-qt/qtdbus-${QTMIN}:5
+	>=dev-qt/qtgui-${QTMIN}:5
+	>=dev-qt/qtwidgets-${QTMIN}:5
+	=kde-frameworks/kconfig-${PVCUT}*:5
+	=kde-frameworks/kcoreaddons-${PVCUT}*:5
+	=kde-frameworks/kwindowsystem-${PVCUT}*:5[X?]
+	dbus? ( dev-libs/libdbusmenu-qt[qt5(+)] )
+	!phonon? ( media-libs/libcanberra )
+	phonon? ( >=media-libs/phonon-4.11.0 )
+	qml? ( >=dev-qt/qtdeclarative-${QTMIN}:5 )
+	speech? ( >=dev-qt/qtspeech-${QTMIN}:5 )
+	X? (
+		>=dev-qt/qtx11extras-${QTMIN}:5
+		x11-libs/libX11
+		x11-libs/libXtst
+	)
+"
+DEPEND="${RDEPEND}
+	X? ( x11-base/xorg-proto )
+"
+BDEPEND=">=dev-qt/linguist-tools-${QTMIN}:5"
+
+src_configure() {
+	local mycmakeargs=(
+		$(cmake_use_find_package dbus dbusmenu-qt5)
+		$(cmake_use_find_package !phonon Canberra)
+		$(cmake_use_find_package qml Qt5Qml)
+		$(cmake_use_find_package speech Qt5TextToSpeech)
+		-DWITHOUT_X11=$(usex !X)
+	)
+
+	ecm_src_configure
+}