2 files changed, 58 insertions, 0 deletions
diff --git a/kde-frameworks/kidletime/Manifest b/kde-frameworks/kidletime/Manifest
new file mode 100644
index 00000000000..f260a4702bb
--- /dev/null
+++ b/kde-frameworks/kidletime/Manifest
@@ -0,0 +1 @@
+DIST kidletime-6.8.0.tar.xz 30712 BLAKE2B 687fce1eff9bc87590bc943e54fa13b81cadd7cc94741b6c280f71d89479b4d2f2a65a78a1c1e3ead40d92f0a8ba1020f2ede6130ab9e4501158a8e2707ec280 SHA512 5062e9e640c4a4c01ec6fd685cd3063114dace737ecfcb72406dad318290216f516fcd39bc0ae6db3ccd8773788ae42d509c34eeaf89851d829aa8e290c9c1bb
diff --git a/kde-frameworks/kidletime/kidletime-6.8.0.ebuild b/kde-frameworks/kidletime/kidletime-6.8.0.ebuild
new file mode 100644
index 00000000000..0f12dce966c
--- /dev/null
+++ b/kde-frameworks/kidletime/kidletime-6.8.0.ebuild
@@ -0,0 +1,57 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+ECM_TEST="false"
+QTMIN=6.7.2
+inherit ecm frameworks.kde.org
+
+DESCRIPTION="Framework for detection and notification of device idle time"
+
+LICENSE="LGPL-2+"
+KEYWORDS="~amd64 ~arm64 ~ppc64 ~riscv ~x86"
+IUSE="wayland X xscreensaver"
+
+REQUIRED_USE="xscreensaver? ( X )"
+
+RDEPEND="
+	>=dev-qt/qtbase-${QTMIN}:6[gui]
+	wayland? (
+		dev-libs/wayland
+		>=dev-qt/qtbase-${QTMIN}:6=[wayland]
+		>=dev-qt/qtwayland-${QTMIN}:6
+	)
+	X? (
+		x11-libs/libX11
+		x11-libs/libxcb
+		x11-libs/libXext
+	)
+	xscreensaver? (
+		>=dev-qt/qtbase-${QTMIN}:6[dbus]
+		x11-libs/libXScrnSaver
+	)
+"
+DEPEND="${RDEPEND}
+	wayland? (
+		>=dev-libs/plasma-wayland-protocols-1.11.1
+		>=dev-libs/wayland-protocols-1.27:0
+	)
+"
+BDEPEND="wayland? ( >=dev-qt/qtwayland-${QTMIN}:6 )"
+
+src_prepare() {
+	ecm_src_prepare
+	if ! use xscreensaver; then
+		sed -i -e "s/\${X11_Xscreensaver_FOUND}/0/" CMakeLists.txt || die
+	fi
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DWITH_WAYLAND=$(usex wayland)
+		-DWITH_X11=$(usex X)
+	)
+
+	ecm_src_configure
+}