2 files changed, 53 insertions, 0 deletions
diff --git a/kde-frameworks/kirigami/Manifest b/kde-frameworks/kirigami/Manifest
new file mode 100644
index 00000000000..0eadf783dff
--- /dev/null
+++ b/kde-frameworks/kirigami/Manifest
@@ -0,0 +1 @@
+DIST kirigami2-5.115.0.tar.xz 383944 BLAKE2B ce95794319ebbda40d384896da4e94dcf5137d176b0c3cab53bf5223ed48e0c95486002010c74008b42857ce7d27d4840c2af0395e957d0eade18bc2f5796f87 SHA512 b99d9829f864ae59b0ae4064e0b0b24a0f33ce2c35c60b4609fd9746bb322cab26d3f9afe6ba0893b486d4c546ead98c5ba42dc33271d2fdf47e34caef35ea90
diff --git a/kde-frameworks/kirigami/kirigami-5.115.0.ebuild b/kde-frameworks/kirigami/kirigami-5.115.0.ebuild
new file mode 100644
index 00000000000..75684c65be2
--- /dev/null
+++ b/kde-frameworks/kirigami/kirigami-5.115.0.ebuild
@@ -0,0 +1,52 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+ECM_EXAMPLES="true"
+ECM_QTHELP="false"
+ECM_TEST="true"
+KDE_ORG_TAR_PN="${PN}2"
+QTMIN=5.15.9
+inherit ecm frameworks.kde.org toolchain-funcs
+
+DESCRIPTION="Lightweight user interface framework for mobile and convergent applications"
+HOMEPAGE="https://techbase.kde.org/Kirigami"
+
+LICENSE="LGPL-2+"
+KEYWORDS="~amd64 ~arm ~arm64 ~loong ~ppc64 ~riscv ~x86"
+IUSE="openmp"
+
+# requires package to already be installed
+RESTRICT="test"
+
+DEPEND="
+	>=dev-qt/qtconcurrent-${QTMIN}:5
+	>=dev-qt/qtdbus-${QTMIN}:5
+	>=dev-qt/qtdeclarative-${QTMIN}:5
+	>=dev-qt/qtgui-${QTMIN}:5
+	>=dev-qt/qtnetwork-${QTMIN}:5
+	>=dev-qt/qtquickcontrols2-${QTMIN}:5
+	>=dev-qt/qtsvg-${QTMIN}:5
+"
+RDEPEND="${DEPEND}
+	>=dev-qt/qtgraphicaleffects-${QTMIN}:5
+"
+BDEPEND=">=dev-qt/linguist-tools-${QTMIN}:5"
+
+pkg_pretend() {
+	[[ ${MERGE_TYPE} != binary ]] && use openmp && tc-check-openmp
+}
+
+pkg_setup() {
+	[[ ${MERGE_TYPE} != binary ]] && use openmp && tc-check-openmp
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DBUILD_EXAMPLES=$(usex examples)
+		$(cmake_use_find_package openmp OpenMP)
+	)
+
+	ecm_src_configure
+}